*label Next_fouryears
*set advancement 2
*set shards 80
*set aurapressure 140
*set kosukecombat + 1
*set combatstat ""
*set combatstat2 ""
*set combatskill ""
*temp subrc ""
*temp val 0
*temp skillgain 0

Smoke billows out of the large wooden structure secluded in the forest, a warehouse hidden from the roads.

You stand atop its roof and feel the night's cold wind blowing against your white arts gi that marks you as an uninitiated Martial Artist. A free agent. Or in your case, an unproven recruit.

The Sunbringer Sect's disciples thought they could hide their ill-gotten gains from the raid they performed on your village's trade caravan. They were wrong.

After lighting fire to their warehouse you crouch low on the rooftop and wait for the guards in the surrounding woods to enter the building to investigate. That's when you make your move and leap from the roof. With any luck the roar of the fires will mask the impact of your body landing on a sturdy tree branch twenty feet out.

Both your ankles threaten to break when you impact the branch, but the wood gives out first.

You crash to the ground, and the Sunbringer guards in their silver and yellow combat gi sound the alarm behind you. Only one word echoes through your mind.

[i]Run.[/i]

*page_break

Blasts of fire and light crash throughout the forest as you weave between trees in a chase of life and death. One Martial Artist in Sunbringer combat robes catches up to you, jumping out at you from behind a tree you planned to dodge behind.

He swings his leg out in a powerful kick enhanced with chi.

You have less than a second to react when you notice it, three inches from your face and closing fast.

*choice
	#Swing a punch at his crotch. [Increase Power]
		*set power + 1
		*set powspent + 1
		Power surges through your forearm and fist and you swing right for the man's crotch. He may land his hit, but so will you.
		
		He shrinks back and dodges, protecting his groin more dearly than you protected your own life.
		
		Coward.
		
	#Headbutt his shin to break it. [Increase Fortitude]
		*set fortitude + 1
		*set forspent + 1
		His kick lands with full impact, albeit 2 inches too high. Instead of crunching through your nose his shin comes in contact with your forehead as you lean into his attack, and you feel his shin break under the impact.
		
		You had expected to be an immovable object meeting an unstoppable force, but found him wanting.
		
		His force was stoppable.
	#DODGE! [Increase Agility]
		*set agility + 1
		*set agispent + 1
		With inhuman speed you surge your Agility Core and nearly disappear in a blur of white light, moving at triple speed for just a moment.
		
		You duck under his kick, grab his other leg, and pull it forward as you dash further away. You hear him swear as he twists in the air behind you and crashes to the ground.
	#Blast him with chi. [Increase Soul]
		*set soul + 1
		*set solspent + 1
		Both your hands shoot forward in a desperate bid to survive. You push the very power of your soul outward, unrefined as it may be, and emit a scorching hot surge of white chi akin to a bonfire launched with the speed of a firework.
		
		The blast hits his other leg and destabilizes him, causing his kick to lose its grounding and deal superficial damage to your head. His leg gives out and he crumbles to the ground, swearing.
		
You keep running using your head start to stay ahead of him and leave every other Sunbringer disciple further behind.
*page_break
Six hours pass. Six hours of nonstop running until you collapse from exhaustion. You can't know if you've lost them all, even with your supernatural ability to sense other Martial Artists' auras. Too many have trained to hide their Aura Pressure to avoid spiritual detection.

But it doesn't matter.

If they're still following you then you're dead no matter what, because you can't go on.

You drop to the ground, exhausted, over a puddle on the outskirts of the woods leading up the mountains. It takes every ounce of willpower to catch yourself before your face hits the water. If you must die here then you will die with dignity.

After several seconds of gasping breaths you see both the puddle and your glistening sweat illuminate with an orange glow, coming from behind, and you know it's over. The Sunbringer Sect has caught up to you after you burned their stolen loot to the ground. You take one last look at the reflection in the puddle.

Damn, what a gorgeous...
*choice
	#Man
		*set himher "him"
		*set hisher "his"
		*set hishers "his"
		*set heshe "he"
		*set ymaster "Young Master"
		*set boygirl "boy"
		*set sondaughter "son"
		*set manwoman "man"
		*set patriarch "Patriarch"
	#Woman
		*set himher "her"
		*set hisher "her"
		*set hishers "hers"
		*set ymaster "Young Mistress"
		*set heshe "she"
		*set boygirl "girl"
		*set sondaughter "daughter"
		*set manwoman "woman"
		*set patriarch "Matriarch"

*label Next_race
*if (heshe = "he")
	*set bffhimher "her"
	*set bffhisher "her"
	*set bffhishers "hers"
	*set bffheshe "she"
*else
	*set bffhimher "him"
	*set bffhisher "his"
	*set bffhishers "his"
	*set bffheshe "he"
