*comment REMOVE *save_checkpoint
*temp val 0
*temp kosukecrossbow false
*temp explosives 0
*temp kosukeinjured false
*temp capturedbandits 20
*temp tomeuse 0
*temp clue 0
*temp hustle false
*temp skipheartbeat false
*if (heshe = bffheshe)
	*set bffromance 0
*set chapter 2.2

*image https://www.auraclash.com/assets/img/ac-linebreak-top.png

[b]Mission Report:[/b] Bandit Uprising

[i]Several farmers in the valley south of Thunderfall Village have gone missing in the past month. Most empty farms have been ransacked of valuables and no noticeable Aura Pressures have been detected in the area. Current suspicion is widespread banditry.

[b]Objective:[/b] End the disappearance threat permanently.
*line_break
[b]Secondary Objective:[/b] Return or replace the lost farmhands.
*line_break
[b]Mission Rank:[/b] C

*image https://www.auraclash.com/assets/img/ac-linebreak-bottom.png

Crusher Mao stands resolutely, staring down at you with that wicked grin and waiting for your reaction. The menacing glint in his eye floods your mind with memories of the day he sought to enslave your family last year.

Hells, your first guess is that Mao took the poor farmers.

*choice
	#"Is there anything else I should know?"
		*set honor + 1
		*set maorep + 3
		"Is there anything else I should know?" You ask, alone with Commander Mao. 
		
		"Yes," Mao says with a dismissive wave, as if you passed some test, "don't show weakness to anyone you talk to. Beasts and spirits don't rob houses much so the problem should be people; either desertion or bandits that think they can take on the Thunderfall Sect. The clerks say there's no report of Aura Pressure or Techniques but I don't buy it. Regular people should be too scared to do this. Someone has a trick up their sleeve. Find it."
		*set val 411
		*page_break
	#"Consider it done."
		*set honor + 3
	#"Beat up some bandits? Nice."
		*set ruthless + 1
		*set maorep + 5
		"So I'm supposed to beat up some unpowered bandits?"
		
		"Probably." Mao replies. "You're likely to break some limbs since they don't have auras."
		
		"Nice."
		
		"Niiice." Crusher Mao says back. It's the only time in your life you've understood each other.
		
	#"No, do your own dirty work."
		*set ruthless - 3
		"Do your own dirty work." You say defiantly.
		
		"What was that?" Mao asks with glee. "Did you just talk back to your Master?"
		
		Your chi cycles quickly but not quickly enough to stop his gut punch. The man takes one long stride forward and slams his enormous fist into your torso.
		
		*if (jadedragonfoundation)
			*set apval 10
		*else
			*set apval 2
		*gosub_scene quicks aploss
		
		Both your breath and your breakfast leave your mouth. You crumple to the ground where Mao crouches down and grabs you by the head, lifting you up so his eyes can meet yours. "You're a Sect member now. I don't know why you thought that made you tough or special, but what it really makes you is [i]mine[/i]. When I give you an order, you do it. When I give you a mission, you do it. If this mission isn't done within the month I will personally sell your siblings into slavery, seperately, and far away from here."
		
		He spits in your eye once for good measure and leaves.
		*set val 78
		*page_break
*set wounds 0
*set agispent 0
*set forspent 0
*set powspent 0
*set solspent 0
*set chispent 0
*if (val = 78)
	After half an hour of calming down and obliterating a wooden target dummy with your fists, you spend another next three hours packing up and getting halfway down the road to the southern valley farms.
*else
	Three hours later you're all packed up and halfway down the road to the southern valley farms. 

Father was busy
*if (background = "Trapper")
	setting traps
*elseif (background = "Herbalist")
	gathering herbs
*elseif (background = "Blacksmith")
	working the forge
*elseif (background = "Merchant")
	running the shop
with Jin so it was surprisingly Rin who provided your journey's supplies by pestering the neighbors until one agreed to lend you a cart and donkey. You sit in the cart's front seat, holding a carrot on a stick, as the donkey continues onward and drags you through the forested karst hills to your goal.

You're not sure if the carrot-and-the-stick bit actually works, or if the donkey is just being professional about it. He seems a veteran of the cart-hauling profession with no love for small talk so your journey towards the lower valley is quiet and peaceful.

Until you hit a bump, hear a groan from the back, and roll your eyes. No one was under the cart's tarp when you packed it but you'd recognize that groan anywhere.

"Come on out, Kosuke."
*page_break
*if ((firstchapter = 2) and (kosukeaura = false))
	Kosuke has been your best friend since childhood. A partner in crime for your earlier antics, a friend who was always there for you when things were down, and a scrappy fighter that helped you train up to your first Advancement.
	
	But to the rest of the village, Kosuke is just...
	*choice
		#The beggar's daughter.
			*set bffhimher "her"
			*set bffhisher "her"
			*set bffhishers "hers"
			*set bffheshe "she"
			*if (portraitpics)
				*image https://www.auraclash.com/assets/img/Kosuke-F.jpg
		#The beggar's son.
			*set bffhimher "him"
			*set bffhisher "his"
			*set bffhishers "his"
			*set bffheshe "he"
			*if (portraitpics)
				*image https://www.auraclash.com/assets/img/Kosuke-M.jpg
	
	Which is why ${bffheshe} has so much free time. In the end ${bffhisher} poverty and Clanless station is a blessing in disguise. Kosuke's free time all these years has meant the two of you could constantly train after your workday with Father ended. On days off you both hunted down hundreds of rumors of spirit-enhancing opportunities, about four of which even turned out to be true.
*elseif (kosukecombat < 2)
	*if (bffheshe = "she")
		*if (portraitpics)
			*image https://www.auraclash.com/assets/img/Kosuke-F.jpg
	*else
		*if (portraitpics)
			*image https://www.auraclash.com/assets/img/Kosuke-M.jpg

Kosuke peaks out from under the canvas covering your cart. "Are we there yet?"

"Halfway." You say.

"Well what's the mission?" ${bffheshe} crawls out of the tarp and sits down
*if (bffromance >= 1)
	next to
	*if (bffheshe = "she")
		you, holding your arm. She feels warm.
	*else
		you, placing his arm over your shoulder.
*else
	across from you.

"People disappearing at the southern farms. Looks like bandits."

"Oh that's easy enough, the farmers are probably all dead." $!{bffheshe} grabs ${bffhisher} throat and mock-dies. "Let's sell the farms to the bandits. Then we'll have farmers that can actually fight, plus we can inflate the prices and keep the change."

*choice
	#"Let's get down there and figure out what's going on before turning my first big mission into an extortion ring."
		*set honor + 4
		You look
		*if ((bffheshe = "she") and (bodytype != "Petite"))
			down
		*if ((bffheshe = "he") and ((bodytype = "Manlet") or (heshe = "she")))
			up
		at ${bffhimher} doubtfully. "Incredible diplomacy skills, I'm sure bandits would love hard labor."
		
		"Hey, crime is harder than I make it look."
		
		You shake your head. "Let's get down there and figure out what's going on before turning my first big mission into an extortion ring."
	#"Hm...Might work."
		*set honor - 1
		*set hustle true
		"Hm...Might work." You say. "I could use the Shards, cultivation costs a fortune."
	
$!{bffheshe} nods
*if (hustle)
	*if (bffheshe = "she")
		eagerly
	*else
		confidently
*else
	reluctantly
and rests ${bffhisher} head
*if ((bffromance >= 1) and (bffheshe = "she"))
	on your lap.
*else
	back.
"You're the Boss. Wake me when we get there."
*page_break
*temp farmhandcollab false
*temp clues 0
Reaching the southern valley reveals a sanctuary of emerald-green fields amidst the rugged peaks that extends for miles. Majestic mountains stand as silent sentinels around the valley border, sheltering it from harsh winds and embracing it with a sense of tranquility. The sprawling fields, meticulously irrigated by a network of canals, reflect the tireless efforts of farmers who have transformed this rugged terrain into an agricultural paradise.

And there's trouble in paradise.

You and Kosuke dismount at the first farm, a rice field, and approach the farmhouse only to find its lock broken and no inhabitants inside. You've already reached the crime scene. The two of you look for clues while your donkey is tied around a tree as, quite frankly, you don't know how to park a donkey.
*label cluefarm
*set clue + 1
*if (clue = 4)
	*goto nextfarm
*choice
	*disable_reuse #Check the fields.
		The rice fields are useless and wet, giving you nothing but mud soaked into your boots, but the abutting field of taro and adzuki beans proves useful in more ways than one. Not only do you find a free lunch from the abandoned crops, you also find-
		
		*if (survival >= 1)
			[b][Survival 1 Check Passed][/b]
			*line_break
			[b][Aura Pressure +1][/b]
			*set aurapressure + 1
			
			Signs of a scuffle in the field. From the footprints it seems a fight broke out here where multiple men took out one poor sap, likely the abductors or bandits beating a farmhand. There are also two distinct tracks of people being dragged from inside the house by these same attackers. From what you can tell, they were dragging the farmer and his wife out of the house when the farmhand intervened and paid for it.
			
			*if (survival >= 2)
				[b][Survival 2 Check Passed][/b]
				*line_break
				[b][Aura Pressure +2][/b]
				*set aurapressure + 2
				*label fieldclue
				
				Upon closer inspection, the field shows [i]fake[/i] signs of a struggle. The farmhand working the field seems to have pretended to fight, or at least pretended to be injured. His knee imprints are deeper than the rest of his body and so are both of his hand imprints. No one falling over from being attacked actually falls in perfect form like that, he braced his fall completely, afraid of hurting himself.
				
				From the looks of things, he was working with the bandits and they pretended to attack him to keep up the ruse. All to fool the farmers...or the investigator.
				
				[b][Clue Obtained: Farmhand Collaboration][/b]
				*set farmhandcollab true
			*elseif (perception >= 1)
				[b][Perception 1 Check Passed][/b]
				*line_break
				[b][Aura Pressure +1][/b]
				*set aurapressure + 1
				*goto fieldclue
		*else
			[b][Survival 1 Check Failed][/b]
			
			A free dinner for later. No clues though. Clues would have been nice.
		*goto cluefarm
	*disable_reuse #Check the barn.
		Two shrieks assault your ears when you open the barn door. One is the rusted hinges of the large barn door and the other is a young boy around ten years of age who's shivering with fear while holding a crossbow pointed directly at your stomach.
		
		*choice
			#Calm the boy down.
				*set ruthless - 3
				"Easy now," you say in your most soothing voice. "I'm not going to hurt you."
				
				*if (persuasion >= 1)
					[b][Persuasion 1 Check Passed][/b]
					*line_break
					[b][Aura Pressure +1][/b]
					*set aurapressure + 1
					
					The boy gently lowers the crossbow. "You promise?"
					
					"I promise. My name is ${fullname}, I've come from the Thunderfall Sect to stop the disappearances. Can you tell me what's been happening?"
					
					The boy sniffs, wipes his snotty nose on his wrist, and nods. "I saw em take ma and pa, six scary men."
					
					"Did you see where they went? What they were wearing? Did they say anything useful?"
					*goto noclues
				*else
					[b][Persuasion 1 Check Failed][/b]
					
					The boy stumbles back in fear of your menacing outline against the blinding morning light filling the barn from the newly opened door. His crossbow fires a single bolt at too close a range to dodge, striking your midsection.
					
					*goto getshot
			#Rip the crossbow out of his hands.
				The boy cries out as you reach for his crossbow. You callously rip it out of his hands just as he pulls the trigger and fires at your midsection.
				
				*label getshot
				*if (an = "arrowcatch")
					[b][Special Event: Arrow Catching][/b]
					*set agiexp + 5
					
					Memories flash through your mind of catching arrows under Big Chu's training. Your hand snatches the arrow midair before it grazes your shirt and
					*goto waitpls
				*if (fortitude = 1)
					[b][Fortitude 3 Check Failed][/b]
					
					Oh no. Oh no that's not supposed to be there. Both you and the little boy stare bewildered at the bolt sticking out of your chest and the blood shooting out of your wound around it. Daaaaaaamn. That's right in your heart.
					
					*gosub_scene quicks woundcheck 1 false false
					
					Kosuke's voice comes in from behind the barn. "Hey $!{name} I thought I heard something." $!{bffheshe} runs in to see you standing there with a bolt in your chest. "HELLS! Does...Does that hurt?"
					
					"Much." You say through gritted teeth. Then with a pained twist
					*goto waitpls
				*else
					*set combatdiff 3
					*set combatstat "fortitude"
					*gosub_scene quicks combatcheck
					
					The bolt bounces off your skin and
					*label waitpls
					you look down on the child with judgment.
					
					"P-Please don't hurt me!" He shrieks, "I'd make a great slave instead!"
					
					You still haven't decided how to pay him back for shooting you but something he said perks your interest. "Slaves? What's this about slaves?"
					
					"The...I mean, aren'tcha with the slavers? The ones that took ma and pa?"
					
					"I'm with the Thunderfall Sect, so I fight these 'slavers'. Do you know where they went?"
					
					The boy's face lights up at the news but then reverts to sadness.
					*label noclues
					"N-No
					*if (heshe = "he")
						sir,
					*else
						ma'am,
					I'm afraid I don't know nothin about that. I mean, I did see Ole Darin among the raiders. He's a farmhand at the Sai Farm down the road so maybe you can get clues there?"
					
					"That's perfect, I'll go check with them. You wait here and I'll send someone to pick you up when it's safe."
					
					The boy nods eagerly as you leave, but his paranoia hasn't died down. He closes the barn doors behind you.
		*goto cluefarm
	*disable_reuse #Check the house.
		The farmer's house contains only two rooms. One holds a well-stocked pantry and multiple tables covered in supplies for preserving herbs and pickling vegetables, and the other room has a slightly elevated floor with tatami mats for sleeping.
		
		Kosuke is gorging ${bffhimher}self in the pantry while you look for clues.
		
		*if (perception >= 1)
			[b][Perception 1 Check Passed][/b]
			*line_break
			[b][Aura Pressure +1][/b]
			*set aurapressure + 1
			
			Sure enough, there's a bloodstain by the beds but not enough for a head wound. A broken nose probably. Seems the farmers were attacked in their sleep and taken prisoner, or taken hostage.
			
			One other detail sticks out to you: When you move the farmer's tatami mat you find a lockbox built into the floor, facing up. The mad farmer must have the worst back pain in all of the Thunderfall territories to sleep on top of this every night and yet he did, all to cleverly hide his valuables from prying eyes like yours.
			
			*choice
				#Leave the man's belongings behind.
					*set honor + 4
					*set ruthless - 1
					Some things just aren't right, like robbing a man you were sent to save. You leave the house with Kosuke as ${bffheshe} whines, finally noticing the safe and having to be dragged out by ${bffhisher} collar.
					
					"But it's free money!" Kosuke says for the third time.
					
					"It's not free and it's not ours. It belongs to a hardworking man that may need our help."
					*set forexp + 5
				#Crack into the lockbox.
					*set honor - 2
					*if (thievery >= 1)
						[b][Thievery 1 Check Passed][/b]
						*line_break
						[b][Aura Pressure +2][/b]
						*set aurapressure + 2
						
						With a flourish you grab tools from the kitchen and begin tinkering with the box's lock. They're not ideal lockpicks but they serve your purpose for such a crude lock. The device clicks open and you pocket the uncut gold nuggets inside. The farmer must have found them over years of digging through so much land in the mountains.
						
						[b][Item Gained: 11 Gold][/b]
						*set gold + 11
					*else
						[b][Thievery 1 Check Failed][/b]
						
						With a flourish you grab tools from the kitchen and Kosuke looks at you with a shake of ${bffhisher} head. "Come on, you know that's not going to work."
						
						"It could work." You say defiantly as you run over to the lockbox and try to crack the lock. Forty minutes of tinkering later you give up and motion to punch the damn thing with all your might before Kosuke stops you.
						
						"Come on," ${bffheshe} says, withdrawing a collection of proper lockpicks from ${bffhisher} pants, "you brought a criminal with you for a reason."
						
						"I didn't bring you with me." You correct while Kosuke cracks the lock in seconds.
						
						$!{bffheshe} looks over to you with a grin and hands you 6 gold nuggets. "But aren't you glad I came along anyway?"
						
						[b][Item Gained: 6 gold][/b]
						*set gold + 6
		*else
			[b][Perception 1 Check Failed][/b]
		
			"Damn." You say after searching the small house thoroughly. "Nothing."
			
			"Speak for yourself." Kosuke says through a mouthful of pickled daikon. "I found a treasure trove of flavor."
			
			$!{bffheshe} hands the jar to you and you sigh, taking a pickled treat out and biting into it. Hm. Pretty good.
		*goto cluefarm

*label nextfarm
*page_break
The trip to the Sai Farm passes by over a dozen likewise abandoned farms and you begin to wonder if there's anyone left in the valley at all. With gusto your donkey hauls you through a large persimmon orchard with one wide road leading through the trees to your destination, all the while it eyes the bountiful trees hungrily. The wagons of your cart roll down that road without issue and you tie your donkey to a nearby tree once again when you come in sight of the Sai Farmhouse, this one substantially larger than the last. The donkey reaches up for a ripe persimmon as you leave.

You and Kosuke approach the two-story farmhouse and find it guarded from the inside by three men with knives leering through a window. They refuse to open up until you announce you're from the Thunderfall Sect.

"The Martial Artists up the mountain have finally sent one of their own? Well why didn't you say so!" The door shoots open immediately and reveals a balding farmer in his mid 40s. "Come in stranger, please come on in. We've been on edge ever since the disappearances got serious a few weeks back." He snaps his fingers at the other two, his farmhands, "go and get our guests some tea, and bring out the spirit fruits."

"But we've only got-" protests a farmhand.

"I don't care what we've got, you bring it out!" He shakes his head after the two farmhands leave to the kitchen. "I apologize, good help is hard to find."

"Speaking of help," you say as you enter, "I'm looking for someone named Ole Darin."

"I'd hope so, bastard tried to kill us."

Your eyebrows involuntarily raise. "Go on."

The farmer walks with you to the dining room while you two talk. "A few nights back, Ole Darin comes up to us in the fields with sword in hand. Bastard says he's been given a new job in some crew and we could either join or become part of the 'merchandise'. Probably talking about slavery." The farmer spits on the ground. "Damn fool thought he was so tough with a real sword for once. Forgot it was three against one. We buried him out back."

*if (insight >= 2)
	[b][Insight 2 Check Passed][/b]
	*line_break
	[b][Aura Pressure +3][/b]
	*set aurapressure + 3
	
	You prepare for trouble, because he's lying.
	*set farmhandcollab true

Kosuke slinks through the doorway and sits down at the dining room table.

"So it's a recruiting gang after all. Did he say anything else?" You ask, taking a seat next to
*if ((insight+perception) >= 2)
	Kosuke and pretending to fall for the man's ruse,
*else
	Kosuke,
"Or did he have any possessions on him that looked suspicious? I'm trying to find their leadership and put an end to this."

"I wish I could say he did." The farmer says, and just then the farmhands return with a bowl of sweet-smelling peeled lychee and a cup of steaming hot tea. The farmer's mood picks up. "Finally! Honored Guest, could I interest you in these spirit-fruits and tea? They've been the prize of our valley. I've been saving them for a bad winter but they're better suited aiding you in stopping these abductions."

*if (insight >= 1)
	[b][Insight Check 1 Passed][/b]
	*set aurapressure + 2
	*line_break
	[b][Aura Pressure +2][/b]
	
	A light brush of your spiritual senses tell you there is indeed power stored within the lychee fruit they've offered.