The world's going to lose a perfect specimen of a...
*choice
	#Human, native and most common inhabitants of the world.
		Like most of the people on the planet, and especially your village, you are a Human. Your brown almond-shaped eyes and black
		*if (heshe = "he")
			spiky
		*elseif (heshe = "she")
			silky
		hair marks you as a Zenshin, or maybe you have ancestors from the previous empire of Cathayans, but that doesn't matter. What matters is the Human body is designed perfectly for cycling chi; Oni only exist because spirits want a human form, and Yokai only exist because animals want a human form. It feels good to be born as the world's most sought-after natural body, even if being a dragon would have been more aesthetic.
		
		Still, you're proud to feel a connection to your people and your lands. History says it was your people who rebuilt this world after the last Calamity, and history will continue to say it is your people that forge its destiny.
		
		Long live the Rasen Empire.
		
		[b][Racial Bonus: Lore +1][/b]
		
		Are you sure you're a Human?
		*choice
			#Yes I'm a Human
				*set lore + 1
				*set haircolor "black"
				*set eyecolor "black"
				*set race "Human"
				*set raceadjective "human"
			#No, I'm something else.
				*goto Next_race
	#Lunargoth, a pale human with rounder eyes.
		You're an oddity in the small village of Thunderfall. While native humans have black or brown hair and brown eyes before absorbing enough chi that might change such traits, your people are born with a cascade of colors. Lunargoths possess lighter skin with more round eyes in shades of blue, green, grey, or amber, and a variety of hair colors from pitch black to white, yellow, orange, or red.
		
		Your father sports short golden hair with green eyes and your mother has long and curly bright-red hair with dark blue eyes. You forgot to say goodbye to them before you mission. You wish you hadn't forgotten.
		
		It's said there are more of you somewhere else. Not just the major cities that have a bit of everything, but in lands beyond this world filled with darkstone Gothic architecture. They say your people came down centuries ago from the Moon, which is awesome. You always wanted to go to the Moon one day.
		
		[b][Racial Bonus: Craft +1][/b]
		
		Are you sure you're a Lunargoth?
		*choice
			#Yes, I'm a Lunargoth.
				*set craft + 1
				*set race "Lunargoth"
				*set raceadjective "gothic"
				Like all Lunargoths you're born with coloration in your hair and eyes. In particular, your hair is...
				*choice
					#Pitch black.
						*set haircolor "black"
					#Shades of light brown.
						*set haircolor "light brown"
					#Dirty blonde.
						*set haircolor "dirty blonde"
					#Golden Blonde.
						*set haircolor "golden blonde"
					#Pure white.
						*set haircolor "white"
					#Burning orange.
						*set haircolor "orange"
					#Deep red.
						*set haircolor "red"
				And your eyes are...
				*choice
					#Black
						*set eyecolor "black"
					#Grey
						*set eyecolor "grey"
					#Deep blue
						*set eyecolor "blue"
					#Pale blue
						*set eyecolor "pale blue"
					#Amber
						*set eyecolor "amber"
					#Verdant green
						*set eyecolor "green"
					#Pale green
						*set eyecolor "pale green"
					#Hazel
						*set eyecolor "hazel"
			#No, I'm something else.
				*goto Next_race
	#Oni, a red-skinned descendant of demons.
		Oni descend from spirits or demons who managed to manifest a physical form, normally by stealing the body of a human and warping it to fit their desires. You are recognizable by the hereditary spiritual taint: red skin, white hair, and black or yellow eyes. Your kind is distrusted in most rural areas where you're considered thieves or cultists.
		
		Oni families like yours aren't rare in your village, but if they were, you'd be in trouble. Luckily there have been enough Oni in Thunderfall Village for generations, to the point that co-existing was easy by the time you were born.
		
		You hear things are worse elsewhere, sometimes much worse. You also hear things are better in the major cities where many of your kind control banks and trade. As an Oni you have no additional spiritual powers or the ability to bargain for souls like a true demon, but you are pretty good at turning a conversation in your favor when you're in trouble.
		
		[b][Racial Bonus: Deception +1][/b]
		
		Are you sure you're an Oni?
		*choice
			#Yes, I'm an Oni.
				*set deception + 1
				*set race "Oni"
				*set raceadjective "demonic"
				Oni always have pitch-black or snow-white hair. Your family in particular displays...
				*choice
					#White hair
						*set haircolor "white"
					#Black hair
						*set haircolor "black"
				Your father is a yellow-eyed Oni while your mother is a black-eyed Oni. You happen to be a...
				*choice
					#Yellow-eyed Oni.
						*set eyecolor "yellow"
					#Black-eyed Oni.
						*set eyecolor "black"
			#No, I'm something else.
				*goto Next_race
	#Yokai, descendant of animals who Advanced their bodies into human form.
		When animals absorb enough chi to transform into a more powerful body they are called Beasts. But not all animals choose to become larger predators. For various reasons, some empowered animals spend immense spiritual energy to advance their intelligence and spirit by taking on the form of a human body.
		
		Such beings are known as Yokai.
		
		Yokai that are formed from this transformation, this variation of "Advancement", are all extremely powerful, but your family isn't like them.
		
		Like the vast majority of Yokai, you just descend from one or more animals who Advanced a long time ago, probably a few great-great-great-grandparents. Most yokai keep some animalistic traits from their predecessor such as eyes, fangs, or ears, and almost all have a tail. You happen to descend from...
		*choice
			#Felines
				*set subrc "Cat"
				Panthers, Tigers, Bobcat, Lions, Cougars, even some housecats, they're all master hunters and so they're some of the most common animals to Advance into a Beast or a Yokai. Your ears are those of a cat, fluffy and twitching, growing through your hair closer to the top of your head. But your real prized trait is your tail, soft and flexible.
			#Canines
				*set subrc "Wolf"
				Wolves and dogs are man's closest friend in the animal kingdom. It's no surprise that some wolf or dog Beast ancestor of yours was around powerful humans long enough that it chose to Advance into a human body. Your ears are those of a wolf, tufted and soft, growing through your hair near the top of your head. Your tail is large, and oh so fluffy.
			#Reptiles
				*set subrc "Reptile"
				Being cold-blooded stops many reptile Beasts from Advancing into Yokai, the change is just too fundamental. It requires too much chi. For that reason, those who manage the process are incredibly frightening creatures. Whatever the reptile was when it was born, by the time your ancestor had enough power to Advance into a Yokai it had probably already Advanced into a massive tunneling Wyrm or terrifying Dragon.
				
				Your thin scaled tail has an arrowhead tip.
			#Monkeys
				*set subrc "Monkey"
				Monkeys are fairly close to humans and are one of the easiest transitions for Beasts to make, barring the tailless Apes. Something about a tail seemed to be vital for Yokai Advancement. As such, Monkey Yokai are the most human-looking. Often the tail is the only trait exposing them as Yokai at all.
				
				You wrap yours to wear it like a belt sometimes, like Father and Mother do.
			#Bovines
				*set subrc "Bovine"
				Cattle are docile creatures, kept in a confined space away from aura-rich hidden treasures of nature. In such captivity cows and bulls are never capable of Advancement...by accident. On purpose however, is another story. Almost all cattle that Advance into a Beast do so because their owner purposefully prepared them for it.
				
				Cattle herds are prime targets for the powerful beasts roaming the wilds, and replacing guards or attack dogs with powerful bovine Beasts is an expensive but worthwhile status symbol for rich farmers, or farmers working for rich nobles. Somewhere up the family tree one of your ancestors was prized enough to Advance not just to a Beast, but again later on into an intelligent Yokai with their own rights under the Rasen Imperial Government. They must have been very long-lived.
				
				Your tail is short, only growing down to your knees, with a tuft of hair at the end. You could hide it if you wanted.
	
		Animalistic instincts flow through your mind now and then. You find they can be leaned on for an edge in the natural world.
		
		*if (subrc = "Wolf")
			[b][Wolf Yokai Racial Bonus: Survival +1][/b]
		*elseif (subrc = "Cat")
			[b][Cat Yokai Racial Bonus: Perception +1][/b]
		*elseif (subrc = "Reptile")
			[b][Reptile Yokai Racial Bonus: Stealth +1][/b]
		*elseif (subrc = "Monkey")
			[b][Monkey Yokai Racial Bonus: Thievery +1][/b]
		*elseif (subrc = "Bovine")
			[b][Bovine Yokai Racial Bonus: Athletics +1][/b]
		*else
			*bug
		
		Are you sure you're a Yokai?
		*choice
			#Yes, I am a Yokai.
				*if (subrc = "Wolf")
					*set Survival + 1
				*elseif (subrc = "Cat")
					*set Perception + 1
				*elseif (subrc = "Reptile")
					*set Stealth + 1
				*elseif (subrc = "Monkey")
					*set Thievery + 1
				*elseif (subrc = "Bovine")
					*set Athletics + 1
				*else
					*bug
				*set race "Yokai"
				*set subrace subrc
				*set raceadjective "yokai"
				*if (subrace != "Monkey")
					All Yokai have a tail but some ${subrace} Yokai deal with other changes to their base human form,
				*if (subrace = "Cat")
					such as cat ears and vertical pupils. You happen to have...
					*choice
						#Just a cat tail.
							With 
						#A cat tail and cat ears.
							Both are
							*set yokaitrait1 "cat ears"
						#A cat tail and cat eyes.
							Your tail is
							*set yokaitrait2 "cat eyes"
						#A cat tail, cat ears, and cat eyes.
							The whole package makes you stand out in a crowd. Your tail and ears are
							*set yokaitrait1 "cat ears"
							*set yokaitrait1 "cat eyes"
					the same color as your hair, which is...
					*choice
						#White
							*set haircolor "white"
						#Black
							*set haircolor "black"
						#Brown
							*set haircolor "brown"
						#Orange
							*set haircolor "orange"
						#Peach
							*set haircolor "peach"
					While your 
					*if (yokaitrait2 = "cat eyes")
						feline
					eyes are..
					*choice
						#Black
							*set eyecolor "black"
						#Amber
							*set eyecolor "amber"
						#Green
							*set eyecolor "green"
						#Hazel
							*set eyecolor "hazel"
						#Blue
							*set eyecolor "blue"
						#Brown
							*set eyecolor "brown"
				*if (subrace = "Wolf")
					such as wolf ears or pronounced canine fangs. You happen to have...
					*choice
						#Just a wolf tail.
							With
						#A wolf tail and wolf ears.
							Both are
							*set yokaitrait1 "wolf ears"
						#A wolf tail and pronounced canine fangs.
							Your tail is
							*set yokaitrait2 "sharp fangs"
						#A wolf tail, wolf ears, and pronounced canine fangs.
							The whole package makes you stand out in a crowd. Your tail and ears are
							*set yokaitrait1 "wolf ears"
							*set yokaitrait2 "sharp fangs"
					the same color as your hair, which is...
					*choice
						#Black
							*set haircolor "black"
						#White
							*set haircolor "white"
						#Grey
							*set haircolor "grey"
						#Brown
							*set haircolor "brown"
						#Red
							*set haircolor "red"
					While your eyes are...
					*choice
						#Black
							*set eyecolor "black"
						#Yellow
							*set eyecolor "yellow"
						#Orange
							*set eyecolor "orange"
						#Brown
							*set eyecolor "brown"
						#Blue
							*set eyecolor "blue"
						#Hazel
							*set eyecolor "hazel"
						#Green
							*set eyecolor "green"
				*if (subrace = "Reptile")
					such as reptilian eyes and a forked tongue. You happen to have...
					*choice
						#Just a thin arrowhead-tipped tail.
							With
						#A thin arrowhead-tipped tail and reptilian eyes.
							Your tail is
							*set yokaitrait2 "reptilian eyes"
						#A thin arrowhead-tipped tail and forged tongue.
							Your tail is
							*set yokaitrait1 "forked tongue"
						#A thin arrowhead-tipped tail, reptilian eyes, and a forked tongue.
							The whole package makes you stand out in a crowd. Your tail is
							*set yokaitrait2 "reptilian eyes"
							*set yokaitrait1 "forked tongue"
					the same color as your hair, which is...
					*choice
						#Black
							*set haircolor "black"
						#Green
							*set haircolor "green"
						#Red
							*set haircolor "red"
						#Brown
							*set haircolor "brown"
						#Yellow
							*set haircolor "yellow"
					While your
					*if (yokaitrait1 = "reptilian eyes")
						reptilian
					eyes are...
					*choice
						#Black
							*set eyecolor "black"
						#Brown
							*set eyecolor "brown"
						#Green
							*set eyecolor "green"
						#Orange
							*set eyecolor "orange"
						#Red
							*set eyecolor "red"
						#Grey
							*set eyecolor "grey"
						#Blue
							*set eyecolor "blue"
				*if (subrace = "Monkey")
					Unlike other Yokai types, Monkey Yokai do not suffer other animalistic traits. You've got your tail on an otherwise human body and that's it. The only other noticeable difference is your coloration may come from primates instead of the base human form. Your tail and hair in particular are...
					*choice
						#White
							*set haircolor "white"
						#Black
							*set haircolor "black"
						#Brown
							*set haircolor "brown"
						#Red
							*set haircolor "red"
					While your eyes are...
					*choice
						#Brown
							*set eyecolor "brown"
						#Black
							*set eyecolor "black"
						#Orange
							*set eyecolor "orange"
						#Yellow
							*set eyecolor "yellow"
						#Hazel-Blue
							*set eyecolor "hazel-blue"
						#Deep Blue
							*set eyecolor "deep blue"
				*if (subrace = "Bovine")
					such as a pair of horns. You happen to have...
					*choice
						#Just a tail.
							With
						#A tail and horns.
							Your tail is
							*set yokaitrait1 "horns"
					the same color as your hair, which is...
					*choice
						#Black
							*set haircolor "black"
						#Red
							*set haircolor "red"
						#White
							*set haircolor "white"
						#Shades of black [i]and[/i] white
							*set haircolor "black and white"
					While your eyes are...
					*choice
						#Brown
							*set eyecolor "brown"
						#Black
							*set eyecolor "black"
			#No, I'm something else.
				*goto Next_race
			*if (subrc = "Wolf")
				#People only think I'm a Wolf Yokai. In truth I'm a Kitsune, a fox spirit.
					Kitsune are the least common of all races as they are not quite Yokai but rather a cross of Beast, Spirit, and Man. Their mysterious essence and mischievous nature have earned Kitsune a reputation as dangers to society, far more trouble than they're worth, and many Sects do not even classify them as a race but rather as hostile trickster spirits.
					
					For this reason, your parents have masqueraded as Wolf Yokai while settling down in the safety of Thunderfall Village. Should you ever grow too powerful or live passed your first century this will be a problem when you grow additional tails that would ruin your disguise, something you've been thinking about ever since manifesting your aura for the first time.
					
					[b][Kitsune Racial Bonus: Deception +1][/b]
					
					Are you sure you and you're a Kitsune?
					*choice
						#Yes, me and my family are Kitsune.
							*set race "Kitsune"
							*set raceadjective "Kitsune"
							*set deception + 1
							As a Kitsune you're not [i]technically[/i] a Yokai, or even a Mortal, but you look the part.
							
							You've always been prone to a bit of trickery and the best so far is your Wolf Yokai "disguise", because the disguise is you walking around in broad daylight and just calling yourself a Wolf. A single-tailed kitsune looks strikingly similar to a Wolf Yokai, although obviously better looking in your opinion.
							
							Just like the Yokai you're born with a fluffy tail, but only some Yokai have ears and fangs while every Kitsune is blessed with such traits. You're able to hide the sharp teeth and ears with a minor natural talent in illusions that you've (so far) only been able to use for that one purpose.
							
							That's not to say you [i]do[/i] hide them. Your base form is made of...
							*choice
								#Just a single fox tail.
									With
								#A fox tail and fox ears.
									Both are
									*set yokaitrait1 "fox ears"
								#A fox tail and pronounced canine fangs.
									Your fox tail is
									*set yokaitrait2 "sharp fangs"
								#A fox tail, fox ears, and pronounced canine fangs.
									You hide nothing, and why should you? Your Kitsune form is [b]glorious[/b]. Your tail and ears are
									*set yokaitrait1 "fox ears"
									*set yokaitrait2 "sharp fangs"
							the same color as your hair, which is...
							*choice
								#Red
									*set haircolor "red"
								#White
									*set haircolor "white"
								#Black
									*set haircolor "black"
								#Golden
									*set haircolor "golden"
							While your eyes are...
							*choice
								#Amber
									*set eyecolor "amber"
								#Brown
									*set eyecolor "brown"
								#Blue
									*set eyecolor "blue"
								#Green
									*set eyecolor "green"
						#No, we're something else
							*goto Next_race

You close your ${eyecolor} eyes and brace for impact from the burning Technique being launched behind you. The glow is so bright that it must be the entire Sect launching blasts at your exhausted body.

...Wait.

If it's an attack using chi, and as a Martial Artist you can sense chi, then why can't you sense anything behind you?

Slowly you open your eyes and turn around to see the source of the orange glow matching the light and fire auras of the Sunbringer Sect Martial Artists: the dawn.

It's just the damn sunrise, behind you to the east. You must have run through the entire night.

Tension melts off your shoulders and you laugh in the face of your death that never came. How oddly freeing. You take a drink of the puddle in front of you and rest for two minutes before rising on shaky legs and continuing your march home.

It's time to turn in your mission.

*page_break

*image https://www.auraclash.com/assets/img/childhood_village.jpg

Life in the forested mountain-village of Thunderfall is an easy one, and quite comfortable, but it comes at a cost. The Martial Artists of the Thunderfall Sect make heavy demands of the village as its ruling Caste, lead by a massive warrior from foreign lands named Crusher Mao.

It's hard for you to like Crusher Mao, or his lookalike son Crusher Jack. They don't like you either.

Your ${raceadjective} family consists of yourself, your parents, and the younger twins Rin and Jin. You descend from members of the Laborer Caste, those born to work crafts and menial labor for the good of the Warrior Caste and Noble Caste. Never one to accept your fate, you worked tirelessly to master the basics of the Martial Arts to elevate your family into the Warrior Caste, but no matter how hard you worked it never seemed enough to catch up to your peers born into the role.