*choice
	#"Yes please."
		*label yummyfruit
		A single bite is all it takes to know these spirit fruits are the real deal. Each succulent lychee produces a juicy burst with a softly sweet taste and sour aftershock. The tree from which they grew has clearly soaked in ambient chi for generations. 
		
		[b][Aura Pressure +8][/b]
		*set aurapressure + 8
		*set powexp + 1
		
		Likewise the tea's citrusy aroma soothes your tired bones and
		*if ((((perception + alchemy) >= 3) or (val = 411)) or (farmhandcollab))
			
			*if (val = 411)
				[b][Mao's Warning Activated][/b]
				*set powexp + 1
				*set agiexp + 1
				*set forexp + 1
				*set solexp + 1
			*elseif (farmhandcollab)
				[b][Special Event: Farmhand Collaboration Clue][/b]
				*set forexp + 3
			*else
				[b][Perception + Alchemy 3 Check Passed][/b]
				*set solexp + 2
				*set forexp + 1
			
			-is poisoned?! Oh Hells. You gently place the tea down and look at the three 'farmers' in the room. It becomes painfully obvious that you've found some of the bandits you've been looking for.
			
			*choice
				#Forcefeed your tea to the farmer.
					"Host, I would be delighted if you tried my tea for me. My culinary etiquette for this region is lacking, I'd like to see you do it first."
					
					All three of them freeze. "Honored Guest, I could never-"
					
					"You can, and you will." An aura of white haze rises from your body ominously.
					
					*if (persuasion >= 1)
						[b][Persuasion 1 Check Passed][/b]
						*line_break
						[b][Aura Pressure +2][/b]
						*set aurapressure + 2

					*set solexp + 1
					The farmer and his two farmhands look to each other and scowl. "Honored Guest, please. I can't-"
					
					Events turn to violence, as they always do, but this time it's because of you. Quickly thinking you pull your chair out from under you and break it over the head of the farmhand by the door. The other two jump to intervene but Kosuke leaps from ${bffhisher} seat and intercepts the second farmhand, dropping them to the ground with an armbar hold. The farmer himself draws a dagger from his boot that you swat away with ease and grip him by the jaw.
					
					You lift the man who tried to poison you off the ground, holding him by his jaw, and look him in the eyes. This man tried to truly kill you. It's a first. A first you haven't forgiven. You slowly raise your teacup off the table and pour its poisoned contents down his throat.
					
					The man screams, writhing in pain, and you let go to watch him drop to the floor. In seconds a white froth comes from his mouth, quickly turning red, and in mere seconds more he dies. It's a gruesome sight.
					*set ruthless + 4
					*set capturedbandits - 1
					
					You crouch down to the only conscious bandit remaining, the one Kosuke has in a hold on the ground. "That was not very good tea." You say. "I have questions about bandits, and you either have answers or you have your own cup to drink."
					*page_break
				#Slam your chair into a farmer's head.
					Events turn to violence, as they always do, but it's you who causes it this time.
					*label basicfight
					Quickly thinking you pull your chair out from under you and break it over the head of the farmhand by the door. The other two jump to intervene but Kosuke leaps from ${bffhisher} seat and intercepts the second farmhand, dropping them to the ground with an armbar hold.
					
					The farmer himself draws a dagger that doesn't do much good when you punch him in the lung so hard that his feet leave the ground. He crashes into the wall and crumples to the floor, unconscious.
					*set powexp + 1
					
					It's over before it begins.
					
					You look over to the only conscious bandit remaining, the one Kosuke has in a hold on the ground. You walk up and place a foot on the man's neck. "I think it's time we get to know each other. Why don't you tell me about yourself and all your friends?"
		*else
			you let out a content sigh. Finally, some good food.
			
			After your first three sips you notice the others looking at you in silence. "The tea is delicious." You say to ease their worries. They must be deeply concerned of your opinion of them. After all, you are a Martial Artist here to save them. That's why they're still looking at you with such concern. With such...expectancy.
			
			Oh, you've been poisoned.
			
			*set combatstat "fortitude"
			*set combatdiff 3
			*gosub_scene quicks combatcheck
			*if (passcheck)
				[b][Poison Resisted][/b]
			*else
				*gosub_scene quicks woundcheck 1 false false
			
			"Now!" Shouts the farmer. One farmhand grabs Kosuke around the waist while another seizes you around the shoulders. The poison works its way through your system but it's crude, only affecting the body and not your inner chi.
			
			Power cycles through your Cores in reaction, spinning rapidly to build momentum. The farmer pulls a woodcutter's ax off the wall just as your scorching hostile chi within your Cores builds enough force to launch out of your hands in a bright chi blast.
			*choice
				#Blast the farmer.
					*set powexp + 1
					*gosub chiblast1
					
					The farmer doesn't do so well. Your chi blast of scalding hot hostile energy blasts through his shirt and blisters his skin immediately. Smoke comes from his mouth and he can barely let out a stutter before falling out of his own chair.
					
					That just leaves the one holding Kosuke, who immediately releases ${bffhimher} and holds his hands in the air after seeing what could have happened to him. "I surrender!"
					
					"Good!" Shouts Kosuke, leaping from the floor and placing the bandit in an armbar hold out of revenge. The two drop to the floor together.
					
					Every inch of your body aches from the poison coursing through your veins as you walk up to the grappled bandit and put your foot on his neck. "I'm tired, I'm poisoned, and I am not happy. Start talking."
					*set val 33
				#Carefully shoot the farmhand holding Kosuke.
					*set solexp + 1
					*set bffrep + 3
					*gosub chiblast1
					
					"Oh shit, oh shit, OH SHIT!" Kosuke shouts as your blast of hostile combat chi the size of a campfire shoots just above ${bffhisher} head, crashing into ${bffhisher} captor and knocking them off.
					
					Well, not really knocking them off. The blast was more scalding than concussive. It's more like you burned all the hair and skin off their face, knocked them unconscious from the shock, and they fell off.
					
					The just leaves the farmer, who immediately drops the axe and holds his hands in the air after seeing what could have happened to him. "I surrender!"
					
					"The Hells you do!" Shouts Kosuke, leaping from the floor and placing the farmer-bandit in an armbar hold. The two drop to the floor together.
					
					Every inch of your body aches from the poison coursing through your veins but its effects are slowing and you've got a job to do. You walk up to the grappled bandit and put your foot on his neck. "I'm tired, I'm poisoned, and I am not happy. Start talking."
	#"No thank you."
		"No thank you." You say with a raised hand.
		
		The farmhand bows his head. "Of course Honored Guest, but I am sorry to say this is all we can offer to aid you in your journey. Are you sure you do not want it?"
		
		If all you're getting out of this bonus reward is a few Aura Pressure, it would be a shame to waste it...
		*choice
			#Accept the spirit fruits and tea.
				*goto yummyfruit
			#"I'm sure."
				"I'm sure." You say with total resolution.
			
				"I see, well in that case let's discuss the bandit problem." The farmer says, dismissing his farmhand to the kitchen.
				*page_break
				*if ((perception >= 1) or (farmhandcollab))
					*if (perception >= 1)
						[b][Perception 1 Check Passed][/b]
					*else
						[b][Special Event: Farmhand Collaboration Clue][/b]
					*line_break
					[b][Aura Pressure +2][/b]
					*set aurapressure + 2
					
					The dismissed farmhand returns to the kitchen at full sprint with a knife in-hand.
					
					With swiftness only seen among trained Martial Artists you grab a plate off the table and throw it at the charging 'farmhand', knocking the knife out of his grip and staggering him towards the door.
					*label whatmeaning
					"What is the meaning of this?!" You shout to the farmer as he jumps out of his chair in alarm. Not at the farmhand. At you.
					
					*if (farmhandcollab)
						Just as you had suspected, you've found the bandits responsible.
					*else
						It all clicks into place, a little too slowly. You've found the bandits responsible.
					
					*goto basicfight
				*else
					[b][Perception 1 Check Failed][/b]
					
					You don't see the farmhand return with a knife in hand until he's already upon you.
					
					*set combatstat "agility"
					*set combatdiff 2
					*gosub_scene quicks combatcheck
					*if (passcheck)
						Quick reflexes let you narrowly dodge the knife strike as the dismissed farmhand sprints back into the room with a scream. You only dodge by leaning forward in your chair, then grab his arm and twist the wrist until something pops. He drops the knife and staggers back toward the doorway, looking down at the small bone now protruding from his skin.
						
						*goto whatmeaning
					*else
						*bug
*goto interrogation

*label chiblast1
White hot energy erupts from your hands so hard that it knocks your chair backwards into the kitchen wall. The farmhand behind you takes the brunt of the blow as your chair crushes his sternum against the wall and knocks him unconscious.
*return

*label interrogation

"Please don't hurt me!" Shouts the last farmhand. "I'll tell you everything!"

Kosuke sighs. "Damn, another one doesn't want to talk. We'll have to get the boiling water."

The farmhand's eyes widen in fear. "Wait no, please! I-I have good information! Valuable information!"

"I don't know," You say while walking towards the kitchen, "If you had good information you'd lead with details instead of [i]saying[/i] you have good information. Where do you guys keep your boiling pots?"

"Sunbringers!" The man screams in desperation, "W-We're working for the Sunbringer Sect! You didn't know that, right? Up until a few months ago we were just a group of men trying to make a living on other people's money, you know, like any normal bandit or-or tax collector." He laughs but neither you nor Kosuke let up.

You're both too young to truly hate taxes yet.

"Okay well, it all changed when this bald Martial Artist shows up, kills our old boss, and tells us he's brokered work for us with the Sunbringers. We would have avenged our old boss, we're good men like that, but they're paying more in a week than we used to make in a season! The new boss says he'll even teach us cultivation to anyone who proves themselves. We took the job and figured the outlying farms were a safe first target."

That [i]is[/i] useful information. "And what have you been doing with the missing farmers and their families?"

"Well...Selling them. The Sunbringers are supposed to pay a premium for Thunderfall slaves."

Taking your people is one thing you cannot ignore. You look down on this man, hostile chi coursing through your hand and ready to strike in anger, but one thing doesn't add up. "If your gang has a Martial Artist to train them then why are all three of you so weak?"

He blinks back tears when Kosuke increases the pressure on his arm again. Softly he whimpers, "Our new leader, our 'Master' now that he treats us like his own personal Sect, he's a harsh man. Says none of us are worthy yet, but I don't mind. I'm just here for the money, that book of his-"

"Path Manual."

"-That Path Manual of his looks haunted something fierce. The men whisper that it's made of human skin."

"Does he have a name?" Kosuke asks.

"He tells us to call him Taio, says it's Old Cathayan for "Great Man." Master Taio's laying low at the Rolling Rock Tavern. Your farmers are under heavy guard in a barn next to the tavern until the Sunbringers come to collect at dawn."

"And how many men does he have, total?" You ask.

"About twenty throughout the valley, we're supposed to meet him at the tavern tonight to prepare for the slave auction tomorrow morning. Now I've told you all I know, isn't that worth my life?"

*choice
	#Tie him and the other bandits up to face justice.
		*set ruthless - 3
		Your mission will go better with a cowardly living witness who's already surrendered. "Kosuke, tie him and the others up."
		
		*if (bffheshe = "she")
			"With pleasure." Kosuke says through a sinister grin. She finds enough rope around the house and gets to work tying each of them up, but only after snapping the rope like a whip in front of the cowering bandit.
		*else
			"Consider it done." Kosuke says, scouring the house for rope and coming back with enough to tie down a small village. "Go figure that slavers have a surplus on rope." He crouches down and looks the conscious bandit in the eyes. "I'll find a way to use it all."
	*selectable_if (persuasion >= 2) #"No, your life is [i]mine[/i]. You work for me now." [Requires Persuasion 2]
		*set capturedbandits -1
		"No." You reply, denying the bandit his mercy. "Your life is [i]mine[/i]. You work for me now."
		
		He audibly gulps and nods silently, tears swelling up. The fool thinks a blubbering act will pull your heartstrings when he's been abducting your village's people to sell into slavery. 
		
		That fresh thought floats through your mind and you crouch down, grab the bandit by the hair, and pull his face up to meet your eyes. "In case you get any ideas, I've sensed your spirit now. If you try to run, or betray me, or disobey my orders in any way, I will find you. I will find you and I will castrate you. By hand. Are we clear?"
		
		He nods so fast that he might concuss himself. "Yes, absolutely, anything you say!"
		
		[b][1 Underling Acquired][/b]
		*set underlings + 1
		
		Kosuke ties up the other
		*if (capturedbandits = 19)
			bandit
		*else
			bandits
		to turn in later. You have no use for the wounded.
		*set honor - 2
	#Break his neck.
		*set ruthless + 4
		"Worth your life?" You ponder the man's words out loud. "It sounds like you're offering your life as payment."
		
		The man looks from you to Kosuke and back, unsure what to say.
		
		You grab his hair and hoist his head up to look into his eyes. "I accept your payment." With a quick twist you snap his neck in one swift motion. His head falls limply to the ground with a lifeless thud.
		
		[b][Aura Pressure +3][/b]
		*set aurapressure + 3
		*set capturedbandits - 1

*page_break
Kosuke finishes tying the
*if ((underlings = 1) and (capturedbandits = 19))
	unconscious bandit
*elseif (capturedbandits = 18)
	last unconscious bandit
*else
	unconscious bandits
to a sturdy tree outside, making sure to bind
*if (capturedbandits = 18)
	his
*else
	their
hands and feet as well. The two of you look out over the orchard farm around you, at the barn full of who knows what, and at the forested mountains from which you arrived. You have a battle coming and you need to prepare.

"So," You say after a big stretch, "One enemy Martial Artist, twenty career bandits, dozens of hostages, and trained Sunbringers arriving tomorrow morning."

"Easy enough." Kosuke replies nonchalantly. "What's the plan?"
*label cultprepoptions
*choice
	*disable_reuse *selectable_if (survival >= 1) #Gather herbs from the farms. [Requires Survival 1]
		Not all farmed herbs are useful, but nearly all useful herbs are farmed. With the surplus of abandoned farms in your surroundings the two of you are able to collect a plethora of useful ingredients for later.
		
		*set val ((2 + alchemy) + survival)
		[b][Item Gained: ${val} Alchemy Reagents][/b]
		*set alchemyreagents + val
		*goto cultprepoptions
	*disable_reuse *selectable_if ((alchemy >= 1) and (alchemyreagents >= 3)) #Refine a Healing Elixir pill. [Requires Alchemy 1 and 3 Reagents]
		With so many other ingredients and rich soil you've got nearly everything you need to brew a potent Healing Elixir pill. Between the pantry in the house and the lychee spirit fruits as a base you only need a minimal amount of ingredients from your personal collection.
	
		[b][Lost Item: 3 Alchemy Reagents][/b]
		*set alchemyreagents - 3
		*line_break
		[b][Item Gained: Healing Elixir][/b]
		*set healingelixir + 1
		
		"Cool." Says Kosuke, looking over your shoulder at your stained fingers and the glowing red pill. It shines in your hand until you drop it into an opaque vial to mask its presence.
		*goto cultprepoptions
	*disable_reuse *selectable_if (craft >= 1) #Build a weapon for Kosuke. [Requires Craft 1]
		Chi blasts are well and good but they're loud, spiritually speaking, and extremely bright. You want something more stealthy for this mission.
		
		The child's weapon earlier gives you the idea. Using the surplus of materials and workshop in the barn you and Kosuke put together a crossbow and a few bolts that should give ${bffhimher} the silent element of surprise. It works surprisingly well for your first design, firing accurately through the persimmon that your donkey was reaching for. He hangs his head in defeat when it disappears off the tree.
		*set kosukecrossbow true
		*goto cultprepoptions
	*disable_reuse *selectable_if ((perception+thievery) >= 2) #Locate any hidden valuables. [Requires Perception+Thievery 2]
		You're no saint. Kosuke doubly so. If these three were bandits then there's no way they haven't hidden a cache of stolen goods somewhere around here.
		
		The two of you check the most obvious places first. Which isn't to say the most obvious to everyone, but the places you would hide things. Together you knock on each floorboard in less-traveled spaces until you find a hollow one against the wall, just under a four-legged side table where no one would be walking. The perfect spot for a cache.
		
		Bingo.
		
		*rand val 420 580
		[b][Item Gained: ${val} Silver][/b]
		*set silver + val
		*line_break
		*if (alchemy >= 1) and (alchemyreagents < 3)
			[b][Item Gained: 3 Alchemy Reagents][/b]
			*set alchemyreagents + 3
		*else
			[b][Item Gained: 4 Ritual Components][/b]
			*set ritualcomponents + 4
		*goto cultprepoptions
	*disable_reuse *selectable_if (insight >= 2) #Detect spirit fruit from the lychee trees. [Requires Insight 2]
		Like any Advancement Elixir, your body can only process so much spirit fruit at once. Especially spirit fruits of the same type. Luckily you have a second use for them: Kosuke.
		
		You waltz through the orchard and reach out with your spiritual senses to find which trees have any noticeable chi stored within them, then narrow down that sensation until you can find the lychee that have absorbed the most. By the end you have two dozen spiritually-infused lychee.
		
		"Bottoms up!" Kosuke shouts, eating a handful.
		
		*if (bffromance >= 1) and (heshe != bffheshe)
			"Make sure to swallow, no spitting." You say as ${bffheshe} motions to spit out the seed.
		
			"Oh very funny." $!{bffheshe} says with an eyeroll.
		*set kosukecombat + 1
		Then something incredible happens. Kosuke's
		*if (kosukeaura)
			second
		*else
			first
		Core begins to form.
		
		"Oh shit!" You shout in alarm, "Sit down and cycle, like we did before! Compress all that energy into your center as tense as it will go. You want to push it until it breaks through and you form the yang aspect of your Core to compliment your current Yin aspect."
		
		"I don't know what any of that means!" Kosuke yells back, dropping into a meditative state and trying to figure out what to do with ${bffhisher} hands. The chi-infused fruit was just barely enough to make the difference so unlike your near-instant Advancement in a 
		*if (firstchapter = 2)
			fight,
		*else
			Heavenly Gate,
		Kosuke's is a grueling ten-minute process of you shouting instructions and Kosuke clenching ${bffhisher} teeth, sweating through the strain.
		
		[b][Your Mentorship has
		*if (kosukeaura = false)
			unlocked
			*set kosukeaura true
		*else
			improved
		Kosuke's aura.][/b]
		
		Finally the Core is formed and a white mist rises around Kosuke's soaked body, which is lying facedown on the ground. "This sucks." $!{bffheshe} whines, unable to raise ${bffhisher} arms. "Advancement sucks. How did you fight like this?"
		
		"Some of us are naturals. Take a ten minute break." You leave to let Kosuke rest there on the ground. On your way out you swipe the last of the lychee spirit fruit. They can't help as much as they did before, but that's never stopped you from seizing an advantage.
		
		[b][Aura Pressure +3][/b]
		*set aurapressure + 3
		*goto cultprepoptions
	*if ((lore + alchemy) >= 3)
		*disable_reuse #Fill your cart with barrels of explosive manure. [Requires Lore+Alchemy 3]
			*if (subrace = "Wolf")
				Your nose twitches from the proximity to so much crap. Why did your great-great-grandparent have to be a wolf?
				*set forexp + 1
			
			"Hear me out." You say for the third time while dropping a sixth empty wooden barrel on the ground.
			
			"No." Replies Kosuke, standing next to the compost pit of a neighboring cattle farm. The last four games of rock-paper-sword to decide who has to dig the dung for your genius plan have ended in a tie. You've devolved into diplomacy.
			
			"If the manure is packed into a sealed barrel and treated properly the gas build up could be our greatest weapon! Don't you want to see a massive explosion?"
			
			"Not [i]this[/i] badly."
			
			"Look someone's got to do it and I'm the one who has to get up and close for battle, I can't have them smelling me a mile away."
			
			*if (bffheshe = "he")
				"...Fine." Kosuke finally gives in. "But only because I'm no quitter, and I don't trust
				*if (heshe = "she")
					a [i]woman[/i] to do it right."
					 
					"Thattaboy." You reply, not taking the obvious bait to make you do it instead.
					*if (bffromance >= 1)
						"And make sure to do it shirtless!"
						
						You spend the next hour watching him work, upwind. 
					*else
						Better luck next time, Kosuke.
				*else
					you to do it right."
				
					"You got me." You say with relief, "I'm a terrible shit shoveler."
			*else
				"No."
			
				*if (underlings > 0)
					"Alright alright, we have a backup plan." You turn to the barn where your new underling is relieving himself. "MINION! Get over here and dig up these barrels of cow crap!"
					
					"You got it boss!" Shouts your pressganged bandit with gusto.
				*elseif (bffromance >= 1) and (bffheshe != heshe)
					"Well damn. Looks like if I want something done right then a man's got to do it." You reply, praying she disagrees.
					
					"Damn right." Kosuke says, "and he should do it shirtless, too."
					
					"You going to ogle me while I shovel cowshit?"
					
					She backs up and lays down on the grass. "From upwind, yeah."
				*else
					"You know, if Jin were here he'd love the idea. I thought you would love blowing stuff up too."
					
					Kosuke narrows ${bffhisher} eyes at you. "That's different since Jin always smells anyway, no loss to him. Besides, I know what you're doing."

					"And?"
					
					"And it's working. Just give me the damned shovel."
					
			Hours later you've got six barrels filled to the brim with pungent cow dung
			*if (alchemy >= 1)
				treated with a few powders
			and ready to be used as explosives. You're sure this could not possibly backfire as you load them all together onto your donkey's cart.
			*set explosives 1
			*goto cultprepoptions
	*selectable_if (powspent > 0) #Meditate to restore 1 spent Power Core. [Ends Preparations]
		*set powspent - 1
		*set powexp + 1
	*if (forspent > 0) #Meditate to restore 1 spent Fortitude Core. [Ends Preparations]
		*set forspent - 1
		*set forexp + 1
	*selectable_if (agispent > 0) #Meditate to restore 1 spent Agility Core. [Ends Preparations]
		*set agispent - 1
		*set agiexp + 1
	*selectable_if (solspent > 0) #Meditate to restore 1 spent Soul Core. [Ends Preparations]
		*set solspent - 1
		*set solexp + 1
	#Get some sleep. [Ends Preparations]
		*if ((bffheshe != heshe) and (bffromance = 0))
			After everything you close the farmhouse's shutters and lay on the tatami mat to get some rest before the mission. Rest that is immediately interrupted when you hear floorboards creaking under Kosuke as ${bffheshe} lays down next to you.
			
			*if (bffheshe = "she")
				"So..." Kosuke says. "You um...You...I've been..." A heavy gulp comes from the darkness and Kosuke laughs nervously.
				*if (kosukeaura)
					"So my first Advancement really helped me uh, grow up, you know, and I've been thinking about what to do about it..."
				*else
					"So I know my Martial Arts haven't developed as well as yours but, uh, my body has! And that's got me thinking about..."
					
				Ancestors, Kosuke's being weird. This is the kind of babbling you expect from Jin before he asks for something. Your eyes open in the dark room. "Are you okay?"
				
				Kosuke's quickened breathing is the only sound in the empty farmhouse as she suddenly turns over and sits up, gripping her upper shirt. "Do you...want to touch them?"
				
				"..."
				*choice
					#"Sweet Ancestors yes." [Seduction]
						Kosuke, the irredeemable trickster and con artist, sits up before you with her chest puffed out and her cheeks blushing redder than the setting sun, shy as a chaste shrinemaiden. You've been sneaking more and more glances at her ever since her body started developing and wrestling was getting harder and harder to get away with, in multiple ways. Yet here she is now, asking for exactly what you've always wanted.
						
						Internally you thank every Ancestor you've ever had.
						
						You reach out with one nervous but eager hand and...
						
						Feel her grab your wrists and shove both hands against her well-developed chest, a squeal escaping her mouth as she closes her eyes. Panicking at thinking you may have hurt her you lurch forward to stop the squeal and find your instincts kick in. With both hands busy against her breasts your lips are drawn to hers, interlocking instantly.
						
						Her face heats up almost as much as yours, your heartbeat racing at a thousand beats per minute, yet the world seems to reach perfection when she wraps her arms around you. "Yes!" She shouts as she pulls away and comes back in, her lips meeting yours between each word. "Yes, yes, yes, yes!"
						
						*set skipheartbeat true
						*goto kosukekiss2
					#"I want to touch a pillow and go to sleep."
						*label pillowingkosuke
						There goes Kosuke, making things weird again. You throw a pillow at ${bffhimher} and get some rest.
						
						...
						*goto rollingrock
			*else
					"So..." Kosuke says, propping his head up on one arm. "You, me...A quiet getaway with no one around to hear us..."
					
					You look over to Kosuke and narrow your eyes. What's he playing at?
					
					Ah, he's taking off his shirt. Hm. Nice abs.
					
					You sit up, curiosity peaked. "Kosuke, are you trying to make a move?"
					
					"I am." $!{bffheshe} answers confidently. "I should have years ago."
					*choice
						#Interesting. "Alright then tough guy, give me your best shot." [Seduction]
							"Alright then tough guy," You laugh, reaching your face teasingly close to ${bffhisher} own. "Give me your best shot."
							
							Your tantalizing gaze meets his own in the pale light seeping through the closed shutters. Without hesitation ${bffheshe} leans down, hand against your cheek, and he presses his lips against your own with a passion built on years of longing.
							
							It catches you off-guard.
							
							You've never been kissed before.
							*label kosukekiss2
							*set metkosuke + 1000000000
							*set bffromance + 1
							The warm feeling of ${bffhisher} lips against yours floats through your mind so dizzyingly that you don't even notice ${bffhisher} hand longingly reaching out until
							*if (bffhisher = "her")
								her soft
							*else
								his strong
							fingers interlock with yours. $!{bffhisher} chest eagerly presses against your own and you hold each other closely, rolling onto a single mat in unison.
							
							*if (skipheartbeat)
								You're both lost in bliss.
							*else
								Your heart is beating faster than it ever did during training.
								
							Your best friend, the
							*if (bffheshe = "she")
								girl
							*else
								boy
							you grew up with, passionately kissing you in a secluded home so often shared by married couples. It's an unreal dream you never knew you had...but ${bffheshe}'s not a
							*if (bffheshe = "she")
								girl
							*else
								boy
							anymore. $!{bffheshe}'s a
							*if (bffheshe = "she")
								woman,
							*else
								man,
							and you're a ${manwoman}. Growing up together made your feelings for ${bffhimher} appear so slowly, so naturally that you never noticed the change, but in this moment they've grown so strong that you can't deny them. Your other hand runs through ${bffhisher} hair and you lean into the embrace.
							
							Neither of you pull away for a long, long time.
							
							*set apval 4
							*gosub_scene quicks apboost
							*page_break
							*goto rollingrock
						#"Years ago? Damn man, you shouldn't have even done it [i]tonight[/i]." [Go to sleep]
							*goto pillowingkosuke
*label rollingrock

Before long the sun is setting across the valley. The bandits gather at night but the Sunbringer Sect will arrive with real Martial Artists by dawn. If you want this done right then your window of opportunity is short, and the time to strike is now.

Through the gentle cover of night you guide your donkey
*if (explosives = 1)
	cart, packed with explosive manure barrels,
*else
	cart
down the rough dirt road past a few pig farms with their farmhouse doors broken in. Finally the soft red glow of windows up ahead serve as an ominous beacon that you've reached the Rolling Rock Tavern. Parking down the street to avoid unwanted attention, you and Kosuke
*if (underlings > 0)
	and your minion
dismount and dip in through an orchard behind the tavern to approach the scene, the crunch of dried leaves beneath your feet drowned out by the distant cacophony of revelry. The moonlight flickers through the trees casting long, eerie shadows that seem to dance along the ground.

You peer through the gnarled branches of an apple tree, your eyes taking in the cruel tableau laid out before you.

The tavern is alive with merriment, the air filled with raucous laughter and the clinking of mugs audible even from out here. Yet just a stone's throw away from such a sight lies a grim, weather-beaten barn in stark contrast to the joyous scene. Two men with clubs stand guard at the door and
*if (underlings > 1)
	your minion
*else
	the blabbering bandit
already told you why. Within that barn's cold, wooden confines the farmers and their families lie shackled, huddled together, their freedom to be sold to the highest bidder.

*choice
	*if (underlings >= 1)
		#No one should face such cruelty (except my underling)!
			*set ruthless - 2
			Morality is subjective, only the strong decide what is or is not justice. These men have seized citizens from the strong (you) and so they will pay dearly (justice).
	*else
		#No one should face such cruelty!
			*set ruthless - 4
			This world is a cruel place, and only the strong can change that. Tonight you will be the strength that brings about such change.
	#These bandits will pay.
		*set honor + 3
		Abducting your people is a crime that cannot go unpunished. You will be their punishment tonight.
	#By the time this night is done, I will have the farmers selling the bandits!
		*set honor - 1
		An eye for an eye is a perfectly reasonable justice system, in your opinion, and it's only the opinion of the strong that matters. These bandits will wish they never set foot in your territory.
	#Typical peasants. Ah well, time to work.
		*set ruthless + 1

A twig snaps twenty steps to your left and you see a man patrolling the tavern ground's perimeter with knife in hand. He stares through the orchard trees scrutinizingly, scanning for anything suspicious - nope, wait, he's looking for the perfect apple on the tree in front of him. Picking apples while on duty. Typical. You don't know why you expected discipline from some highwaymen.

Another sentry follows him five paces behind. That's four bandits outside the barn in total, and you'll need to get rid of them if you want to continue unseen.
*choice
	#Sneak up on them.
		You double-back through the darkness and the obfuscation of the trees, silently stalking your prey of the two patrolling bandits.
		
		*set combatstat "agility"
		*set combatskill "stealth"
		*set combatdiff 3
		*gosub_scene quicks combatcheck
		*if (passcheck)
			The darkness of night masks you from their senses, in two short minutes you've silently maneuvered behind the first bandit and struck him with a single neckchop that knocks him out.
			
			Damn, you can't believe that actually works.
			
			That bandit sentry's partner notices nothing, eagerly crunching into what he appears to believe is the perfect apple he's just picked from the tree. You give him a swift neck chop as well and he drops to the ground soundlessly. Now your only problem is approaching the two bandits guarding the prisoners. They have torches illuminating the entire front of the barn, sneaking up is not an option.
			
			So you throw an unripe apple at each of them, one with each hand, at full force. The fruits slam into the unsuspecting bandits' temples with precise accuracy; one crumples to the ground but the other only staggers, barely injured. So you hit him with a second apple, a third, and a fourth. The concussive headshots keep him delirious and he barely makes more than a grunt as the fruits explode against his head. Finally he drops to the ground.
			
			Kosuke lets out a soft clap. "They teach applejutsu in the Thunderfall Sect?"
			
			"Laugh all you want, it worked." You take one final fruit off the branch and eat it.
			*goto stealthsuccess
		*else
			A branch snaps under your foot. Both sentry heads turn in your direction immediately.
			
			"We've got an intruder!" One of the sentries shouts in alarm, charging into the tree line with weapon drawn.
			
			Shit. Time to act fast.
			*page_break
			*goto Next_swingin
	#Send Kosuke to take them out.
		*if (stealth = 0)
			Stealth isn't your strong suit so you send Kosuke
		*else
			If Kosuke is going to accompany you then ${bffheshe} needs to get some experience. You send ${bffhimher}
		to silently take out the sentries and...

		*if (kosukecombat >= 1)
			[b][Kosuke's Training Check Passed][/b]
			*set powexp + 1
			*set agiexp + 1
			*set kosukecombat + 1
			
			All your sparring together in childhood pays off. Kosuke puts ${bffhisher} thieving skills to work by sneaking up behind the bandit sentry and, oh Heavens, snaps the poor bastard's neck. $!{bffheshe} gently lays their body on the ground, takes their weapon, and brains the next sentry while the bandit was enjoying an apple. $!{bffheshe} looks over to you through the trees and gives you a thumbs up next to the corpses.
			*set capturedbandits - 2
			*choice
				#"Calm it down Kosuke, damn."
					*set ruthless - 4
					"Calm it down Kosuke, damn." You mouth through the tree line.
				
					"Sorry." $!{bffheshe} mouths back, then steals one of the victims bag of shards and loops around the tavern. You lose sight of ${bffhimher} for five minutes until you hear a crunch behind you. When you turn you see Kosuke chewing on an apple cheerily. "Knocked
					*label kosssent1
					out the two at the barn, and one hiding behind some barrels with a crossbow." $!{bffheshe} hefts the crossbow in ${bffhisher} left
					*if (kosukecrossbow)
						hand while balancing ${bffhisher} own crossbow in ${bffhisher} right. "I'm dual-wielding."

						"You can't dualwield crossbows."
						*set agiexp + 1

						"Maybe [i]you[/i] can't dualwield crossbows." ${bffheshe} says, holding both up with horrible form. $!{bffheshe} admires both crossbows with the widest smile you've ever seen on ${bffhimher}.
						*set bffrep + 5

						"Alright, alright, good
					*else
						hand. "I'm keeping it."
						*set kosukecrossbow true

						"Good
					work, that should be all the sentries." You say with relief. "I'll take care of the rest."
					*page_break
					*goto stealthsuccess
				#"Nice."
					*set capturedbandits - 3
					*set ruthless + 1
					"Nice." You say, returning the thumbs up to ${bffhisher} wise choice. Lethal force is a permanent solution.
					
					Kosuke beams and sneaks around the tavern. You lose sight of ${bffhimher} for five minutes until you hear a crunch behind you. When you turn you see Kosuke chewing on an apple cheerily. "Took
					*goto kosssent1
		*else
			[b][Kosuke's Training Check Failed][/b]
			*line_break
			Feel a spike of alarm when ${bffheshe} goes to take out the first guard with a chokehold and takes an elbow to the gut that knocks the wind out of ${bffhimher}.
			
			"We've got an intruder!" The sentry shouts while grappling with Kosuke.
			
			Oh shit. Time to act fast.
			*page_break
			*goto Next_swingin
	*if (explosives = 1)
		#Charge in and start swinging. [Forfeits the explosives plan]
			*goto Next_swingin
	*else
		#Charge in and start swinging.
			*label Next_swingin
			*if (honor >= 48)
				"FOR THUNDERFALL!" You shout at the sentry, diving with a flying kick. You don't get to see his expression, he jumps from the shock and takes your kick to the back before he can even turn around. The blow knocks him into the second sentry and they both crash through the wall of an outhouse. Either the impact or the smell knocks them unconscious.
			*else
				"Hey shitass!" You shout at the sentry after maneuvering behind him at top speed. He turns around just in time to see your fist eclipse his eye. The man drops like a rock that you quickly grab and throw at the second patrolling sentry, crashing their heads together. They crumple to the ground unconscious.
			
			The other two bandits guarding the barn jump to attention, drawing clubs that don't do much good when you bound across the grounds and ram into them. You don't know when you became so much stronger than unpowered yet fully grown adult men, but all you do is grab their faces, one in each hand, and shove their heads three feet back into the barn door.
			
			They drop too.
			
			"Behind you!" Kosuke yells as a fifth sentry tumbles out from behind some crates with a crossbow in hand.
			
			*set combatdiff 2
			*set combatstat "agility"
			*gosub_scene quicks combatcheck
			*if (passcheck)
				It might as well be a bouquet. You dodge the first shot and
			*else
				The hidden fifth sentry lets loose his bolt before you can get to him.
				
				*set combatdiff 3
				*set combatstat "fortitude"
				*gosub_scene quicks combatcheck
				*if (passcheck)
					*label blockeditagain
					Luckily your skin is tough enough to take the hit. You
				*else
					*gosub_scene quicks woundcheck 1 true false
					*if (pblocktech != "")
						
						*goto blockeditagain
					*else
						It pierces through your side inflicting far more pain than you expected. In revenge you
			charge the man, grab him by the chest and ram him through the window of the tavern.

			Unfortunately in the heat of the moment you didn't let go. His weight and your momentum drag you through the window close behind him. The two of you crash into the main hall of the Rolling Rock Tavern in an impressive rain of glass shards that interrupts the songs and merriment of the men inside. The bandit takes the brunt of the landing and doesn't move.
			
			You rise to your feet just as Kosuke opens the front door, out of breath and shocked at your audacity.
			
			$!{bffheshe}'s not the only one.
			
			Over a dozen bandits stare at you in a mix of insult and confusion, rising from their seats at the rows of tables against the walls. Each draws a weapon of some kind and the mood of the tavern noticeably darkens.
			
			*label shittalking
			"Gentlemen." You say after adjusting your outfit and scanning the grizzled faces throughout the tavern hall. The faces of your enemies. "On behalf of the Thunderfall Sect...
			*choice
				#"You're all under arrest."
					You look upon the two dozen bandits with the cold nerves of authority. From your travel pack you withdraw a truly unreasonable amount of rope and toss it into the center of the room. It lands with a heavy 'thud' as you announce your verdict.
				
					*set honor + 2
					"Start binding your hands or you will be beaten. You are all under arrest."
				#"I'm going to kill everybody in this room."
					You look upon the two dozen bandits with smug superiority, as you've earned, and announce your verdict.
					
					"I'm going to kill everybody in this room."
					*set ruthless +2
			
			Every face turns to a scowl and they charge you in unison.
			*page_break
			*goto bossfight
	*selectable_if (kosukecrossbow) #"Kosuke, take them out with your crossbow." [Automatic Success]
		*set capturedbandits - 4
		Kosuke closes ${bffhisher} eyes, silently relishing the moment. "I love when a plan comes together." $!{bffheshe} draws the crossbow from off ${bffhisher} back and loads a bolt. The first target, the bandit watching the apple picker, gets one swift shot to the head and drops. The slight noise of the crossbow alerts the apple picker just in time for him to know something is wrong before Kosuke shoots him too. You're quickly reminded that Kosuke spends most days and nights on the streets and you wonder if this is the first time ${bffheshe} has killed a person. It doesn't seem to bother ${bffhimher} at all.
		
		The two bandits guarding the barn have the same situation. One slumps over after Kosuke shoots them and the other notices something is wrong just in time to go down themselves.
		
		Kosuke blows on the crossbow as if it were a smoking cannon and grins victoriously at you. "Four down from the safety of an apple orchard." $!{bffheshe} grabs an apple off the tree and tosses it your way. "Celebrate with a treat?"
		
		You catch it, take a bite, and twist your face in displeasure. "It's unripe."
		
		Kosuke hangs ${bffhisher} head.
		*if (bffheshe != heshe)
			"The mood is ruined."
		*else
			"So close, yet so far."
		*page_break
		*goto stealthsuccess
*label stealthsuccess
With the sentries gone you sneak to the barn and peak inside. The sight before you is exactly what you expected to see, but it still hits your gut to witness it. Dozens of men, women, and children, YOUR people, shackled to the walls inside. If you free them now it would alert the enemy and the hostages would be in danger, so it's time to take care of the main forces: the bandits inside the tavern and their leader.

*choice
	#Waltz right in. It's time to end this, fist-to-fist.
		You kickdown the door to the tavern with such force that it flies off its hinges, slamming into one of the bandits hard enough to knock him off his seat. All cheer and merriment dies down as the men see you entering the room.
		
		*goto shittalking
	*selectable_if (explosives = 1) #Blow up the entire tavern. [Requires Explosive Barrels]
		Parking the donkey cart so far away from the tavern was a poor choice. After twenty minutes of setting up you finally have your prepared barrels located where they need to be.
		
		"Hey, Sunbringer lackeys!" You and Kosuke shout in unison from a safe distance down the road. The chatter and merriment from inside the tavern abruptly stops. Moments later a couple lightly armored men come through the door with knives drawn to investigate. They wrinkle their nose at the sudden smell.
		
		"Who the Hells are you?" Shouts one bandit inside the doorway. A half dozen more can be seen peaking through the open doorway to see what the interruption is about.
		
		"I am ${fullname}, ${patriarch} of the ${clan} Clan. On behalf of the Thunderfall Sect you are all under arrest for abduction of our peasants. Come out with your arms bound or face annihilation."
		
		The second bandit chuckles as he raises a crossbow, pointed directly at you. "You must have a death wish kid. Hey boss, come check this out."
		
		Kosuke lets out an audible tsk tsk.
		
		You draw a piece of flint and aim for a well-placed pile of oil-soaked rocks you assembled on top of one of the barrels. "Your disobedience has been noted."
		*set explosives 2
		*page_break
		*image https://www.auraclash.com/assets/img/exploded-inn.jpg
		*if not (jadedragonfoundation)
			*achieve bigbang
		*set capturedbandits - 12
		
		Five barrels explode simultaneously in a chain reaction around the tavern. A blinding orange and red detonation is followed by a deafening boom, the concussive blast blows your clothes against you body when tavern walls erupt inward from both directions and the blaze engulfs everyone inside. Even the tavern becomes a weapon once the supports fail in the explosion and parts of the second story fall onto the screaming burning bandits in large sections of heavy burning timber.
		
		The essence of fire is so all-consuming in the area that your body even absorbs fractions of the heat's power as if it were a Heavenly Gate.
		
		[b][Aura Pressure +7][/b]
		*set aurapressure + 7
		
		You shield your eyes from the debris and light until it fades into 'just' a tavern-sized inferno. The screams have slowly silenced to nothing.
		
		"Do you think we got them?" Kosuke asks redundantly, looking over to you with a sly smirk. $!{bffhisher} face is covered in soot. Oh Heavens you hope that's soot, because it's on your face too and those explosives were manure barrels.
		
		Please be soot.
		
		"Let's find out." You say confidently to hide your inner turmoil, marching to the flames. It's time to collect the leader's body.
		*page_break
		Searching through the debris is harder than you thought because you really let this tavern have it. The damn thing will be on fire for hours if not days. Kosuke's getting water from the nearby well to see what can be done while you take care of the hard part: suppressing the flames around you with waves of your own natural chi. It's not a real Technique you've mastered and, as such, barely works.
		
		[b][1 Chi Point Spent][/b]
		*set chispent + 1
		
		Tremors of your inner energy push the flames away from your body with middling success as your spiritual senses feel out for their leader. He should still be alive, Martial Artists are notoriously hard to kill in one hit, but that explosion was pretty damn big...
		
		Your search is solved in the worst possible way a moment later when the orange glow of the fires turn darker. Too dark to be the red of fire chi and too light to be the scarlet of Akakiru's bladed chi. No, this color is the unmistakable crimson of blood. "Of all the fools in this world, I never expected a child to tread upon my plans." A voice echoes through the wreckage. "Yet I have never hesitated from killing a child."
		
		Urgency fills your mind and you send up a haze of white energy around you, forming your aura while looking around for the source of danger.
		
		*if (insight >= 1)
			[b][Insight 1 Check Passed][/b]
			*line_break
			*set val 1
			[b][Aura Pressure + 2][/b][/b]
			*set aurapressure + 2
			
			You feel the attack coming just in time to raise your guard.
		*else
			[b][Insight 1 Check Failed][/b]
			*set val 0
			
			You don't see the attack coming until it's too late.
		*page_break
		*if (portraitpics)
			*image https://www.auraclash.com/assets/img/demonicleader.jpg
		
		*if (sonarmode)
			[b][Thunderfaller vs Master Taio][/b]
		*else
			*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-taio-bandit.png
		
		As the only Martial Artist reported in the group you can piece together that the bald monk who looks like he just stepped out of a demonic cult must be Master Taio. He's upside down in the air above you before you can even react, dropping a kick down deep into your shoulder.
		
		*set combatstat "agility"
		*set combatdiff (4 - val)
		*gosub_scene quicks combatcheck
		*if (passcheck)
			You catch his leg with both arms and tighten your grip. "Master Taio I presume." One heavy throw launches the man back into the fires. "Did you think that would work?" You taunt back, hoping people can still hear when they're on fire. No one's ever tested it that you know of.
			
			"YOU taunt [i]ME[/i]?!" The voice screams from the blaze. "You should be thanking me for trying to execute you in one blow, FOOL! You've ruined everything!"
			
			"You're enslaving my
			*if (ruthless >= 54)
				peasants,
			*else
				people,
			don't expect sympathy from me."
			
			Suddenly the crimson power around him intensifies. "The only thing I expect from you is your demise. I don't know who sent you-"
			
			"Crusher Mao." You interrupt without hesitation. Worst case scenario you die and he seeks revenge on your bastard of a Sect Master.
			
			"-But I will ensure they receive your corpse in PIECES!" The man stomps through the fires and you swear the flames follow him, changing to a darker red and swirling around his body in a display of power. Yet upon closer look his ears are bleeding from the blast. His hands are scorched. Hell, he might have even had hair before the fire.
			
			"That's a nice trick," You say dismissively, "but you're already half dead.
			*goto yougloat
		*else
			Pain rocks down the left side of your body as his kick comes down so hard that your feet break through the brittle burnt flooring. He spins in place and grabs your shirt as a counterbalance, throwing you through a support beam and tumbling into the fires.
		
			*gosub_scene quicks woundcheck 1 false true
			
			*if (eblocktech != "")
				The impact is painful but the protective energies of your ${eblocktech} prevents the flames from damaging your skin. Yet the smoke is still lethal.
			*else
				The pain of the impact is immediately replaced with the pain of the flames. No air enters your lungs, all of it burnt by the all-consuming flames, and the pain of the fire blinds your eyes shut.
			With the last breath in your lungs you leap out of the fire with no care for direction, desperate to escape the smoke and heat.
			
			A hand catches your face and throws you backward. "You're not leaving yet!" Taio barks. You hit a surviving table thankfully outside of the flames and rise to your feet just in time to block one of the man's basic chi blasts and charge up your own. He follows his up with a charging kick but has to give up his attack to defend from your blast, jumping back and skidding to a halt fifteen feet away.
			
			The man, presumably this Master Taio, regards you with a dismissive sneer. "So, it seems you can fight back after all, perhaps this won't end so quickly."
			
			"Don't worry Taio," You say through the pain. "It will be over quickly-"
			
			"Doubting yourself? You've a big Aura Pressure."
			
			"-For you.
			*label yougloat
			I am ${fullname}, ${patriarch} of the ${clan} Clan and here to take you in on behalf of the Thunderfall Sect."
			
			"Hmph. A pup grows teeth and thinks itself a wolf."
		*goto mergeboast

*label bossfight
The closest table of brutes tries their luck first. Four men surround you and draw their knives.

*set combatdiff 2
*set combatstat "power"
*gosub_scene quicks combatcheck

Combat chi crudely courses through your spirit like blood through your veins. You catch two of them by the neck and slam their heads together just in time before the back two come in range with their blades. Your fist strikes one in the adam's apple before he can strike, and in the same motion your leg works as a counterweight to slam your full power into the face of the last attacker with a side kick. All four lie on the ground bleeding and acting as a frame for the rest of them to see a perfect view: you, a glowing Martial Artist, flanked on all sides by their defeated men.

There is no second wave. The bandits pull back in hesitation and look to a larger chair in the back of the tavern's main hall, and their leader who sits upon it.
*page_break
*if (portraitpics)
	*image https://www.auraclash.com/assets/img/demonicleader.jpg
A bald man resembling a monk in his early 20s, this 'Master' Taio rises from his chair and dusts off his ceremonial robes. There's no smile or mockery in his face like you've grown used to from your opponents. He doesn't look down on you. He doesn't expect your submission. He expects a fight. "You have made a mistake this day, Martial Artist. My operations are not to be interrupted."

"Master Taio, I presume. You're the one who's been interrupting Thunderfall's operations. This is your only chance to surrender."

His men step back against the walls. A clear pathway forms for the two of you to fight.

"Not a chance on your life, ${boygirl}." His top lip curls up with disgust. "My ambitions do not end here, they've only begun. I don't know who at Thunderfall had the gall to send you after me, but they'll regret it when I send you back in pieces. Especially after what you've done to my men."

You look down on his bleeding bandits who attacked you first. First Jack and his father act like spoiled brats when you defend yourself and now this bandit gang does too. What do they put in the drinking water around here?

"These bandits steal and enslave
*if (ruthless >= 55)
	that which rightfully belongs to my Sect
with no remorse. They have not even begun receiving the beating they deserve. And as their leader..." You take on a battle stance and breathe calmly to cycle your inner chi. All that training has lead up to this. Prepared you for this. [i]Designed[/i] you for this. A swirling haze of hot white steam surrounds your body. "You will take that punishment in their place."

*if (sonarmode)
	[b][Thunderfaller vs Master Taio][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-taio-bandit.png

Spiritual energy fuels your leg muscles and you kick off across the main hall like a loosed arrow. Taio staggers back two steps in surprise and draws a sword.
*choice
	#Catch the blade.
		*set combatstat "fortitude"
		*set combatstat2 "power"
		*set combatdiff 5
		*gosub_scene quicks combatcheck
		*if (passcheck)
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
			
			You catch the blade with the expertise of a warrior trained. Because you are a Warrior and you have been trained. With a half-second's surprise, you get the chance to press your advantage in a counterattack.
			
			*choice
				#Headbutt him.
					*set combatstat "power"
					*set combatskill "survival"
					*set combatdiff 3
					*gosub_scene quicks combatcheck
					*if (passcheck)
						[b][Aura Pressure +1][/b]
						*set aurapressure + 1
						
						Your forehead slams into the bridge of his nose much the same as a hammer slams into a piece of hot metal at a forge: loudly.
						
						Taio screams when your skull shatters his nasal system. He grabs his bleeding face with both hands and staggers back, giving you time to push your assault.
					*else
						Your head crunches into his own but you would never call it a headbutt. A headbutt targets his weak nose with your strong skull. In your infinite wisdom and immaculate aim you've crashed your hard forehead into his hard forehead. Your head bounces off with the blinding light of a concussion.
						
						*gosub_scene quicks woundcheck 1 true false
						
						The two of you wobble on your feet, stunned.
						
						"Should we..." Says one of the bandits just as you recover first and make your next move before any of them get funny ideas.
				#Steal the sword.
					*set combatstat "agility"
					*set combatskill "thievery"
					*set combatdiff 3
					*gosub_scene quicks combatcheck
					*if (passcheck)
						[b][Aura Pressure +1][/b]
						*set aurapressure + 1
						*set armed true
						
						You spin the sword out of his hands and deliver a wide slice across Taio's stomach. He jumps back to lessen the damage but finds your foot wrapped behind his heel, pulling him off balance and allowing a free slice at his thighs instead.
						
						His blade - no, [i]your[/i] blade - slices cleanly across his legs and inflicts noticeable damage.
						
						"Gahhh!" He screams, grabbing both legs with both hands. He's on the defensive, now's your chance.
					*else
						The sword spins over your hands similar to the showboating of a master swordsman. The difference is you are not a master swordsman, you are not doing this on purpose, and after a second of spinning the sword launches off into the distance.
						
						Both you and Taio look over at the unlucky bandit who just found out he's dead, staring down at the sword in his heart.
						
						Then you get back to your fight.
		*else
			You catch the blade with your chest instead of your
			*if (pblocktech = "")
				hands.
			*else
				hands, only your ${pblocktech} stopping the mistake from injuring you.
			A poor tactical move. Taio looks almost as surprised as you do.
			
			*gosub_scene quicks woundcheck 1 true false
			
			"No $!{name}, your Acid Blood Technique is forbidden!" Kosuke shouts from the door. Taio hears that and jumps back, eyes wide, creating some room for your counterattack.
	#Duck the attack.
		*set combatstat "agility"
		*set combatdiff 3
		*gosub_scene quicks combatcheck
		*if (passcheck)
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
			
			With quick thinking you duck under the blade at a sharp angle and position yourself perfectly for a counterattack.
			*choice
				#Uppercut him.
					*set combatstat "power"
					*set combatdiff 3
					*gosub_scene quicks combatcheck
					*if (passcheck)
						[b][Aura Pressure +1][/b]
						*set aurapressure + 1
					
						Your fist flies up with a twist and catches his chin from below in a perfect connection, knocking him off his feet and sending his blade flying. He's stunned and falling back to the floor which gives you room to...
					*else
						Your fist surges up just past his face, nicking him on the chin enough that he jumps back but not hard enough to wound. He throws his sword at you but you expertly duck again and close the gap to...
				#Chi-blast his groin at point-blank range.
					Big Chu taught you the basic of hostile chi blasts. The secret is take your inner energy, cycle it through your spirit's core a few times, then use that momentum to launch it out of your body through your hands.
					
					And that's exactly what you do.
					
					*set combatstat "soul"
					*set combatdiff 3
					*gosub_scene quicks combatcheck
					*if (passcheck)
						[b][Aura Pressure +1][/b]
						*set aurapressure + 1
					
						Your scalding hostile chi launches out of your palm like a campfire fired out of a catapult. The blast collides into Taio's groin and you don't actually hear anything at all from his reaction. His mouth opens but nothing comes out.
						
						Miles away, dogs are barking.
					*else
						To the both of you. Your chi-blast comes out more concussive and scalding and blows the two of you away from each other, crashing into tables and landing on your backs.
						
						*gosub_scene quicks woundcheck 1 false true
						
						You're surprised to see he gets up after you, but then remember you were merely blasted in the hands. His blastzone was center-mass. You close the gap as he shakily stands and...
		*else
			You crouch low, duck too slow, and take a sword slash to the back. The sharp pain screams through your shoulder blade, a bleeding slice forming up and down the upper right of your back.
			
			*gosub_scene quicks woundcheck 1 false false
			
			"No $!{name}, your Acid Blood Technique is forbidden!" Kosuke shouts from the door. The cult leader hears that and jumps back, eyes wide, creating some room for your counterattack.
	#Blind him with a wide chi blast.
		Big Chu taught you the basic of hostile chi blasts. The secret is to take your inner energy, cycle it through your spirit's core a few times, then use that momentum to launch it out of your body through your hands.
		
		But you have a better idea for how to wield such a power.
		
		Both sets of your fingers interlock to press your chi out of each arm at once. Rather than launching the most potent blast you can, you take the faster route and charge your inner spiritual energy to maximum intensity without a care for trajectory or heat. You don't need a strong blast that takes a while to charge, you need a [i]bright[/i] blast that can charge instantly.
		
		*set combatstat "soul"
		*set combatdiff 3
		*gosub_scene quicks combatcheck
		*if (passcheck)
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
		
			A new dawn rises through room in the form of your attack, casting a blinding sphere upon your enemies that would make the Sunbringer Sect seethe with envy. Taio covers his eyes from the blinding assault and flails his sword at your general direction.
			*choice
				#Kick his own sword into his chest.
					Taio's blind, wild swings are fast and unpredictable. They make it hard to close the gap and his vision is recovering soon enough. Luckily his sword is single-edged. You wait for him to swing to the left instead of the right, so the blade is facing himself at the cusp of his swinging arc.
				
					*set combatstat "power"
					*set combatdiff 3
					*gosub_scene quicks combatcheck
					*if (passcheck)
						[b][Aura Pressure +1][/b]
						*set aurapressure + 1

						Then you kick the blade into his arm.
						
						"GYAAHHH!!" He screams as his own sword slices deep into his own bicep. His bloodshot eyes shoot open, forcing chi into them to force a recovery sooner. The fact that they're still bloodshot proves it's not a real healing Technique, just desperation, but your blast wasn't a real blinding Technique either.
						
						His eyes do restore to proper vision, but only just as you...
					*else
						you kick the pommel by accident and send the damn sword flying into a nearby wall. So much for that plan.
						
						He reaches out to grab you but misses and you realize with luck that he's still partially blind. An advantage you intend to press.
				#Sweep his leg.
					Taio's blind, wild swings are fast and unpredictable. A blur of desperate bladework swinging death in your general direction.
					
					You don't have time for it.
					
					You crouch low, place a palm on the ground for quick stability, and swing both legs [i]hard[/i] against Taio's knees.
					
					*set combatstat "agility"
					*set combatdiff 3
					*gosub_scene quicks combatcheck
					*if (passcheck)
						[b][Aura Pressure +1][/b]
						*set aurapressure + 1

						His knees give out and his body collapses mid-swing, sword falling and cutting his shoulder on its descent. You kick the blade away and press the advantage for your next attack.
					*else
						He jumps just in time, having heard your palm slap against the ground, and swings down blindly in your general direction with all his might.
						
						"DIE, INTERLOPER!" Taio screams as his blade slices down your thigh.
						
						*gosub_scene quicks woundcheck 1 false false
						
						Pain racks through your body and you roll out of the way with such urgency that he has to jump again to avoid being tripped. You get up behind him, pain shooting through your bleeding leg when it supports your weight, but your conviction gives just enough time to...
		*else
			The explosion in your hands [i]is[/i] instant, but in your haste it's pointed the wrong way. Your own chi blast burns into your chest and shreds a good bit of your clothes.
			
			*gosub_scene quicks woundcheck 1 false true
			
			Taio covers his face to guard against your explosion but when he opens his eyes and sees your injuries he only grins.
			*if (heshe = "she")
				Actually, he grins quite a bit.
				
				A quick glance down makes you realize where the creepy old man is staring. OH HELLS, your shirt!
				
				Your face blushes bright red and the embarrassment fuels your next attack.
				
				[b][Aura Pressure +2][/b]
				*set aurapressure + 2
			*else
				"They were fools to send an amateur like y-"

*choice
	#Grab his midsection and suplex his head through the floor.
		*if ((fortitude + lore) >= 3)
			*set combatstat "fortitude"
		*else
			*set combatstat "power"
		*set combatskill "lore"
		*set combatdiff 3
		*gosub_scene quicks combatcheck
		*if (passcheck)
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
		
			With immaculate form you wrap one arm around his waist and one around his arms.
			
			"What do you think you are you doing?!" He shouts, "Unhand me!" 
			
			Wordlessly you lift him high overhead like a sack of grain you're about to launch behind you, but you keep your grip on his body and instead swing him in a full circle down into the wooden floorboards, face-first.
			
			His head takes the brunt of the impact and breaks through the floor with a deafening crash. His body tenses up but ceases movement, his limbs hanging loosely from his rigged but unmoving form, dangling like a willow tree.
			*set an "suplex"
			
			*goto winningfight
		*else
			Grappling maneuvers are not your strong suit, a fact you remember just as you lift Taio off his feet.
			
			You raise the man too high, turning him completely upside down in your arms. When his feet reach the ceiling he grabs your shoulders and kicks off to collapse you into the ground where your head slams into the floor. Pain disorients your five senses as the world shifts out of focus and blinding lights flash through your vision.
			
			*label banditleadergloat
			*gosub_scene quicks woundcheck 1 false false
			
			"Is this all they send?" Taio taunts over you while you try to come back to your senses. "This is what the Thunderfallers have to offer? No wonder the Sunbringers think they can take their town! Hells, [i]we[/i] can take their town!" His men let out a rallying cheer.
			
			You roll away desperately and stand on shaky feet. "You're not taking anything." You say through gritted teeth, "This fight isn't over yet."
			
			"Isn't over? You can't even fight a fraction of my power!"
			*goto mergeboast
	#Run hostile chi over your fingers and stab his pressure points.
		Each unpowered bandit only sees a cascade of flashing lights obscuring your movements as you run scorching chi over your index and middle fingers.
	
		*set combatstat "soul"
		*set combatskill "thievery"
		*set combatdiff 3
		*gosub_scene quicks combatcheck
		*if (passcheck)
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
		
			You knock Taio's arms wide open and unleash a dozen soul-shredding stabs into his spirit and flesh simultaneously.
			
			'Master' Taio convulses on his feet with each strike hitting into his nerves and forcing the fight out of him. When you finish smoke rises from the puncture wounds and Taio's eyes have rolled into the back of his head.
			
			"Too easy." You say, pushing him over. He teeters on his feet, leans back ever so slowly, and falls to the ground without a word.
			
			*goto winningfight
		*else
			What they don't see is when you [i]burn the shit out of your own hands[/i] by messing up the impromptu attack and screech out in pain.
			
			Taio presses that advantage by smacking you in the face with alternating hands then jumping off the nearby wall and using the leverage for a final full-force blow knocking you into the ground.
			
			*goto banditleadergloat
	#Deliver a combo of strong punches.
		*set combatstat "agility"
		*set combatstat2 "power"
		*set combatdiff 3
		*gosub_scene quicks combatcheck
		*if (passcheck)
			[b][Aura Pressure +1][/b]
			*set aurapressure + 1
		
			You slam your fist into Taio's gut to knock the man off-balance. He deflects it but takes a hard hit to the hip.
		
			*set combatstat "agility"
			*set combatstat2 "power"
			*set combatdiff 4
			*gosub_scene quicks combatcheck
			*if (passcheck)
				[b][Aura Pressure +1][/b]
				*set aurapressure + 1
			
				Taio protects his face from your next swing only to take your follow-up hook to the left cheek. The impact knocks him to steps to the side and he tries to turn around before you can follow through.
				
				*set combatstat "agility"
				*set combatstat2 "power"
				*set combatdiff 5
				*gosub_scene quicks combatcheck
				*if (passcheck)
					[b][Aura Pressure +2][/b]
					*set aurapressure + 2
				
					He fails. Your last punch lands a haymaker with your full weight behind it. He takes the punch right to the nose and drops to the ground where he quickly develops two black eyes.
					
					*goto winningfight
				*else
					He succeeds and dodges your haymaker with a cross-punch, catching you directly in the nose and giving you two black eyes.
					
					*goto banditleadergloat
			*else
				Taio protects his face from your next swing and blocks your follow up hook, catching both your hands at once and headbutting you in the face. Your nose crunches as he gives you two black eyes at once.
				
				*goto banditleadergloat
		*else
			He blocks your very first punch and you begin to think the Martial Arts might not be for you.
			
			"The Martial Arts are not for you." He confirms, punching you in the face repeatedly until you fall to the ground with two black eyes.
			
			*goto banditleadergloat
	*if (armed)
		#Run him through with the blade.
			*set agiexp + 1
			*set powexp + 1
			"Your swordplay is weak!" You say to the 'Master' Taio with a swing at his midsection.
			
			He leaps back to evade the first strike. "As if you'd know better, fool! You can't even-"

			Your high kick to his jaw snaps his head back midsentence. His stance loses balance and you ready his own sword to strike. "Let me give you a tip." Then you pierce your new blade through his midsection so fiercely that it drives him back and pins him to the wall. The man looks down at his wound in shock, but you just look into his eyes and boast. "Don't talk when you're losing."
			
			He tries to say something but only blood comes from his mouth.
			*set an "sword"
			*goto winningfight

*label winningfight
A hushed silence fills the tavern main hall.

Every bandit stands dumbfounded, unsure what to do. They gawk in unified horror at their leader's body, the empowered man strong enough to dictate their lives, lying defeated at the hands of a young Martial Artist. One by one their weapons fall to the floor and they kneel in submission. You catch your breath and nod, pleased with the outcome. Mission complete.
			
*page_break
"Heh. Hehe. HehahAHAHAHA!"

You turn to your opponent in time to block his flying arc of crimson chi that knocks you skidding across the hall. Taio
*if (an = "sword")
	rips the sword out of his gut and tosses it aside.
*elseif (an = "suplex")
	grips the floor with both hands and rips his head out, sending a cloud of splinters into the air around him.
*else
	rises to his feet with an effortless single flip.

Both his swollen lips part into a smile. "You've pushed me to desperation. Impressive. Yet do not think yourself strong."
*label mergeboast
He reaches into his robes and withdraws a leather Path Manual with the cover of a screaming face. "You've merely defeated a fraction of my power. My masters have trained me to contain what power I've earned into this Soul Treasure to avoid your Sect's detection, but it's pointless if
*if (explosives = 2)
	my men are dead and my operation is ruined.
*else
	they're already sending whelps.
Your Sect will surely detect me once I reclaim my might but I'll ensure you won't be alive to see how that ends."

He opens the Path Manual's pages and the entire room illuminates in an eerie crimson glow. "Behold my power unleashed, the power of a true Martial Artist beyond the limits of regular men! [b][i]Immortal Core Advancement!![/i][/b]"

Crimson power swirls around him with whipping winds of force strong enough to cause an indoor 
*if (explosives = 2)
	hurricane that extinguishes the flames all throughout the tavern.
*else
	hurricane. Swirling gusts knock cups, plates, knives, and debris all throughout the tavern hall. His underlings duck under the tables in fear.

Acid fills your mouth as you nearly vomit from the sensation coming off of this man. Taio's aura gives off the impression of invasive sickeningly-sweet decay, like a bucket of rotting, coagulating blood sliding down your throat. Sensing the chi coming off of him revolts your soul to a level you didn't know possible and it takes every ounce of your resolve to keep your lunch down.

*if (perception >= 1)
	[b][Perception Check Passed][/b]
	*set val 1
	*line_break
	Then he charges you at speeds you've never faced before.
*else
	[b][Perception 1 Check Failed][/b]
	*set val 0
	*line_break
	Then your opponent disappears from your sight.
*page_break
In the blink of an eye he's upon you. Not with some pose, but with his fist already in your face. You're blown into the wall and the impact knocks the wind out of your lungs. He kicks those lungs in the next instant, then delivers a second kick to your abs forcing you to bend over in pain. From there he grabs you by the collar and throws you over his shoulder to the opposite end of the tavern he just came from, where you crash 
*if (explosives = 2)
	through a burnt
*else
	into a
staircase.

*set combatstat "fortitude"
*if (val = 1)
	*set combatdiff 3
*else
	*set combatdiff 4
*gosub_scene quicks combatcheck
*if (passcheck)
	*label passedit
	[b][Aura Pressure +3][/b]
	*set aurapressure + 3
	
	You're bleeding and bruised but everything still works. With quick adaptation you
	*if (explosives = 2)
		break through the burnt wood
	*else
		get to your feet
	and look upon your powered up opponent across the main hall.
*else
	*if ((perception >= 1) and (pblocktech != ""))
		*gosub_scene quicks woundcheck 1 true false
		
		Only your ${pblocktech} Technique stops his blow from crushing your face.
		
		*goto passedit
	*else
		*gosub_scene quicks woundcheck 1 false false
	
	You're bleeding and bruised, and something in your chest isn't working quite right. Breaths come out ragged and your vision blurs as you
	*if (explosives = 2)
		crawl out of the burnt wood to
	stare upon the
	*if (explosives != 2)
		changed
	man before you.
	
'Master' Taio is now covered in swirls of crimson chi that feel sickening in your spiritual senses. The flow of power is so dense that you don't need to scan him to know what he's doing, it's visible in plain sight. Crimson spiritual energy swirls into condensed 'orbs' that churn like millstones, cycling in his aura and shoving this new chi deep into distinct locations.

Four distinct sources of chi. Four distinct cyclings at once to restore his power.

Your understanding clicks into place.

One pool of chi for Soul over the mind, the source of all understanding and will. One for Power over the dominant hand, the focus point of force projection. One for Fortitude over the heart, the center point of vitality. One for Agility over the naval, the source of one's balance. All four swirls of energy mix into Taio's aura slowly as if being ground up with each spiraling rotation and shoved into his spirit, filling him with power as you fight.

The sight is hypnotic.

Big Chu only ever toughened you up in what he called "raising your Mortal Cores". Peak physical fitness. What you're witnessing now, this direct injection of chi into four abstract parts of the soul, it's something else. Something beyond the natural body.

Something you've only done once by accident back in your first Advancement.

"Scanning people is rude, Thunderfaller." Taio mocks in the middle of one mighty leap across the tavern. "Let me teach you some manners!" He kicks you again but you block with both arms just in time to protect your head from total destruction.
*if (explosives = 2)
	There's no remaining wall where his blow launches you through the air so you
*else
	Only your toughened skin protects you from glass lacerations as you're launched through the nearest window and
bounce off the soft earth several times outside. The world spins in your perception while your body tumbles toward the tree line.

Yet the nauseating pain can't interrupt your new obsession.

The risk of death is right before you, yet you're almost ashamed at how...excited you are. There's nothing special about this man's transformation after all, except that he's using odd chi from some item. You may not have a tool like his but you have something just as good: a well of inner energy cultivated within your soul, slowly built over years of effort. If it's as easy as condensing huge masses of power towards the right skillset in the right place, why can't you do it now?

"Kosuke!" You yell while ungracefully landing on a tree's trunk,
*if (agility != 3)
	barely
managing to impact it with your feet and crouching to soften the blow, "Distract him for me, I have an idea! We can win!"

*if (bffheshe = "he")
	"Easier said than done!" Kosuke yells back, sprinting
	*if (explosives = 2)
		to the scene from the safety of the nearby well to help you.
	*else
		to the back of the tavern from the front door to help.

Taio leaps 
*if (explosives = 2)
	through the weakened roof of the tavern and lands on a remaining set of tiles.
*else
	out of the tavern. Not through the hole he knocked you through, but his own hole he blows through the roof.
"Stupid fools, I can hear you! I'll not fall for some distraction when I can end this between us right now!" His hand pulses with more sickening crimson energy and he throws it at you with two hands as if hurling a boulder overhead.

*if (bffheshe = "she")
	"You want me to distract THAT?!" Kosuke screams back, running
	*if (explosives = 2)
		to the scene from the safety of the nearby well.
	*else
		around the tavern to get to your fight.

	"YES!" You demand while sprinting
*else
	You sprint
behind a tree for cover from the energy blast coming at you. Excess power and heat explodes through the wood and nearly scorches your left side but you roll out of the way in time.

"Uhhhhhhhhhhhhhh" Kosuke says, deciding to go with...
*choice
	*selectable_if (kosukecrossbow) #Shooting Taio with a crossbow.
		"Distract this!" Kosuke shouts while firing a crossbow bolt at your enemy.
		
		Taio catches it with ease then goes back to charging another two-handed energy blast, only to be interrupted again by catching another crossbow bolt. "Give up, powerless mook! I can catch these all day."
		
		Kosuke fires again and the man catches the bolt with ease again.
		
		"It's pointless!" Taio shouts, returning to charge his energy attack with both hands. He has to stop to catch a fourth bolt and his irritation becomes palpable. "Pest, cease interrupting me or I will come down there and rip y-"
		
		His irritation turns to infuriation at the fifth bolt. In his anger he gets sloppy, catches it by the tip, and cuts his hand. The sphere of energy he'd been preparing dissipates from his loss of focus. He turns to Kosuke with a snarl. "YOU ARE DEAD!" Taio screams, launching a weaker one-handed attack at Kosuke that hits ${bffhimher} at centermass. Kosuke
		*if (bffheshe = "he")
			shouts
		*else
			screams
		and tries to block the attack with the wood of the crossbow, only to have the weapon explode on impact and the remaining force of the attack blows ${bffhimher} twenty feet back into the stables.
	*if ((kosukeaura) and (explosives = 2))
		#Tossing the last explosive barrel.
			*goto kosuketoss
	*else
		*selectable_if ((kosukeaura) and (explosives = 1)) #Tossing an explosive barrel.
			*label kosuketoss
			"Sorry Mr. Donkey!" Kosuke shous while sprinting towards the street. "Sorry sorry sorry sorry!!" Kosuke bellows, sprinting directly at your donkey tied to a roadside tree and your cart. The beast notices Kosuke's distress and, more importantly, that Kosuke is sprinting directly at him.
			
			Panic sets into the donkey's gut as Kosuke reaches him and leaps.
			
			A white glow fills the darkness of night around the cart when Kosuke powers up ${bffhisher} meager aura, ascends ten feet in ${bffhisher} leap, and reaches a sturdy branch just above the donkey. Kosuke pushes off that branch with both hands and all the power of what you assume is a developed Power Core.
			
			$!{bffheshe} launches down onto the connector of your cart like a seesaw.
			*if (explosives = 2)
				The sixth manure barrel, the last of your haul,
			*else
				One of your explosive manure barrels, still left on the donkey car,
			launches like a catapult directly at Taio on top of the tavern roof.
			
			'Master' Taio doesn't even turn, sensing no chi except Kosuke's aura at a distance. It's not until the sound of a midair approaching object is too close that he finally turns from his charging energy attack and sees the barrel.
			*if (explosives = 2)
				"No." The bandit leader whimpers. "No not again!"
			
			Kosuke's manure barrel crashes into Taio's Technique with a fiery concussive explosion engulfing that entire section of the roof.
			
			"I got him!" Kosuke shouts in cheer. "I actually got him! YAHOOO!! Come on out $!{name} you're not even needed, Kosuke's got your back this time. Hells I have been waiting for a win like that, ugh, it feels so good." $!{bffheshe} rubs ${bffhisher} cheeks with both hands in glee. "Soooo g-"
			
			$!{bffhisher} eyes bulge out of ${bffhisher} head and ${bffheshe} lets out a
			*if (bffheshe = "he")
				shout
			*else
				scream
			with the last of ${bffhisher} breath. One minute Kosuke was cheering, the next Taio stands directly in front of ${bffhimher}, skin charred on one side of his face, his fist embedded into Kosuke's gut. Crimson chi rocks through the weakened enemy's fist and into your friend, blasting Kosuke twenty feet back into the stable.
	*selectable_if ((kosukeaura) and (kosukecombat >= 2)) #Launching ${bffhisher} first energy blast.
		"Okay, okay, okay." Kosuke says to ${bffhimher}self, taking several calming breaths. $!{bffheshe} cycles ${bffhisher} chi in several circles just like you taught ${bffhimher}, looping the power faster and faster to build momentum and fill the power with hostile intent before loosing it into ${bffhisher} arms.
		
		And then out.
		
		A glowing orb of power shoots out of Kosuke's outstretched hands and goes wide, missing Taio by fifteen feet and crashing into the tavern.
		
		"Hah, what an amateur!" Taio laughs in return and turns back to you, finishing the charge of his two-handed energy attack prepared to destroy the entire orchard you've been weaving through to buy time. Then, for seemingly no reason, he sees the night sky directly above him. His thoughts before dropping into tavern and having his left arm impaled on roofing nails is, "Why am I looking up?"
		
		Kosuke never missed. $!{bffheshe} hit the support beam of Taio's remaining section of roof.
		
		But Kosuke's celebration is cut short, as Taio releases his attack on ${bffhimher} instead. The mass of hostile crimson chi rips through the entire debris of the tavern and slams into Kosuke, who lets out a
		*if (bffheshe = "he")
			shout
		*else
			scream
		as the attack shatters ${bffhisher} aura and launches ${bffhimher} thirty feet back into the stables.
	#With no better option, giving the Martial Arts a try.
		Kosuke is not a Martial Artist, more like a brawler. Most of ${bffhisher} fights have been spars against you and your siblings. $!{bffhisher} only real use for combat chi has been hunting in the woods to save money on food.
		
		And Taio is a much bigger target than some poor wild goat. Still, ${bffhisher} friend is in danger so Kosuke climbs the tavern debris swiftly to engage the enhanced Martial Artist in hand to hand combat.
		
		*if (kosukecombat >= 2)
			[b][Event Check Succeeded: Kosuke's Training][/b]
			*line_break
			[b][Kosuke has avoided injury!][/b]
			
			A swift kick launches debris at Taio's eyes and then actually lands just as the man protects his vision, hitting him in the throat. A couple punches land but inflict little damage, only for Kosuke to duck a blind swing and trip Taio off his feet then bullrush him off the roof in the confusion.
			
			They both fall.
			
			The thirty foot drop is nothing to Taio who spins mid-air and lands on his feet, but it's a whole lot more to Kosuke who lands on ${bffhisher} elbow. More precisely, Kosuke lands on Taio's head [i]with[/i] ${bffhisher} elbow.
			
			A thirty foot diving elbow is nothing to scoff at, for either party.
			
			"GAHH!" Taio screams in shocked frustration, staggering back with both hands on the top of his head where a welt is quickly forming.
			
			"AAAAHHH!!" Screams Kosuke, hitting the ground with the rest of ${bffhisher} body. All the breath is knocked out of ${bffhimher}; with all focus on offense ${bffheshe} suffers the consequences of hitting the ground chest-first after such a fall. The man walks up to your friend as Kosuke tries to roll to safety but it's not enough.
			
			Taio grips Kosuke by the neck and pinches down with chi to paralyze ${bffhimher}. "I'm going to come back for you when I have your friend's head." Then he throws Kosuke through the wall of the stables twenty feet away.
		*else
			[b][Event Check Failed: Kosuke's Training][/b]
		
			Taio turns and sees Kosuke coming in time to sidestep ${bffhisher} first punch, then dodge a kick and knock Kosuke's feet out from under ${bffhimher}. Kosuke tumbles off the roof but saves ${bffhimher}self in the last second by grabbing onto the ledge.
			
			"Pathetic." Says Taio, returning to charge his next energy blast with both hands so he can destroy the entire orchard you're weaving through.
			
			"I'm not done yet!" Kosuke shouts, pulling a piece of burnt wood off a nearby crumbling wall in one hand and lifting ${bffhimher}self up with the other. $!{bffheshe} charges Taio from behind with the impromptu wooden stake, illuminated by the crimson light of the man's energy attack that Kosuke has to stop.
			
			Just as Kosuke gets within reach Taio turns again, annoyed. In one swift motion he snatches the wooden stake out of Kosuke's hand and stabs ${bffhimher} with it in the gut. "Not done yet?" The bandit leader mocks. "You never started."
			
			[b][Kosuke has been injured!][/b]
			*set kosukeinjured true
			*set kosukecombat - 1
			*if (kosukecombat < 0)
				*set kosukecombat 0
			
			Then he grips Kosuke by the collar and throws ${bffhimher} off the thirty foot roof, all the way through the stables across the tavern grounds.
			
			Kosuke's had a tough life, and pain is nothing new. $!{bffheshe} rips the wooden stake out of ${bffhisher} own gut midair, now wrapped in ${bffhisher} own life essence in the form of blood, and throws it into the charging mass of chi that Taio is preparing for an attack. You're not sure if Kosuke even knows or if it was a guess; chi attacks are designed to harm the living. The blood triggers the attack.
			
			Its eruption of crimson energy engulfs Taio just as Kosuke collides through the stable wall with a blood-curdling
			*if (bffheshe = "he")
				howl.
			*else
				scream.

A one-sided match, but while it's been going on you've been putting the time to use.
*page_break
Gathering up all your unaligned energy into condensed swirls of chi and linking them to the right focus is easy on paper. Yet in reality, you're not just aiming for a location on a body-sized map and throwing chi at it. You're trying to change that energy from natural chi into something else. You need to mentally forge it, permanently dedicating massive amounts of spiritual power towards a singular goal.

While Kosuke's fighting you're weaving through the trees to evade stray energy blasts. The scene makes for poor meditation but you look inward all the same. The sounds of Kosuke's battle don't add stress to your mind, oddly enough, they add serenity. The idea that you have mere seconds to figure this out only makes you trust your first full instinctive thought on what is missing:

[i]Purpose[/i]

...Nope. Your spirit doesn't respond to that revelation. Shit.

Then what is the missing component? Ownership? You've gathered up enough of the world's energy but that could be the problem. It's the world's energy, not yours. It's an addition to your actions instead of a part of your actions. There's only so much you can control quickly and that's always come from your Mortal Cores, any big displays using all your inner chi are too slow since you need time to shape the chi's working in your mind. If only you could control your inner chi more quickly, like you control your body, then it could answer to your call like a reflex.

Well okay then, you think to yourself, what is a reflex? To you it's always been an automatic response. But a response to what? An event? A situation? No, that doesn't sound right. Reflexes in combat have more to it than that. There's always a sense of [i]desperation[/i] to make your body react before your mind, something that triggers immediately when it's needed.

Could that be it? Could it be so simple?

...A need?

Tremors shake through your soul when your revelation completes and you instinctively know you've solved the puzzle. You feel the call of your Power Core, answering the needs of force and rage. 

Your Agility Core radiates to answer the needs for speed and precision.

Calmly your Soul Core lends its response to your will, focused on the needs of analysis and control.

And lastly your Fortitude Core stands firm, as it always has, in its lifelong quest to solve the needs of stability and survival.

All four an extension of your willpower, all four connecting in your mind and spirit to your urgent needs in battle.

At that exact moment Kosuke's
*if (bffheshe = "she")
	screech
*else
	howl
of pain echoes through the night as ${bffheshe}'s blasted into the stables, letting you know that time's up.

Swift footsteps crash through the trees as you do your best to channel your chi. In mere seconds Taio is upon you, cutting off your escape with a grim expression and his fist surging with crimson power.

*if (explosives != 2)
	"Behold, men, as I add this fools blood to my power!"
*else
	"It's time you pay back the lives you cost me, I will add your blood to my power!"
His attack descends toward your head with a scream. In response you grit your teeth and flex your spiritual power with the desperation of life and death. You condense every ounce of energy inside of you into four places at once with the full weight of your Aura Pressure that you've honed from a lifetime of struggle. You don't know when you started smiling maniacally, but you know you are now.

The words leave your lips all too easily. [b][i]"IMMORTAL CORE ADVANCEMENT!!"[/i][/b]

Nothing inside you breaks.

Not like your first Advancement.

Instead it's [i]the world[/i] that caves this time, losing the last of its claim on the energy inside you. With a spiritual snap your inner chi is no longer a pool of untyped energy connected to nature. Your willpower seizes on it with an iron grip and wrests the last bit of control, forging that energy into a reserve of personal power bound directly to your reflexes.

[b][Ability Unlocked: Immortal Core Advancement][/b]
*set val 0

*set coreadvancement true
*goto immortalcorecheck

*label immortalcorecheck
*set val + 1
[b][Go to your Stats Page, then navigate to the Cultivation page and allocate 100AP into a Combat Core to increase its rating permanently.][/b]

[b][When you have less than 100 unallocated AP remaining, click "Next" below.][/b]
*page_break
*if ((aurapressure - allocatedap) >= 100)
	*if (val <= 5)
		*goto immortalcorecheck
	*else
		*label loopsetcore
		*set allocatedap + 100
		*set power + 1
		[b][100 Aura Pressure Allocated to Increase Power by +1][/b]
		*line_break
		*if ((aurapressure - allocatedap) >= 100)
			*goto loopsetcore
		*else
			*page_break
*label fightcont
*if (sonarmode)
	[b][Thunderfaller vs Master Taio][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-taio-bandit.png

*gosub_scene quicks statcheck
*set val 0

Newfound energy rocks through your very spirit. Everything around you is pushed back as you release a primal scream accompanying your second Advancement.

Not the scream of fear or even the battlecry of a warrior, but the groundshaking roar of a ${manwoman} forcing their own soul past its limits in defiance of the natural world, then pushing even further beyond. A roar so powerful the impact of it knocks Taio off his feet and back nine yards. Blood shoots from between his clenched teeth when his back collides into a tree.

You stare up at your prey with the eyes of a hunter.
*choice
	*selectable_if (power >= 3) #Charge him with a soul-infused power fist.
		*set combatstat "power"
		*if ((power - powspent) >= 1)
			*set combatdiff 4
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +5][/b]
			*set aurapressure + 5
		*elseif (power >= 3)
			*set combatdiff 3
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
			
		You charge low and push all your power into one fist that you drag behind you as if carrying a great weight. Once you get within range of Taio you don't just swing your fist for a punch, you detonate the chi around your fist with all the might of your Power Core to speed up your attack and slam through his guard.
		
		The blow connects with his face in an explosion of ${auracolor} chi that launches him through the tree behind him with an echoing [b]CRACK[/b] that can be heard throughout the valley. A rain of wood splinters falls around you and even you are amazed at your own work.
		
		As the sounds of battle quiet down you can finally hear your own gasping breaths; that attack took everything out of you.
		
		After several attempts you stand and hobble over to inspect the damage. When you get to Taio's unconscious body you find his nose has been completely inverted and you've shattered his top row of teeth.
	*selectable_if (soul >= 3) #Enhance your roar with scorching chi.
		*if ((soul - solspent) >= 1)
			*set combatstat "soul"
			*set combatdiff 4
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +5][/b]
			*set aurapressure + 5
		*else
			*set combatstat "soul"
			*set combatdiff 3
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
		
		The power of your roar comes from deep within your soul. Deep within the soul you have finally strengthened. Every fiber of your being focuses on that wasted power spilling out and focuses it, shaping the concussive blast of your Advancement's outburst into a cone and filling it with the scorching power of hostile chi.
		
		The result is a wide streaming blast of white chi-fire coming from your mouth. The breath of a dragon.
		
		Your assault continues for several seconds before dissipating and leaving a smoking crater where the tree once was. Taio stands on shaky feet, his skin blackened and his clothes burnt to a crisp.
		
		When he opens his mouth to speak, weakened and wobbling in a daze, only smoke comes out. He collapses to the ground unconscious.
	*selectable_if (agility >= 3) #Deliver a devastating five-point heartstrike.
		*if ((agility - agispent) >= 1)
			*set combatstat "agility"
			*set combatdiff 4
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +5][/b]
			*set aurapressure + 5
		*else
			*set combatstat "agility"
			*set combatdiff 3
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
		
		The world slows around you as ${auracolor} light crawls over your body. Not just the mist of your old aura but snaking lines of bright light looping all around you. Taio raises a hand to charge you with more of his crimson energy but you close the gap before he can, striking his arm in a vital nerve and watching it fall to his side. He responds with a knee that you sidestep, striking a vital nerve in his knee as well. He falters, slipping from the disorientation, and you palm strike his chin to keep him up.
		
		Then you leash chi to your fingertips, combine all five fingertips on each hand into piercing tools, and strike Taio's heart with the speed and precision of a cobra. His aura faulters. You strike his heart again, his eyes shoot wide open. You strike his heart again, blood spurts from his mouth. You strike his heart again, his entire aura explodes in an effort to keep him conscious with the last of its energies.
		
		You strike his heart again.
		
		He falls.
	*selectable_if (fortitude >= 3) #Headbutt him the rest of the way through the tree.
		*if ((fortitude - forspent) >= 1)
			*set combatstat "fortitude"
			*set combatdiff 4
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +5][/b]
			*set aurapressure + 5
		*else
			*set combatstat "fortitude"
			*set combatdiff 3
			*gosub_scene quicks combatcheck
			[b][Aura Pressure +2][/b]
			*set aurapressure + 2
			
		"Stop!" Taio shouts as you leap upon him and grip his throat in one hand and the tree behind him in another, rearing your head back for a crushing blow. "Stop at once! I ORDER YOU TO STOP!" All your chi weaves through your skull until it hardens like steel. Then you crash your head on his skull a guillotine with so much force that shatters the tree behind him.
		
		Miniscule remnants of wood rain through the air from the circular explosion of concussive force caused by your attack. You pant desperately for breath and when the debris clears you see the whites of the man's eyes as he's laid unconscious on the orchard ground, bleeding from his eyes, nose, ears, mouth, and forehead.

It's over. You've won.
*page_break
*if (sonarmode)
	[b][Thunderfaller vs Master Taio][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-taio-bandit.png

*if (sonarmode)
	[b][Victory!][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-victory.png

*gosub_scene quicks fightexp

Exhaustion hits you like an avalanche. Your body collapses to the ground with the exception of a single fist raised in the air in victory.

"I did it..." You say to yourself in exhausted glee, chest shaking from pained laughter. "I'm a Martial Artist."

Yet the eerie crimson glow from Taio's body does not fully dissipate, even though his own aura has shattered from your fight. Curiosity and caution drag you to his unconscious form on the ground where you realize the luminescence is coming from that odd leather Path Manual of his, the one with a screaming human face on the front.

Its glow resonates emotions in your spirit, concepts that you feel in the back of your mind just from the sight of the tome.

Barters. Promises. Tribute.

It calls to you, offering power...
*choice
	#Pocket it for now, to trade to the Thunderfall Sect for a common but less risky item.
		*set tomeuse 1
		This Path Manual is obviously haunted, cursed, demonic, or otherwise just a bad idea. A perfect gift for the other Thunderfallers to deal with.
		
		"Haunt or curse me and I'm throwing you into a fire." You say to the face on the cover of the eerily glowing Path Manual, just for good measure. A trick of the light convinces you that it frowns at that as you jam it into your satchel.
	#Siphon what power you can from the strange Path Manual.
		You take the Path Manual in shaky hands and grin. It's obviously not a regular Path Manual but also some sort of Soul Treasure; you witnessed first-hand when Taio used it to consume some sort of power.
		
		"Give it to me." You say while opening the tome, hoping to activate the effect somehow. "Give me everything you have left."
		
		A trick of the light makes you think the front cover of the Path Manual smiles ever so slightly. Then its crimson light leaves the Path Manual and enters your aura, swirling effortlessly to your Cores like water down a drain.
		*set taint + 30
		*set tomeuse 2
		*if (race = "Oni")
			As an Oni you feel more whole, as if your spirit were a shadow of its true self and you've taken a step towards manifesting your real potential.
			*comment gain gravitas, an increased level of Presence that makes your deeds seem greater.
			*set prestige + 1
		
		[b][Aura Pressure +30][/b]
		*set aurapressure + 30
		
		Memories flood into you as well, memories of Taio's life. Yet for some reason none pertain to his past, they are instead memories of actions. Picking locks, forging documents, sneaking up on targets for murder, crafting a dozen fake identities, and deceiving his crew to believe they would ever be given a fraction of his Path Manual's power.
		
		All these memories flood into you, but the ones that stick out the most are...
		*if (((thievery >= 2) and (deception >= 2)) and (stealth >= 2))
			*choice
				#The lies. [Increase Deception]
					*set deception + 1
					*set honor - 2
				#The murders. [Increase Stealth]
					*set stealth + 1
					*set ruthless + 2
				#The thefts. [Increase Thievery]
					*set thievery + 1
					*set honor - 1
		*else
			*choice
				*selectable_if (deception <= 1) #The lies. [Increase Deception]
					*set deception + 1
					*set honor - 2
				*selectable_if (stealth <= 1) #The murders. [Increase Stealth]
					*set stealth + 1
					*set ruthless + 2
				*selectable_if (thievery <= 1) #The thefts. [Increase Thievery]
					*set thievery + 1
					*set honor - 1
	#Destroy the eerie Path Manual.
		*set tomeuse 3
		Wow, a haunted Path Manual. You could not imagine a more stupid decision than letting this thing continue to exist.
		
		"Begone." Is all you say to the cursed object as you hold up one hand glowing with hostile chi and punch down on the tome with all your remaining strength.
		*set powexp + 2
		*set solexp + 2
		A trick of the light makes you think the face on the cover looks afraid just before your fist smashes through it.
		
		Of course it does, you think to yourself, it's a haunted Path Manual.
		
		[b][Special Event: Having Common Sense][/b]
		*line_break
		*if (lore >= 2)
			*if (insight >= 2)
				[b][Survival +1][/b]
				*set survival + 1
			*else
				[b][Insight +1][/b]
				*set insight + 1
		*else
			[b][Lore +1][/b]
			*set lore + 1
*page_break
Footsteps approach and you turn to see Kosuke
*if (kosukeinjured)
	with ${bffhisher} right arm hanging limply to ${bffhisher} side. $!{bffhisher} face is marred with
	*goto kosface
*else
	grinning with
	*label kosface
	a bleeding cheek that extends up to a gnarly black eye swollen shut. It looks like ${bffheshe} crashed into something metal in the stable face-first.
"Mission accomplished?" $!{bffheshe}
*if (kosukeinjured)
	asks wearily.
*else
	asks.

"Mission accomplished." You say, rising to your knees and then to your feet with an exaggerated grunt.

*if (bffhimher = "him")
	"Eh, you sound like a forty year old, grunting while standing, but...I couldn't agree more.
*else
	"Oh Ancestors I couldn't agree more with that grunt.
My everything hurts too." Kosuke says. "Let's visit the healer's hut when we get back. Thunderfall Disciples get in for free right?"

"Yeah but you don't." You reply while the two walk over to the barn.

Kosuke shrugs. "Steal me an extra gi and I'll slip out the window after the old ladies wrap me up."

"They're not going to fall for that a fourth time."

"That's what you said about the [i]third[/i] time."

The two of you finally reach the barn doors and take a steadying breath. Your body aches from your own Advancement more than the fight, but at least it's all over now. With a sturdy grip you open the barn doors only to see a clash of violet and golden light emanate from inside. An aura.

"Oh come on!" Kosuke groans out loud through the flashing light.
*page_break
*if (portraitpics)
	*image https://www.auraclash.com/assets/img/gothgf.jpg

The intense violet and golden light comes off a bored and insulted looking Lunargoth woman in dark robes, her pale face accentuated with pale makeup and her lips coated in purple as she stands in the doorway with arms crossed. "Took you long enough."

Another woman in purple combat gi, dark shoulder-length hair, and glasses runs up from behind her with arms outstretched as if presenting. "Behold, Sunbringers, a mistress of power worthy of your alliance!"

Behind them both sit dozens of peasants chained to the walls looking terrified and confused.

"We're not Sunbringers!" Kosuke shouts, covering ${bffhisher} eyes with
*if (kosukeinjured)
	${bffhisher} one good hand
*else
	both hands
and grimacing. "Put the light show away!"

"You're not Sunbringers...?" Both women ask. The shining one reverts to an exaggerated pout and drops her aura. "Well then where are the Sunbringers?"

"Hell, hopefully." You and Kosuke reply simultaneously.

"Then who are you two?"

"Who are YOU?" You counter in exasperation. "We belong here, we're from the Thunderfall Sect," you point at the farmers behind her, "they're the hostages," you point behind you,
*if (explosives = 2)
	"and they just got executed
*else
	"and they're under arrest
for taking hostages. Everyone involved is supposed to be here but you."

The girl's head arcs back as if she's been slapped. Another 'hostage' runs up behind her, a younger man also in purple gi and glasses looking just as offended as the others. "Why, this is Lady Desdemona of the southern swamps, the most skilled Kiihakai practitioner to grace this year's Heavenly Ascension Trials!"

"You should be bowing before her!" Shouts the young woman who presented Desdemona in the first place.

Desdemona cuts them off with a wave of her hand and looks to you. "Hold on. There's been a misunderstanding here. Thunderfallers, you should go while you can. This is Sunbringer territory-"

"No it isn't." Kosuke interrupts.

"I can assure you it is, we've been monitoring the Sunbringer troops rounding up these rebelling slaves to draft for the Trials. Myself and my apprentices infiltrated the draftees with our cunning plan to impress whatever talent judges the Sunbringers are to send." She holds another hand up, to you this time. "And before things get violent, know that we only intend to infiltrate your rivals long enough to run off with their secretive handseal rituals, so long as you don't get in our way."

"I don't care about that," You say plainly, "What I care about is that this isn't Sunbringer territory, it's Thunderfall territory, and those aren't rebelling slaves, they're free Thunderfall men and women that the Sunbringers tried to abduct."

"What? No, that can't be right. We passed through the western pass right in the..." Desdemona snaps her fingers and the woman in purple combat gi pulls out a map. All three of them stare at it intensely and you notice manacles around their wrists with loops of chains dangling off them, the ends burnt through. They really did get captured on purpose.
*if (perception >= 1)
	
	[b][Perception 1 Check Passed][/b]
	*line_break
	[b][Aura Pressure +2][/b]
	*set aurapressure + 2
	
	You notice something else too,
*else
	Kosuke must have noticed something else,
stepping forward and grabbing the map out of her hands.

"Wha-Don't you dare put your filthy hands on my-!" Desdemona starts in protest, until
*if (perception >= 1)
	you turn
*else
	Kosuke turns
the map upside down and
*if (perception >= 1)
	place
*else
	places
it back into her outstretched hands.

Her anger dissipates to worry, then realization as she stares at the map. "Oh no..." Desdemona whispers to herself, eyes darting back and forth. She squints, pulls the map closer to her face, and squints harder. "No..." She says a little louder, looking up at the mountains around the valley, then back down to the map she's been reading upside down. "No! No! No! No! No!" She looks around nervously to get her bearings and suddenly bursts into full sprint towards the northern road with one arm holding her robe closed. "I-I forbid you from telling anyone about this!"
		
Unfortunately for her, she's racing down the wrong road again. The Sunbringers are to the east.

You look to her two stunned followers as they watch their leader run off in panic.
*fake_choice
	#"She wants that road." [Point East]
		*set ruthless - 3
		*set honor + 1
		You look to Desdemona's followers in purple gi with pity as their leader takes the wrong road again. "She wants that road." You jab a thumb towards the eastern road instead.
		
		They each sigh in unison. "Thank you young
		*if (heshe = "he")
			master,
		*else
			mistress,
		we'll go tell her." And they sprint off after their leader.
		*set descombat + 1
		*set desrep + 3
	#"Have a safe trip." [Let them get lost]
		*set ruthless + 1
		
		They both wave and thank you as they run after Desdemona. Neither catches on that they're going the wrong way. Whatever ritual they hoped to learn from the Sunbringers, they're not learning it anytime soon.
	#"That will be a 10 Shard toll." [Rob them]
		*set honor - 2
		*set desrep - 3
		"That will be a 10 Shard toll." You say to the man.
		
		"Each." Adds Kosuke.
		
		The young man in purple reaches for his beltpouch, seeming to not even notice he's being robbed. "Ancestors, this economy!" He groans while handing over 30 Shards. The young woman in matching purple gi beside him shakes her head in astonishment and the two take off after Desdemona, going down the wrong road. Whatever ritual they hoped to learn from the Sunbringers, they're not learning it anytime soon.
		
		[b][Item Gained: 30 Shards][/b]
		*set shards + 30
*page_break
*if (explosives = 2)
	*page_break
	After the three disciples leave you feel a buzzing sensation in the air. The hairs on the back of your neck spring up and a heat builds up in your core like a campfire's warmth getting dangerously close. You look into the barn of prisoners to see who could be causing this but they each stare back in confusion until several shout in alarm, pointing at a glow coming from your solar plexus.

	"Cycle!" Shouts Kosuke, shaking you by the shoulders and trying to help you to the ground.

	That's when it hits you: the fire. With so many enemies destroyed in the burning blaze the flames were fueled with the minor chi of two dozen souls, forming the barest hint of a Heavenly Gate that you'd already accepted into your soul. Now the power of the flame wants in.

	You feel none of Taio's corrupted essence from the burning sensation boiling up inside you and realize it's simply the aspect of Fire itself: it was [i]made[/i] to consume. To destroy. To burn.

	If you just reach out, the power of fire could be yours...

	[b][Elements can be used to solve several problems by spending Chi. Most Martial Artists can only learn 2 Elements in one lifetime.][/b]
	*choice
		#Embrace the power of the flames. [Learn the Fire Element]
			*set auracolor "red"
			*set element2 "Fire"
			*set element2rank 1
			Instead of fighting the invasive burning force in your spirit you embrace it, letting the red Fire-attuned chi burn throughout your very Cores. The power of fire doesn't harm your soul so much as it [i]fuels[/i] your soul, turning you into an engine of raw energy. Your punches burn up the fire inside to hit harder, your hostile chi can use your targets as fuel to burn hotter. The very flames around you call out in your senses and you realize you can see the heat of distant torches even through the trees by sensing the flames around you.
			
			[b][Element Acquired: Fire][/b]
			
			You reach out with a touch of your will to extinguish some nearby smoldering boards from the burning tavern with a thought, and it works. Then you push a fraction of chi into your hands and release new flames into the world, sending a stream at a different pile of debris to light it aflame. They burn up quickly, just as you desired.
			
			The feared power of the flame rests inside your soul, and when you release it your old white haze aura is replaced with a red inferno wrapped around your body.
			
			It's beautiful.
			*if (val = 1)
				
				Kosuke is staring at you open-mouthed, ${bffhisher} look of shock twisting into exaggerated disappointment. "No fair, why didn't I get cool fire powers?"
		#Deny the call of fire, your elemental affinity lies elsewhere.
			Spiritual cycling pushes your Aura Pressure down onto the burning sensation and snuffs it out, allowing you to walk freely without burning up.
			
			*set apval 2
			*gosub_scene quicks apboost
			
			While an element would be nice to have, you have other ideas beyond a basic offensive element like Fire.
			
			"Close call," Kosuke asks, inspecting the hole in your shirt where you were almost burned through. "What happened?"
			
			"I think it was the energy from the fire."
			
			"What the heck, then why didn't I get any?"
	
	*if (val = 1)
		"Great question for later," you reply through a cough of black smoke, "let's get these people free first."
	*page_break

The next twenty minutes go by seamlessly as you free the hostages.

"Oh thank you, thank you, and thank you again!" Shouts the last farmer as you free him from his manacles. "I'm going to name my first
*if (heshe = "he")
	great-grandson
*else
	great-granddaughter
after you, regardless of what my grandson wants!" He's the last of the abducted farmhands and families to be freed, with over 60 in total crammed into the barn like cattle.

They all stand outside now as if waiting for your edict while this particularly old farmer hugs you a little too long. You
*if (ruthless <= 52)
	gently
push him away and step out to address the crowd. "I am ${fullname} of the ${clan} Clan and on behalf of the Thunderfall Sect you can all return to your homes effective immediately, the Sunbringer issue has been dealt with from the top
*if (explosives = 2)
	to the bottom."
	
	They all glance over to the burning remains of the exploded tavern and nod their heads in agreement.
*else
	level. Their master is in my custody."

"But what will you do with the others?" Asks one of the children in the back. "The scary men that took us from our homes?"

An excellent question.
*if (underlings >= 1)
	You turn to the bandit you've personally taken as a personal captive.
	*if (capturedbandits = 0)
		
		As he's the last survivor of the entire lot you've only got one bandit hostage to deal with, besides their leader that you intend to turn in. You grab him by the neck and he jumps in fright. "I have taken a single bandit hostage and killed the rest. Let this be a lesson to our enemies!"
		
		The older farmers cheer in riotous applause, a boisterous hurrah that continues down the road as they all return to their homes to drink to your health and hopefully take a bath.
		*page_break
		*goto missionsuccess
	*else
		"Round up the other bandits with Kosuke, and remember what happens if you disobey me."
		
		"You heard ${himher}, slave!" Kosuke boasts,
		*if not (kosukeinjured)
			cracking ${bffhisher} knuckles.
		*else
			with forced malice through ${bffhisher} broken arm.
		"You're on Kosuke time now, so until $!{name} sees ${hisher} pile of bandits packed neatly in a row, you're my bitch."
		 
		Your underling shivers in fear and nods, leaving with Kosuke to round up the others. The farmers refuse to leave in the meantime,
		*if (explosives = 2)
			staying in the warmth of the burning tavern while
		waiting to see the judgment of their captors.
*else
	You turn to Kosuke. "Gather the bandits here, I'll go get their boss."
	
	Kosuke's eyes deliver more sass than you're willing to deal with right now.
	
	"Fine, [i]please[/i] gather the bandits here."
	
	A smile stretches across Kosuke's mouth in response. "You got it boss!"
	
It doesn't take long. With how your luck is going you expected Taio to have recovered and escaped, but his unconscious body still rests where you left it. Shortly after dragging him to the tavern lawn and punching him in the face again (just to be sure) Kosuke arrives with all ${capturedbandits} bandits and a pile of rope. Volunteers from the farmers take joy in binding the bandits hands and feet in the safety of your presence.

None of your prisoners try anything after seeing their empowered leader bleeding on the ground.
*choice
	#Bring them to town to face justice.
		*set honor + 5
		"Listen up, all of you." You announce to the bandits bound before you.
		
		"Yeah, and [i]bow[/i] like the prisoners you are!" Adds Kosuke, getting into character. $!{bffheshe}'s reminding you of when the two of you would play Good Guard - Bad Guard to get Jin or Rin to confess to something. Unfortunately you're in no mood to be the good guard.
		
		"The hostages you captured are wards of the Thunderfall Sect, which means you've all transgressed against Thunderfall Village. Each of you will march with me back to town where the Sect and the Magistrate will decide your fate. Anyone caught fleeing will increase their chance of getting a death sentence when they're dragged in for sentencing, and you [i]will[/i] be dragged. Do I make myself clear?"
		
		A few of them mumble half-hearted agreement. Kosuke throws an apple at one and nails him right in the forehead. "Answer your betters with enthusiasm, maggots!"
		
		"Crystal clear!" Shout a few of the now-frightened bandits with enthusiasm. Kosuke corrals them into a circle and binds their hands to each other while you help the farmers get back to their homes in peace where they all chatter about sharing a drink and hopefully taking a bath. Each thanks you in cheer and expresses their gratitude that the Sect is looking out for them, many offer you a share of their crops, and more than a few offer you their
		*if (heshe = "he")
			daughter.
		*else
			son.
		
		Life is good for the Warrior Caste.
		*set banditchoice "Justice"
		*set sect_thunderfall + 10
	*if (hustle)
		#Recruit them as farmhands and guards.
			*goto persuadebandits
	*else
		*selectable_if (persuasion >= 1) #Recruit them as farmhands and guards. [Requires Persuasion]
			*label persuadebandits
			*if (persuasion = 0)
				[b][Aura Pressure +2][/b]
				*set aurapressure + 2
			*else
				*set val (1+(persuasion * 2))
				[b][Aura Pressure +${val}]
				*set aurapressure + val
				*set val 0
			
		
			*set banditchoice "Farmhands"
			*set sect_thunderfall + 10
			*if (persuasion >= 2)
				*set sect_thunderfall + 5
			*set ruthless - 2
			*set commerce + 1
			"All I see before me is two groups of people. One who worked hard to make something from this mountainous valley and one who sought to take something from this mountainous valley. The way I see it, we can't have peace until there's only one group left."
			
			Some of the bandits hang their heads, others look up in horror. A few look around for a way out.
			*if (element2 = "Fire")
				red flames flow
			*else
				white haze flows
			around your body, even though the effect of flexing your aura strains you painfully after your fight. Still, the dramatic effect is needed. You look down on the bandits and proclaim your edict:
			
			"That's why I'm recruiting you as farmers and guards. You'll be expanding the farmlands and irrigation routes for these farmers until you've paid off your debt." You turn to the farmers. "Every head of household, come pick an indentured servant to work for you. And every bandit, keep in mind what happened to your leader." With a grunt you lift the unconscious, bloodied bandit leader up by the back of the neck. "I am giving you all a chance to learn useful skills instead of being beheaded in the town square. [i]Do not make me regret this.[/i]"
			
			It takes hours to sort out the details but eventually every farming family leaves with an indentured servant. It's a pleasant sight to see the farmers equipped with the bandits' armor and weapons.
			
			"You think this will work out?" Kosuke asks as you watch the last family leave.

			*if (ruthless >= 53)
				"It better, for their sake." You crack your knuckles for emphasis. "Plus it's poetic justice, these assholes wanted to enslave our Laborers and now they're basically Slave Caste themselves. I think a win for the Laborers has a nice ring to it."
			*else
				"I hope so. Most of those men were just shitty kids a few years back, like we were. I want them to have a chance to be better. Not everyone slips and falls into a Heavenly Gate and a Caste promotion like I did."
			
			"Ain't that the truth." Says Kosuke of the Laborer Caste.
			*set bffrep + 3
	*if (hustle)
		#Pressgang them into raiding Sunbringer territories.
			*goto pressgangbandits
	*else
		*selectable_if (deception >= 1) #Pressgang them into raiding Sunbringer territories. [Requires Deception]
			*set honor - 2
			[b][Deception 1 Check Passed][/b]
			*line_break
			*label pressgangbandits
			*set val (deception * 2)
			*if (deception >= 1)
				[b][Aura Pressure +${val}]
				*set aurapressure + val
				*set val 0
			
			The bandits sit before you in silence awaiting your verdict. All possible punishments flash through your mind and a smile stretches slowly across your lips. Crusher Mao has always had spies looking into the Sunbringer activity but was never one for subtlety. His raids against them were always Martial Artists whose auras could be detected. You have an unpowered, undetectable fighting force in front of you. "Tell me, criminals, what did you hope to gain by enslaving our people for the Sunbringers?"
			
			None respond.
			
			"It's not a fake question. What did you really wish to gain? Wealth? Power? Protection? Prestige?"
			
			None respond.
			
			"Well I have good news for you. I'm offering a chance to get all of these things and more."
			
			[i]That[/i] finally gets their attention. Some of the farmers take a concerned step away from you. One speaks up. "Forgive me, Disciple, but what are you saying? Do you intend to let these men go?"
			
			"Yes." You respond casually. "But not to go free. I'm going to let them go do what they do best." You turn to the bound bandits with arms wide open. "I'm sending you back into the world to be bandits. Better bandits. [i]My[/i] bandits. You're going to raid the Sunbringer Sect and give a share of the profits to these farmers and myself."
			
			[b][Commerce Increase][/b]
			*set commerce + 2
			
			"But-" Says one of the bandits before Kosuke kicks him in the forehead and sends him tumbling. It's always good to have a right-hand
			*if (bffheshe = "he")
				man
			*else
				woman
			who knows the right time to act.
			
			"No buts." You reply as he stops rolling and groans. "You. Work. For. Me. Don't worry about the Sunbringers catching you or what areas you're going to raid. I'll supply you with their warehouse locations and guards' travel routes from the Thunderfall Sect intel records, you'll hit their local merchants on the roads and bring me a share of what you get in exchange for the next month's intel. The bonus is you'll be the least likely suspects because everyone's going to say you all died here today." You look to the farmers with an intimidating leer and they nod in agreement. "You see that? Everyone agrees. Congratulations on your fresh start." 
			
			*set banditchoice "Raiders"
	*selectable_if (taint > 10) #Sacrifice them all according to the eerie Path Manual's instructions. [Requires Corruption]
		*set ruthless + 2
		*set honor - 3
		*set taint + 15
		The Path Manual in your hands offered great power in many ways that you couldn't utilize at first, one being a mass sacrifice. You obtained the ingredients for [i]that[/i] far sooner than you expected. But there are far too many witnesses. "The bandits will be coming with me to face justice." You say to the crowd. "Farmers, disperse to your homes immediately. That's an order."
		
		Despite your commanding tone many of them are still thankful, bowing and offering free food to you and yours (Kosuke takes note) before leaving to celebrate together with many a drink and hopefully a bath.
		
		Once they've all cleared out you whisper to Kosuke.
		*choice
			#Tell ${bffhimher} about your plan.
				"None of these guys are making it to Thunderfall Village."
				
				"Nice." Says Kosuke.
				
				"I'm going to sacrifice them to their boss's Path Manual for power."
				
				"I already said nice." Replies Kosuke. It seems taking a beating has left ${bffhimher} feeling as hungry for revenge as you feel.
				*set bffrep + 2
				*set val 1
			#Dismiss ${bffhimher} to keep it a secret.
				"Go patrol the roads, I'm going to execute these guys in secret and can't risk anyone finding me."
				
				"Nice." says Kosuke, who then takes off to discourage any travelers from discovering your actions, though ${bffheshe}'s oblivious to what those actions are.
				*set val 0
		
		With
		*if (val = 0)
			Kosuke gone
		*else
			Kosuke's help
		you setup the blood ritual according to the eerie Path Manual's instructions, invoking the correct handseals on top of splatters of blood you leave in a circle around the bandits. Between
		*if (val = 0)
			yourself
		*else
			yourself, Kosuke,
		and 'Master' Taio you find no shortage of bleeding injuries.
		
		"What's that for?" Asks one of the smarter bandits while you invoke handseals while walking around them.
		
		"It's to make sure you don't escape. Now shut up before I beat you."
		
		He stays quiet, being one of the smarter bandits. It doesn't serve him well in the end. Your handseal ritual finalizes and the eerie glow from before envelopes the entire large circle around the tied bandits. Tendrils of crimson power rise from the edges of the circle and slither inward, piercing into the souls of each restrained bandit.
		
		The screaming begins.
		
		Wails of the dying bandits buffet your mind as the ritual ages them in seconds, sucking out their life force to the point that their physical bodies wither to dust and disappear. With each lost bandit the crimson glow of the ritual grows brighter and so too does the rush that you feel when the ritual pushes not just their chi but their very essence into you. The power and potential of the bandits' shattered souls flows through your body, the shards of their lifeforce wreathing around your soul like armor. Slowly the wails of the damned fade to nothing and the eerie glow dies out as this new power settles. You feel invigorated more than ever in your...
		*choice
			#Body [+1 Health]
				*set health + 1
				Every breath you take makes you feel more [i]solid[/i] as your body is filled with potence and rebuilt sturdier than ever.
			#Soul [+1 Chi]
				*set chipool + 1
				All the colors in your vision grow more vivid as your spiritual capacity increases and you feel a deeper connection to the natural chi of the world.
		*if (race = "Oni")
			
			[b][Race Event: Oni][/b]
			
			You feel a deeper satisfaction from the absorption of human souls and you don't quite know why, but you [i]like it[/i].
			
			*set apval 15
			*gosub_scene quicks apboost
			
		*if (val = 1)
			*set kosukecombat + 2
			Kosuke even benefits from the ritual too, having been standing outside the circle just as you had. $!{bffhisher} eyes are closed and ${bffhisher} face tilts upward in satisfaction at the feeling of power rushing through ${bffhimher}. It's good to have an accomplice that's equally as guilty.
		*if (underlings >= 1)
			*if (val = 1)
				That reminds you...
			
			A quick glance at your underling shows him cowering by the barn door in a silent scream. You'd better make sure he doesn't run his mouth. "Tell no one what you saw here today, or you're next."
			
			The cowering man drops to a kowtow immediately. His head presses against the floor and his voice cracks. "Y-Yes of course master! Of course! Anything you say!"
			
			It appears the man has pissed himself.
		*set banditchoice "Sacrifice"
	#Let them go.
		*set honor + 2
		*set ruthless - 2
		"You're free to go."
		
		"What?" Says Kosuke.
		*line_break
		"What?" Demands the farmers.
		*line_break
		"What?" Asks the bandits.
		
		"I said you're free to go. You were hired for a job, you failed, and now you're free to go. The leader here is my target, the rest of you are just a tool he used. Get out of here."
		
		One farmer finds more courage than most. "You can't do this, they meant to ruin my life! I will..." His courage fades from the look you're giving him. He shuffles back into the crowd without a word.
		
		You expected a gentle elbow from Kosuke and for ${bffhimher} to want to know what got into you, but when you look over ${bffheshe} is instead filling a burlap sack with apples. That was quick.
		
		The bandits slowly get to their feet, eye the farmers, and both parties slowly separate at the road. You hope to never hear from either side again.
		*set banditchoice "Freedom"
*page_break
*label missionsuccess
*set spareval_2 capturedbandits
The journey back to town takes longer than the journey out of town. Mostly because
*if (banditchoice = "Justice")
	you're corraling ${capturedbandits} bound
	*if (capturedbandits > 1)
		prisoners
	*else
		prisoner
	on a long march and
	*if (capturedbandits > 1)
		none of them are
	*else
		he isn't
	in a hurry despite the occasional threat. It doesn't help that
your donkey cart is going uphill and there's a third body in the back, the bound up unconscious body of 'Master' Taio. Considering his strength you used enough rope to cover most of his body and then added chains for good measure.

A feeling of relief washes over you when you pass through the Thunderfall Village gates without issue, nodding to the guards on duty.

"Hail, Disciple." Says one of the guards. "Anything to report?"

For once, you do have something to say to the guards. It feels unnatural, normally you and Kosuke are avoiding them instead. "Summon Master Mao and Magistrate Khan to the town center, I've captured
*if (banditchoice = "Justice")
	slavers that were abducting our peasants."
*else
	the Martial Artist behind our missing peasant problem."

The guard nods and does exactly as he's told, which is surprising and refreshing.

Ten minutes later Master Mao meets you in the town center. He approaches with a confident stride and a scowl. "Mission reports are done in private, Disciple, not in the town square for everyone to see."

You suppress an urge to retort back and instead keep things professional. "Apologies [i]sir[/i], but the abductions have been dealt with. It was bandits working for the Sunbringers to cause instability for Thunderfall Village. I've brought 
*if ((banditchoice = "Justice") and ((capturedbandits = 19) or (capturedbandits = 20)))
	them all
*elseif (banditchoice = "Justice")
	the survivors and their leader
*else
	their leader
here for judgment."

"Sunbringers eh? Sounds typical, I figured they'd quiet down after I finished off Master Bangle but they've only gotten dirtier. Now let's see who we have here." You feel a powerful sensation press down on your spirit. A quick glance at Kosuke's pained expressions tells you that ${bffheshe} feels it too. Mao's massive Aura Pressure is scanning the entire market square. Yet rather than lean closer to the heavily tied unconscious bandit leader, his face snaps in [i]your[/i] direction. "...Why the fuck do you have
*if (element2 = "Fire")
	Fire Chi in your
	*if (jadedragonfoundation)
		soul and
		*label jademaowhy
		an Aura Pressure in the thousands?"
		
		"I was born special?" You say, and try to leave it at that.
		
		He doesn't budge, keeping his eyes burrowing into you. "A special birth doesn't mean jack shit for enlightened Advancement, why do you have [i]Immortal Cores?[/i]"
	*else
		soul?"
		
		You begin to sweat profusely, not helped by the burning energy in your spirit. "I uh....I did a lot of burning people."
		
		"Hah!" Mao slaps you on the back to a degree that [i]almost[/i] doesn't hurt. "Kid, burning Sunbringers isn't something to be ashamed of. Hell, have a drink on me for it." He flips you a gold coin from seemingly out of nowhere.
		
		[b][Item Gained: 1 Gold][/b]
		*set gold + 1
		
		You catch it, getting used to this new Mao, and then freeze with a chill down your spine when you feel his nose pressed against your cheek, his eyes burrowing into you uncomfortably close. 
		
		"C-Can I help you, Sect Master?"
		
		"Why does your spirit have Immortal Cores?"
*elseif (jadedragonfoundation)
	*goto jademaowhy
*else
	Immortal Cores?"

"I saw him make them," you point to
*if (banditchoice = "Sacrifice")
	Taio and omit the mention of the haunted Path Manual,
*else
	Taio,
"I figured I could do it too. So I
*if (jadedragonfoundation)
	uh,
did."

Mao looks unconvinced. "That's a training technique we teach after years of study. Half the lower Disciples can't do it."

"Then ${heshe}'s better than half the lower disciples." Kosuke smugly retorts with crossed arms. Mao tightens his scan onto Kosuke who immediately drops unconscious from the spiritual pressure.

"That's better." Mao
*if (jadedragonfoundation)
	says, pulling away from you.
*else
	says.
"And this is suspicious. Highly suspicious. Nobody uses Immortal Core Advancement [i]during[/i] a fight. If you know how to do it, you do it during training and then get used to your new power. You're sure he used it during battle? Tell me he didn't announce its name like a combat Technique."

"He did."

"Hah!" Mao snorts out a quick laugh. "What a loser." He shakes his head looking down on the captured prisoner, then looks over to you only to notice your deadpan expression. "...Did [i]you[/i] announce its name like a combat Technique?"

*if (deception >= 2)
	[b][Deception 2 Check Passed][/b]
	*line_break
	[b][Aura Pressure +3][/b]
	*set aurapressure + 3
	
	"Give me more credit than that, Mao."
	
	"That's [i]Master[/i] Mao." He replies, focused more on his vanity than your lie. "But
*else
	[b][Deception 2 Check Failed][/b]
	
	"Uh....No?"
	
	*set metmao + 10000000000
	Mao cringes. "If anyone asks at the Trials, you're not from Thunderfall. But
back to my point, this doesn't add up. Let's say he did use Immortal Core Advancement in the middle of combat. Then what, you just figured it out from seeing it once?" He studies your face. "Who's been teaching you? Whoever it was, they're not from Thunderfall." An ominous green power glows around his body. "That's a problem."

You're genuinely confused so it's not hard to look the part. "I don't know what to say. He used 
*if (tomeuse = 2)
	it during the fight and I kind of...felt out what was happening. He was attuning his chi to four purposes that match the four Cores, like tying them to a reflex, and I did the same." You leave out mention of the haunted Path Manual he used to do it, since you used it too. No need to invite trouble.
	
	Finally he relents scrutinizing your face and waves a dismissive hand with a sigh. "Eh,
	*gosub maoexplains
*elseif (tomeuse = 1)
	some strange Path Manual that powered him up. It highlighted the right four areas to focus on for him, so I worked off that idea. Why don't you tell people the secret if all they have to do is focus their chi towards a specific desire per Core?"
	
	"Because
	*gosub maoexplains
	Show me that Path Manual you mentioned."
	
	You raise the haunted Path Manual out of your satchel, its leatherbound screaming face on the cover available for display. Mao rips the Path Manual from your grasp and his nose wrinkles. "Ancestors above, this thing [i]reeks[/i] of Fiend essence. You didn't use it did you?"
	
	"No." You say definitively, and judging by Mao's expression you're feeling grateful you didn't.
	
	"Good, you'd be on your way to becoming something rotten if you had. A ghoul or a grim, or just shedding your skin and bones to become a bloodwalker." He looks down at Taio and tilts his head inquisitively. "Just what the Hells kind of enemy were you facing?" Before you can open your mouth he holds a hand up, "Nevermind, kid. I was thinking out loud, I don't actually care what you have to say. I'll get all the details out of him myself because
*elseif (tomeuse = 3)
	some strange Path Manual on himself, made four glowing crimsons orbs of power that highlighted the right areas to focus on, and I figured it was a clue that each Core represents a type of desire. Then I just...did it. It's not hard, why don't you teach people earlier if it's such a simple concept?"
	
	"Eh,
	*gosub maoexplains
	Show me that Path Manual you mentioned."
	
	"I destroyed it."
	
	*set maorep + 3
	Crusher Mao's expression relaxes. "Not bad, kid. It sounds like the thing was a Soul Treasure he was using to store his power, which I've never heard of so who knows what other weird shit that Path Manual might have held. Destroying it makes sure he can never get that power back. Now move,
I'm taking our guest here to the torture chambers for questioning."

An elderly voice interrupts him. "I doubt that would bring anything useful, Master Mao."

Crusher Mao closes his eyes as if to suppress for a headache. "Magistrate Khan, so good of you to join us."

The Village Magistrate approaches the scene with a limp steadied by a cane in his right hand. You've never seen him need one before. "It is the market square, after all. I believe anyone could join us." He looks down on the captured and bound form of Taio, then back to you and Crusher Mao with worry in his aged eyes. "Ah. I see. Such a terrible thing to bring to our doorstep. How much do either of you know about Demonic Sects?"
*choice
	#"Like a Martial Arts Sect of all Demons?"
		What the hell is a demonic Sect? "You mean like a Martial Arts Sect of all Demons?"
		
		Damn, that sounds scary.

		Magistrate Khan looks to Sect Master Mao as if he's to blame for your ignorance. Mao's massive shoulders respond with a single shrug.
		
		"No." Says the Magistrate. "A Demonic Sect is a group, or rarely an individual, who partake in forbidden cultivation Techniques that allow them to harness power from the blood of even the most powerless peasant. Most Demonic Sects are pathetic dredges who borrow power from malignant spirits at their formation and use that borrowed power to capture and drain their victims. Such Demonic cultivation is
	*selectable_if (lore >= 2) #"Quite a bit." [Requires Lore 2]
		[b][Lore 2 Check Passed][/b]
		*line_break
		[b][Aura Pressure +2][/b]
		*set aurapressure + 2
		
		"Demonic Sects use forbidden knowledge to harness power from human sacrifice, right?" You jog your memory from your time at the library and, a bit more shamefully, the time when you and Kosuke researched how to get strong fast. "Most of the time they form from evil spirits lending some power to angry peasants."
		
		"Very good." Says Khan, "And that is why we kill such cults whenever they form; their practice is heavily
forbidden for good reason. Using Demonic cultivation eventually taints the user's soul and body, warping them beyond recognition into Fiends like ghouls, shades, or bloodwalkers. They endanger us all for short-term gain. Only death awaits such foolishness."

Mao looks back to Taio. "So that's what I sensed on this guy, Fiend essence."

"Worse." Khan adds, stepping up and placing two fingers on the bandit leader's forehead. "Demonic Sects steal power from the blood of their enemies. This man cannot become a true Fiend..." Khan pushes chi into his two fingers and the captured man, the demonic cultist you fought so hard against, completely disappears in a puff of smoke. "...For he is no man at all."

"Kurokonton Style..." Master Mao mumbles to himself. "The Cursed Lands' Art of Ninjutsu."

Mao and Khan both look at each other in silent concern.

"I don't get it," you say to break the silence, "what does this mean?"

Crusher Mao is the first to speak. "The person you fought wasn't real. They were a Clone Technique, a temporary copy of a someone much stronger. It's an advanced Technique used by the shinobi of the Cursed Lands, one of the five Inner Kingdoms."

Khan nods, rubbing a hand down his beard and nudging an unconscious Kosuke with his foot, "What's worrying, young $!{name}, is there are no Cursed Lands settlements in this region of Outer West. The demonic cultist is either a proficient Martial Artist from the Inner Kingdoms where the natural chi is much stronger, or he killed one and stole their power. Either way he is powerful, well traveled, and still out there somewhere." He looks to Crusher Mao.

"The Inner Kingdoms..." There's only one Martial Artist from the Inner Kingdoms that you've ever met and that's Crusher Mao. When you look to him, squatting on the ground where the cultist's clone was laid out just a moment ago, you see a hint of doubt in his stony expression. Crusher Mao has always been a big fish in a small pond. Another big fish has arrived.

"So what do we do?" You ask.

"[i]You[/i] do nothing." Khan says, "[i]I[/i] reach out to our allies to inform them of the threat. The Heavenly Ascension Trials begin soon, and while the Imperial Archonate and Inner Kingdoms may not often care for the dangers facing Outerland settlements like our own, they may assist against a threat to their prospective recruits." With a quick double-tap of his cane against the ground Magistrate Khan vanishes from sight in a swirl of golden energy.

You had no idea he could do that.
*page_break
Crusher Mao huffs, standing and stretching his arms wide. "That old fart finally whips out the chi sorcery theatrics. He must be feeling insecure."

"What about you?" Regret floods through your mind the second you ask, but Mao doesn't seem insulted for once.

"Tch, I'm excited. Haven't had a good fight since I crippled 'Master' Bangle. Should've let him use that new Technique, now I'll never see it..." He looks down at you with a sideways glance. "Another lesson, kid. Crushing your enemies is exhilarating but running out of enemies is a problem I wouldn't wish on any warrior. Even you." He looks into the sky with an oddly hopeful expression. "That's why I envy you right now. Whoever this mysterious cultist is, you made him lose face when you beat his clone and ruined his operation. That's got to earn you a spot on his shitlist." He lets out a prolonged sigh. "Now that's an enemy worth having, it should have been me....Ah well, I release you from any duties for the next year. Obviously I can't have you training with Tian Fang and the other lower disciples as well."

"WHAT?!" You blurt out. "That was the entire point of doing this mission!"

"Welcome to real life, kid. There's a target sign on your back now that I can't spread to the other weaklings. You did what you were supposed to and it didn't work out, life sucks. Move on."

Your fists shake and you look upon Mao with hatred, the bastard screwed you over again. Yet your composure holds. Mastering Immortal Core Advancement already put you above most of those other lower disciples anyway, who says you need them? All you need is results.
"Fine. But
*if (banditchoice = "Justice")
	what about the other captives I acquired? Dragging them all here was a lot of work and
I've earned payment for completing the
*if (tomeuse = 1)
	mission and acquiring that cursed Path Manual for the Sect."
*else
	mission."

Mao rubs his temple in exasperation.
*if (banditchoice = "Justice")
	*set prestige + 1
	"Nobody cares about a
	*if (capturedbandits > 1)
		bunch of captured, unpowered failures."
	*else
		single unpowered criminal."
	He looks over at the
	*if (capturedbandits > 1)
		${capturedbandits} captured bandits. "How many of you want to be slaves? Raise your hands."
	*else
		captured bandit. "Do you want to be a slave? Raise your hand."

	*if (capturedbandits > 1)
		None raise their hands.
	*else
		Your prisoner stays stiff as a board, unmoving.
	
	"There you have it." Mao says. 
	*if (capturedbandits > 1)
		"They're useless then, kill each one with an unraised hand."
	*else
		"He's useless then, kill him."

	*if (capturedbandits > 1)
		Every one of them immediately raises their hands.
	*else
		The prisoner immediately raises both hands.
	
	"Sure, whatever.
	*if (capturedbandits > 1)
		Kid you can have one, deliver the rest to the town clerks and they'll sort it out."
		
		[b][Commerce Increased][/b]
		*set commerce + 1
		*line_break
		[b][Prestige Increased x2][/b]
		*set prestige + 2
		
	*else
		Kid you can have him. Sell him, enslave him, eat him, I really don't care."
	*set underlings + 1
*else
	"I'd normally beat you for the attitude but we've both had a long day."
He throws a sack of shards at you that you just barely catch before it can smack you in the face.
*if (tomeuse = 1)
	The second item he throws, a thick book, [i]does[/i] smack you in the face.

[b][Item Gained: 100 Shards][/b]
*set shards + 100
*set prestige + 1
*if (tomeuse = 1)
	*line_break
	[b][Item Gained: Skill Manual][/b]
	*set skillmanual + 1

"There's your pay. More than most other Laborers make in a month." You notice he still refuses to acknowledge that you're Warrior Caste. "And no more missions for you until the Heavenly Ascension Trials are over."

Unlike Khan's exit, Mao leaves in a normal human fashion: stomping off while grumbling. "Can't believe kids these days, Advancing in the middle of a fight. No fucking respect. Send ${himher} on another mission and ${heshe}'ll learn how to write ship blueprints in the middle of a grapple or some shit. Ancestors, what is this world coming to."
*if (craft >= 3)
	
	[b][Craft 3 Check Passed][/b]
	*line_break
	[b][Aura Pressure +10][/b]
	*set aurapressure + 10
	
	You actually do know how to write ship blueprints.
*page_break
Without such an insanely high Aura Pressure focused on ${bffhimher} anymore, Kosuke wakes up shortly after Mao's departure. "Hnnnggg...My head..." The two of you are in the center of the market square with people finally starting to enter now that the Magistrate and Sect Master have left. Kosuke lies flat on ${bffhisher} back and looks up at you with eyes half-open. "What'd I miss?"

"A lot." You hold up a finger with each new revelation. "Taio was a Clone created with a Technique, the real version is so strong that he killed, or is, an Inner Kingdom shinobi as strong as Mao, he's part of a cult that uses people's blood for power and might turn into Fiends, and 
*if (banditchoice = "Justice")
	Mao gave the captured bandits the choice of slavery or death, they chose slavery." You take a long breath after such a run-on statement. "I get to keep one."
	
	Kosuke closes ${bffhisher} eyes again and relaxes in the sun. "What a wild day. I don't envy you making an enemy of someone on Mao's level though. What a short straw, goodluck."
	
	You eye Kosuke wondering if ${bffheshe} took brain damage. "You fought him too."
	
	$!{bffheshe} freezes, not even breathing for a moment. "Oh Hells, you don't think I'm on his list do you?"
	
	"Absolutely."
	
	Kosuke buries ${bffhisher} face in ${bffhisher} hands. "I'm going to have to change my name." $!{bffheshe} widens ${bffhisher} hand and peaks through two fingers. "You gonna keep the slave?"
	
	*choice
		#"Only until he's repaid his debt to society for what he's done."
			"I'll only keep him as a servant until he's paid his debt to society for what he's done."
			*set ruthless - 2
			*set honor + 2
			
			"Oh yeah?" Says your prisoner, stepping too close to you for comfort. The shaggy ex-bandit's breath and beard smell heavily of booze. "Is that how you see it? Who gets to decide how long I have to 'serve', [i]you?[/i] Some form of justice that is." He spits on your boots. "You're no better than me!"
			*label smackem
			*choice
				#Elbow him in the nose.
					*set ruthless + 1
					Blood spurts from the man's nose as you crack your elbow up faster than his eyes can track. Some of the blood rains down on your gi. Ugh, Rin will have to wash these.
					
					The captured slaver screams and holds his nose with bound hands but you grab him by the collar and lift him off the ground. "Arrogant prick, you tried to enslave [b]my people[/b] and now you complain when it happens to you? If you think this is up to debate then a broken nose will be the least of your concerns. Do we understand each other?"
					
					He nods so quickly that more blood spills onto your sleeve.
					
					*if ((bffromance >= 1) and (bffheshe != heshe))
						"[i]Hot.[/i]" Kosuke whispers at your side, stepping closer and placing ${bffhisher}
						*if (heshe = "he")
							arms around your shoulders.
						*else
							hands on your waist.
						*label kosflirt
						"So what are you doing later?"
						
						"Resting." You say honestly. "My second Advancement is still sending growing pains throughout my muscles and I haven't slept in my own bed since before the mission."
						
						"I, too, have not slept in your bed since before the mission." Kosuke adds with a
						*if (bffheshe = "he")
							devious grin
						*else
							devilish smile.
						*choice
							#Head back to your room with Kosuke.
								The two of you head back to your house for some much needed relaxation, all the while your
								*if (underlings >= 2)
									underlings follow
								*else
									underling follows
								behind, cringing.

								Your room is not soundproofed.
								
								[b][Aura Pressure +3][/b]
								*set aurapressure + 3
								*set bffromance + 1
								*Set forexp + 1
								*set bffrep + 3
							#Take the night to rest.
								"Maybe another time." You hiss slowly from the ache of every sore muscle. "My legs feel like they got run over."
								*set solexp + 2
								*set bffrep - 2

								"Understandable,
								*goto sameway
					*else
						"Damn, where did that come from?" Kosuke asks.
						
						Turning to ${bffhimher} takes the look of anger off your face when you see ${bffheshe}'s almost laughing. "Heh...Yeah I may need sleep." You drop the prisoner-bandit and he crumples to the floor. "I think my Advancement's still reeling through my body. Ancestors above, I miss my bed."
						
						"Heh,
						*label sameway
						I feel the same way. My eye needs a healer and sleeping on the cart made me feel as out of shape as Big Chu looks. Catch you tomorrow?"
						
						"You got it."
						
						The two of you head to your respective homes for the first relaxing night in what feels like forever.
				#"Quit your whining and clean your spit off my boot."
					"Quit your whining and clean your spit off my boot." You say to the captured slaver, meeting his angered face with an impassive stare.
					
					"I-" He raises a fist to your face and pauses, suddenly remembering what you did to his boss. You see recognition in the man's eyes and catch on that, somehow, in the middle of his tirade, he forgot that you're an empowered Martial Artist and he is not. "-Will go find a rag."
					
					"Your shirt will do." Kosuke
					*if ((bffromance >= 1) and (bffheshe != heshe))
						says before turning back to you.
						*goto kosflirt
					*else
						says with a malicious grin. "Ready to get out of here?" ${bffheshe} says to you. "Because I can use a healer's hut."
						
						"Agreed." You say while your new servant shines your shoe. "Thanks for the assist."
						
						"Don't mention it." Kosuke replies. "No really, don't mention it. Rin wanted me to collect honey for her makeup while we were down there and I forgot. If she asks, I never went."
				#"Fine, then go free and prove you're a better man."
					*goto freeslaver
		#"A free slave? Hell yeah I'm keeping him."
			"A free slave?" You look over to the bound bandit like he's a pile of walking gold. "Hell yeah I'm keeping him."
			*set honor - 2
			*set ruthless + 1
			
			"Keep me?!" Shouts your captured slaver. "That makes you no better than me! I thought you were supposed to be some sort of hero?"
			*goto smackem
		#"Nah, he's free to go."
			With one last glance at your slave you give a slow shake of the head. "Nah, he's free to go."
			
			*label freeslaver
			*set underlings - 1
			*set ruthless - 4
			"Really?" Asks Kosuke and your prisoner simultaneously.
			
			*if (honor >= 50)
				"Yes, I have no use for you. Remember that you served a master who overstepped his bounds, and do not repeat that mistake again."
				*set honor + 2
			*else
				"Yep." You cut the ropes binding his hands together without ceremony. "Now piss off."
				
			The freed man stares at his hands dumbfounded, then looks around at Thunderfall Village's market shops. "Can I...Stay here? Inside the walls?"
			
			*set prestige + 1
			*label pointinthatway
			You point across the market square. "Town clerks are that way, go ask for a job."
			*goto returnhome
		*if (underlings >= 2)
			#"Nah, he's free to go. And so is my other underling."
				With one last glance at your slaves you give a slow shake of the head. "Nah, he's free to go. And so is my other underling."
				
				*set underlings - 2
				*set ruthless - 6
				"Really?" Asks Kosuke and your prisoners simultaneously. The two captured slavers stare at each other in astonishment.
				
				*if (honor >= 50)
					"Yes, I have no use for you. Remember that you served a master who overstepped his bounds, and do not repeat that mistake again."
					*set honor + 2
				*else
					"Yep." You cut the ropes binding their hands together without ceremony. "Now piss off."
					
				The freed men stare at their hands dumbfounded, then look around at Thunderfall Village's market shops. "Can we...Stay here? Inside the walls?"
				
				*set prestige + 2
				*goto pointinthatway
		#"I'd rather sell him at the market."
			*set underlings - 1
			*set shards + 120
			[b][Item Gained: 120 Shards][/b]
			
			Selling your captured slaver into slavery turns out to be more lucrative than you expected, giving 10
			*goto soldslaves
		*if (underlings >= 2)
			#"I'd rather sell both my underlings at the market."
				*set underlings - 2
				*set shards + 240
				[b][Item Gained: 240 Shards][/b]
				
				Selling the two slavers turns out to be more lucrative than you expected, giving 20
				*label soldslaves
				years worth of your old allowance.
				
				"Wow, no wonder you guys were selling people." Kosuke says as you sell your enemy for a heavy sack of Shards. "You're worth a fortune."
				
				Rather than enjoy the irony you simply finish the trade and go home to rest. It's been such a long couple of days and your body is still reeling from your Advancement. Sleeping in your own bed sounds [i]amazing[/i] right now.
	*goto returnhome
*else
	Mao mentioned a torture chamber at one point."
	
	"We have a torture chamber?"
	
	"We do now." You shrug.
	
	Kosuke closes ${bffhisher} eyes again and relaxes in the sun. "Cool. What a wild day. I don't envy you making an enemy of someone on Mao's level. Heh, goodluck."
	
	You eye Kosuke wondering if ${bffheshe} took brain damage. "You fought him too."
	
	$!{bffhisher} expression changes from relaxed to horrified. "Oh Hells, you don't think I'm on his list too do you?"
	
	"Absolutely."
	
	"...I'm changing my name."
*label returnhome
*page_break
[i]You find yourself in the middle of a bustling marketplace, far from home in an unfamiliar city. The smiles of travelers greet you and children chase each other around the market in circles, their laughter ringing through the air. Suddenly the laughter turns to screams when the bright day turns to a night as dark as ink. The people around you drop to their knees, looking to the sky where their sun has been swept away, and their bodies wither as if drained of life.[/i]

[i]You run towards them, desperate to help, but as soon as your fingers graze their skin they turn to ash. The entire city, once vibrant and full of life, is now silent and empty. You are left alone in the midst of the destruction that, deep down, you know you have wrought.[/i]

And then you awake.
*page_break Chapter 3
*finish

*label maoexplains
that's not really how it works. Mortal Core Advancement is about using the inner chi you've built through hard work, while Immortal Core Advancement is about seizing absolute control of the chi you've absorbed from the world. There's a hundred ways to do it and they all come down to willpower. You both imagined some visual aid for your idea that it's linked to areas of the body or desires or whatever. The confidence of thinking you're right increased your willpower. Just like how it's easier to lift a heavy object if you've lifted it before, because you [i]know[/i] you can lift it."

Mao waves his hand over the horizon as if tracing a rainbow. "Confidence. In reality your Combat Cores are all in your spirit's center, not scattered throughout your body. You were wrong but it worked anyway, so consider this a good lesson, kid. Much of the mystical side of cultivation is based on believing you're right more than being right. That's why it's hard to teach."

Huh...You never thought of it that way. This is the first time you've ever heard a real lesson from Mao. It's insightful but off-putting.

Mao dusts off his hands and looks around the market square before continuing. "Nothing either of you did is that unusual, except that Immortal Core Advancement is not a temporary power up, it's permanent." He looks back down on your prisoner. "If this enemy knew how to do it the whole time but refused to then he was crippling himself for who knows how long just to avoid detection. That's strange, and I don't like strange.
*return