Crusher Jack and his friends bullied you about it relentlessly, calling you a Laborer for most of your childhood until your training finally paid off and you Advanced...in the middle of a fight with Jack.

He was already a Martial Artist by that point, toying with you. He already had an aura and his own burgeoning chi powers, so you held nothing back. That day, when your body glowed with white chifire for the first time, your fist crashed into Jack's jaw and launched his whole body ten feet back into a cliffside as if you'd fired him from a cannon.

You spent that following winter working for the local baker to make up for the damages to his wall.

Jack hasn't forgiven you for embarrassing him.

Neither has his father.
*page_break
Magistrate Khan is the one who saved you from reprisal.

He's a wizened old man with a long thin beard who appeared ancient before you were born, and his job is to administer the people of your village. Crusher Mao demanded that Khan punish you to the full extent of the law for bringing shame to his son. His excuse was that the Thunderfall Sect couldn't be seen losing to a Laborer peasant.

Magistrate Khan agreed, and indoctrinated you into the Thunderfall Sect as a new member of the Warrior Caste. The dispute was resolved, he claimed, as the Thunderfall Sect now technically won that fight.

Crusher Mao did not take that well. After your winter of baking reparations had finished Master Mao gave you an initiation mission to prove yourself like all Thunderfall Sect disciples were forced to do.

That was three days ago.

Your life's been changed so quickly that your body has barely had time to adjust to your first Advancement, the rejuvenating process that unlocked your aura, chi powers, and latent potential for one of the Martial Arts.

It turns out your spirit was attuned to have...
*gosub_scene chapter1 Next_potential

You're suspicious that Master Mao's mission for you was a suicide mission, being ordered to go to a rival Sect's territory and burn one of their warehouses of Soul Treasures and supplies. And yet you've succeeded. The bastards deserved it too, most of those supplies were stolen from your village.

You waltz up to the town gates victoriously and nod to the two guards at the gate.

"Hold it." Says one of the guards, an unpowered man in splint mail armor, "I recognize your uniform, traveler, but not your face. State your name and Clan."
*if (heshe = "he")
	*if (race = "Oni")
		*goto Next_Boyname_Oni
	*elseif (((race = "Human") or (race = "Yokai")) or (race = "Kitsune"))
		*goto Next_Boyname_Human
	*else
		*goto Next_Boyname_Lunargoth
*else
	*if (race = "Oni")
		*goto Next_Girlname_Oni
	*elseif (((race = "Human") or (race = "Yokai")) or (race = "Kitsune"))
		*goto Next_Girlname_Human
	*else
		*goto Next_Girlname_Lunargoth

*label Next_Boyname_Human
*choice
	#Ronin
		*set name "Ronin"
	#Genji
		*set name "Genji"
	#Kenzo
		*set name "Kenzo"
	#Xin
		*set name "Xin"
	#Ryuu
		*set name "Ryuu"
	#Something else [Enter Name]
		*input_text name
*goto Next_Chap2Clan

*label Next_Boyname_Lunargoth
*choice
	#Roderic
		*set name "Roderic"
	#Cade
		*set name "Cade"
	#Evander
		*set name "Evander"
	#Bremet
		*set name "Bremet"
	#Godwin
		*set name "Godwin"
	#Something else [Enter Name]
		*input_text name
*goto Next_Chap2Clan

*label Next_Boyname_Oni
*choice
	#Brand
		*set name "Brand"
	#Soren
		*set name "Soren"
	#Vox
		*set name "Vox"
	#Kozael
		*set name "Kozael"
	#Aoyin
		*set name "Aoyin"
	#Something else [Enter Name]
		*input_text name
*goto Next_Chap2Clan

*label Next_Girlname_Human
*choice
	#Jade
		*set name "Jade"
	#Mira
		*set name "Mira"
	#Kiyoko
		*set name "Kiyoko"
	#Akane
		*set name "Akane"
	#Sakura
		*set name "Sakura"
	#Something else [Enter Name]
		*input_text name
*goto Next_Chap2Clan

*label Next_Girlname_Lunargoth
*choice
	#Eve
		*set name "Eve"
	#Luna
		*set name "Luna"
	#Aurora
		*set name "Aurora"
	#Violet
		*set name "Violet"
	#Nessa
		*set name "Nessa"
	#Something else [Enter Name]
		*input_text name
*goto Next_Chap2Clan

*label Next_Girlname_Oni
*choice
	#Ozra
		*set name "Ozra"
	#Ember
		*set name "Ember"
	#Lilith
		*set name "Lilith"
	#Ansila
		*set name "Ansila"
	#Eyri
		*set name "Eyri"
	#Something else [Enter Name]
		*input_text name
*goto Next_Chap2Clan

*label Next_Chap2Clan
"It's $!{name}," You say to the guard who has a plot right next to yours in the communal gardens, "You really don't recognize me?"

"I can't be expected to recognize every face. State your Clan."
*if (((race = "Human") or (race = "Yokai")) or (race = "Kitsune"))
	*choice
		#Kazurai
			*set Clan "Kazurai"
		#Akira
			*set Clan "Akira"
		#Maki
			*set Clan "Maki"
		#Saitomoto
			*set Clan "Saitomoto"
		#Hakura
			*set Clan "Hakura"
		#Something else [Enter Clan Name]
			*input_text Clan
*elseif (race = "Oni")
	*choice
		#Ammon
			*set Clan "Ammon"
		#Sin
			*set Clan "Sin"
		#Valoren
			*set Clan "Valoren"
		#Hellfire
			*set Clan "Hellfire"
		#Magnus
			*set Clan "Magnus"
		#Something else [Enter Clan Name]
			*input_text Clan
*else
	*choice
		#Jaeger
			*set Clan "Jaeger"
		#Novak
			*set Clan "Novak"
		#Vulcan
			*set Clan "Vulcan"
		#Hyperion
			*set Clan "Hyperion"
		#Sieghart
			*set Clan "Sieghart"
		#Something else [Enter Clan Name]
			*input_text Clan

Humans and most Yokai normally say their Clan name first and then their given name, but Lunargoths and most Oni normally say their given name first and then their Clan name.
*set clan "$!{clan}"

Your Clan in particular pronounces it...
*choice
	#${clan} $!{name}
		*set japannaming true
		*set fullname "${clan} $!{name}"
		${clan} $!{name}, it has a nice ring to it.
	#$!{name} ${clan}
		*set japannaming false
		*set fullname "$!{name} ${clan}"
		$!{name} ${clan}, it has a nice ring to it.
	#Go back
		*goto Next_Chap2Clan

"Oh! The kid from the baker's incident," says the second guard, who you detect a hint of power from. "you were away on mission, correct? The clerks will want to speak to you. Go report in to the Grand Pagoda."

The Grand Pagoda is easy enough to find, it's the only six-story building in town and wide enough to fit multiple houses per floor. Plus it's the centerpiece of the town's market square.

The top two floors are forbidden, they belong to the Magistrate and his sage who advises him on all things mystical. Below that is the library, and two floors below that are locked barracks that belong to the Thunderfall Sect. The bottom floor is a large hall with desks lining walls where clerks hear complaints or requests of the common folk. It's this floor where you find yourself talking to some stuttering new clerk who looks about your age.

*page_break

"It-it-it's good to see you r-r-return, Disciple." says the clerk in glasses.

"It's good to be back," you say, trying to appear nonchalant. "I've finished the mission to burn down the Sunbringer warehouse. Mao said to report to the dojo when I'm done but I'm not really sure where that is."

"The initiation trial, corr-rect?" He walks to someone else's desk, exchanges whispers, and comes back with a scroll that he unrolls. With brush and ink in hand, he records your successful mission. "I'm pleased to w-w-welcome you to the Thunderfall Sect. Now that you've c-completed your initiation mission you're to be given a set of combat gi and this-"

He hands you a shining golden rock the size of your palm, layered in handseal sigils around its center. A keystone to bypass mystic locks. "This k-keystone will let you enter the dojo tomorrow, after we add its chi signature to the d-d-door's seal."

The two of you stare at each other for an awkward moment.

"Is th-there anything else?" He asks.

"Yeah, where is the dojo?"

"Oh," he leans in and whispers, "second floor."

*page_break

You head back home for a well-deserved bath.

Mother and Father's house wasn't much to look at but you had your own bedroom and the twins didn't, which meant all was well in the world.

"I'm home!" You shout as you enter, clothes caked in dirt and sweat. From the kitchen you can hear Rin and Jin arguing over who has to skin a hare for dinner. Mother peaks out and sees you. "$!{name}, you're home! I was so worried!" She runs up to hug you with one hand while still holding Rin and Jin by the ear with the other.

Rin's been keeping her hair shorter lately, like a dusting brush, and you've heard through the grapevine that she's trying to steal the boyfriend of some short-haired Thunderfall Sect girl.

*set val (age - 2)
Jin on the other hand has shaved his head since you went away. Weird. He looks tougher but his neck isn't thick enough to pull it off. He has time, they're both only ${val}.
*set val 0

Your first Advancement that unlocked your capacity for chi-enhanced Martial Arts probably got them both jealous and their hair paid the price. 

While you'd be happy for them if they Advance too, it wouldn't be a bad thing if Jin fails. Father had been training you in the family business for years, and now that you're a student of the Thunderfall Sect your younger brother will be needed to replace your apprenticeship as a...

*choice
	#Blacksmith
		*set craft + 2
		*set background "Blacksmith"
		*set itemtanto 100000000
		*set powexp + 10
		*set forexp + 10
		*set agiexp + 5
		*set solexp + 5
	#Herbalist
		*set alchemy + 2
		*set background "Herbalist"
		*set healingelixir + 1
		*set powexp + 10
		*set forexp + 5
		*set agiexp + 5
		*set solexp + 10
	#Merchant
		*set persuasion + 2
		*set background "Merchant"
		*set shards + 40
		*set powexp + 5
		*set forexp + 5
		*set agiexp + 10
		*set solexp + 10
	#Trapper
		*set survival + 2
		*set background "Trapper"
		*set powexp + 5
		*set forexp + 10
		*set agiexp + 10
		*set solexp + 5
Speaking of the resident ${background}...

"There, I did it my own damn self!" shouts Father from the backyard. He enters the house, hands covered in rabbit blood and a scowl on his face, until he sees you. The gruff old bastard smiles from ear to ear when he sees his prodigal ${sondaughter} returned home. "My ${sondaughter}, the Warrior! I knew you'd make it, I told you all, didn't I?" He says to the others, "Bring it in here!"

You're a Martial Artist and faster than normal humans. Your father is not. Yet his bloody-handed hug catches you before you can react. "I won't say I was worried, didn't have a doubt in my mind, but I will say I'll sleep better now that you're back. And-...oh."

"Yes, I noticed too." says Mother looking apologetic.

"Noticed what?" Asks you and Jin.

"That you STINK!" Shouts Rin covering her nose. Mother does too, albeit with a more sympathetic expression.

You suppose you could use a bath...

*page_break
*set powspent 0
*set forspent 0
*set agispent 0
*set solspent 0
*set chispent 0
*set wounds 0

After a good twenty minutes of fetching water from the river, filling the tub, and setting a fire under it, you finally disrobe in the bathtub and throw your soiled gi into the trash rather than the hamper. It's a beginner's gi and you'll be getting a real one tomorrow.

A quick dip into the hot bath soothes your aching muscles and washes away the rest of the grime that you couldn't get out in the river. No idiot would ruin a drawn bath by going in filthy.

Several minutes of scrubbing and relaxing pass and you look down at your body, marveling how the Advancement process seems to have aged you a couple years in the best possible way.

*if (heshe = "he")
	As a man you've grown into your full physique that's most noticeably...
	*choice
		#Lean and agile, like a wolf. [Increase Athletics]
			*set athletics + 1
			*set bodytype "Agile"
		#Large and muscular, like a warrior. [Increase Survival]
			*set survival + 1
			*set bodytype "Muscular"
		#Defined and handsome, like a prince. [Increase Persuasion]
			*set persuasion + 1
			*set bodytype "Handsome"
		#Short and stocky, like a builder. [Increase Craft]
			*set craft + 1
			*set bodytype "Manlet"
			*if not (jadedragonfoundation)
				*achieve kingofdwarves
*elseif (heshe = "she")
	As a woman you've grown into your full physique, most noticeably with...
	*choice
		#A runner's build with shapely legs. [Increase Athletics.]
			*set athletics + 1
			*set bodytype "Legs"
		#A lean and petite build. [Increase Stealth]
			*set stealth + 1
			*set bodytype "Petite"
		#An eye-catching hourglass figure. [Increase Persuasion]
			*set persuasion + 1
			*set bodytype "Hourglass"
		#More muscle than I ever expected! [Increase Craft]
			*set craft + 1
			*set bodytype "Dommymommy"
		*if (subrace = "Bovine") and (heshe = "she")
			#The need for a bigger bra. A MUCH bigger bra. [Requires Female Bovine Yokai] [Increase Persuasion and Deception]
				*set deception + 1
				*set persuasion + 1
				*set bodytype "Bodacious"

Your body isn't the only thing that's grown. Unkempt ${haircolor} hair has grown passed your waist from the transformation's rapid maturity. You've kept it like this for your mission but now you decide to...
*choice
	#Keep it that long.
		*set hairlength "Waist"
	#Keep it that long and tie it back.
		*set hairlength "Long Tied"
	#Cut it to chest-length.
		*set hairlength "Chest"
	#Cut it chest-length and tie it back.
		*set hairlength "Medium Tied"
	#Cut it to shoulder-length.
		*set hairlength "Shoulder"
	#Cut it to shoulder-length and tie it back.
		*set hairlength "Short Tied"
	#Cut it short.
		*set hairlength "Short"
	*if (alchemy >= 1)
		#Cut it short and spike it up with alchemical treatments.
			*set hairlength "Spiked"
			[b][Your continuous use of alchemical preparation each morning has improved your understanding of cultivation.][/b]
			*line_break
			[b][Aura Pressure + 2][/b]
	*if (heshe = "he") #Cut it down to a mere quarter-inch.
		*set hairlength "Buzz"
	*if (heshe = "he") #Shave it all off.
		*set hairlength "Bald"
*if (heshe = "he")
	More than just the hair on your head, the hairs of your face have come in. The beard hasn't grown as much as your hair has but whether you let it grow out or trim it down, the time to shape it is now. You decide to...
	*choice
		#Grow out a long beard.
			*set beardlength "long"
		#Grow out a long beard and braid it.
			*set beardlength "long braided"
		#Grow out a modest beard.
			*set beardlength "medium-length braided"
		#Grow out a modest beard and braid it.
			*set beardlength "medium-length braided"
		#Keep a short beard.
			*set beardlength "short"
		#Trim it to a goatee.
			*set beardlength "goatee"
		*if (race = "Lunargoth")
			#Trim it to just the mustache.
				*set beardlength "mustache"
		*if (race = "Oni")
			#Trim it to a sharp goatee with twirled mustache.
				*set beardlength "devilish goatee"
		*if (race = "Human")
			#Trim it to a fu manchu mustache.
				*set beardlength "fu manchu"
		#Shave it clean.
			*set beardlength ""

With a towel wrapped around
*if (heshe = "he")
	your waist
*elseif (heshe = "she") and ((hairlength != "Short") and (hairlength != "Spiked"))
	your torso and another for your hair,
*else
	your torso
you head back to the kitchen to enjoy a nice meal with your family. You'll need the food and the rest, tomorrow's going to be a big day.

*if (jadedragonfoundation)
	*set alchemy + 1
	*set athletics + 1
	*set craft + 1
	*set deception + 1
	*set handseals + 1
	*set insight + 1
	*set lore + 1
	*set perception + 1
	*set persuasion + 1
	*set stealth + 1
	*set survival + 1
	*set thievery + 1
*else
	But it's harder to fall asleep than you expected.
	
	*label Next_skillgain
	You keep your eyes closed and meditate to pass the time, focusing on all your lessons in life and the skills they have brought you. All of them will be needed for your journey ahead.

	In particular, you're thankful that you picked up some tricks in...
	
	*set val (11 - skillgain)
	*if (val > 1)
		[b][${val} Choices Remaining][/b]
	*else
		[b][${val} Choice Remaining][/b]
	*choice
		*selectable_if (alchemy <= 2) #Alchemy
			*set alchemy + 1
		*selectable_if (athletics <= 2) #Athletics
			*set athletics + 1
		*selectable_if (craft <= 2) #Craft
			*set craft + 1
		*selectable_if (deception <= 2) #Deception
			*set deception + 1
		*selectable_if (handseals <= 2) #Handseals
			*set handseals + 1
			*gosub_scene quicks fuuinjutsudescription
		*selectable_if (insight <= 2) #Insight
			*set insight + 1
		*selectable_if (lore <= 2) #Lore
			*set lore + 1
		*selectable_if (perception <= 2) #Perception
			*set perception + 1
		*selectable_if (persuasion <= 2) #Persuasion
			*set persuasion + 1
		*selectable_if (stealth <= 2) #Stealth
			*set stealth + 1
		*selectable_if (survival <= 2) #Survival
			*set survival + 1
		*selectable_if (thievery <= 2) #Thievery
			*set thievery + 1
	*set skillgain + 1
	*if (skillgain <= 10)
		*goto Next_skillgain
Rest finally takes over and you dream of great battles and greater fame.

In the morning, your new life awaits.
*page_break The next day...
*goto_scene chapter2 chapter2start