*comment REMOVE *save_checkpoint
*set age + 1
*set shards + (commerce * 2)
*temp fangfightcounter 0
*temp fanghealth 5
*temp fangambushed false
*temp fangambushyou false
*temp usefire false
*temp val 0
*if (subrace = "Wolf")
	*temp mutt "lesser wolf"
*elseif (race = "Yokai")
	*temp mutt "dumb mutt"
*else
	*temp mutt "Yokai mutt"
*if (element1 = "Earth") or (element1 = "Ice")
	*set an "an"
*else
	*set an "a"
*gosub_scene quicks timepass

It happens in the middle of a cold winter's night.

You're resting in a cave dug into one of the nearby mountains. Only two days remain before you have to leave for the Trials and you're still not ready; you've been training in the wilderness relentlessly the last week for any last advantage.
*if (roc >= 2)
	${rocname} is off hunting for prey. You're quite proud of her development, she's bigger than most adult eagles despite being adolescent. But you can't watch over her all the time now that she's learned to fly, so you rest while she's out.
	
From deep within a dream you feel the impression of natural energy in the back of your mind, its aura pressure immense. There's no mistaking this feeling since it's what lead to your first Advancement.

The land's natural energies have grown unstable and it's venting some of that energy out, a bounty of natural chi waiting to be claimed. A Heavenly Gate.

You awaken immediately.

It takes seconds to ditch your blankets and don the Thunderfall combat gi before running out into the late winter air where you're hit with heavy rain.

Wait, rain? It was freezing cold when you went to bed, and what happened to all the stars? The sky is completely dark.

That's when a violet bolt streaks across the horizon and illuminates the dark nimbus that blot out the moon.

Storm Aura! It's a Heavenly Gate of storm aura and it's happening right over your head!

*page_break
You've been wishing for a Storm Surge for the entire year.

Surges of Storm Aura are the hardest to get to, you have to enter the storm clouds to get any real results, but that's why they're the richest bounty in Thunderfall. Less competition.

The natural energy in the deep western sea where the storms form is far more potent and dangerous than the natural energies of your mountainous outer Province. There are very few flying creatures in that ocean to get up to the storms and harness their power, and the rare flying coastal Martial Artists can only absorb a fraction before they have to descend. Cycling disturbs active Techniques.

You, however, live in high elevation. You can climb mountains higher than the clouds and sit down within the storm, meditating for hours or days until it passes. Heavenly Gates of Storm Chi are feasts for your village, your spirit's natural prey.

You just have to get to the nearest peak before anyone else does.

*page_break
Dark stormy winds blow rain into your face and violet lightning cracks overhead to overpower even the sound of your own quick footsteps slapping against heavy puddles. You rush through the gravel trails and climb smaller cliffsides for shortcuts, eager to close the six miles between you and the peak that actually enters the clouds.

*if (element1 = "Wind")
	There's no time like the present to test out your Elemental powers.
	
	With a focus of will you envision the air beneath your feet as condensed swirling springs, waiting for the right signal. A sliver of chi sets that signal and gusts appear under each step, bounding you through the air thirty feet at a time.

	*set apval 5
	*gosub_scene quicks apboost
	
*elseif(element1 = "Light")
	There's no time like the present to test out your Elemental powers.
	
	A focus of will and a sustained output of chi connects your body to the property of light, which is always moving. You don't move nearly as fast as light but you do triple in running speed and leave a white outline behind you as if you were surging an Agility Core. The difference is, this isn't just a dash. It's your speed for the whole voyage.
	
	*set apval 5
	*gosub_scene quicks apboost
	
*else
	It's a long trek and you thank the Heavens you were already this close. For everyone else in town it's three times as long.
The mountain's trail finally leads you into the heavy dark clouds touching the land like a black fog. Raw power emanates through the air.

"Danger." Whispers Taio.

You leap in surprise and sweep your left leg in a full circle arc, hitting nothing. When you land you check your surroundings and see nothing as well.

Try as you might you cannot find signs of the man. The mud around you is undisturbed save for the constant rain that blocks your vision, and the chi of the Heavenly Gate blocks your spiritual senses even worse. Minutes pass without issue while you stay on guard, searching your surroundings until you wonder if you're just hearing things.

Suddenly a distant burst of violet lightning illuminates your surroundings once more. In its light you see a figure standing ahead on the steep trail, not the demonic cultivator you expected but an outsider nonetheless, one you recognize.

Tian Fang.
*page_break
The two of you have barely spoken in her whole year at your village. Her mission to train everyone took up all her time, and your mission was to train without her. You didn't imagine you'd have to deal with her as competition at any point before the Trials. A quick spiritual scan tells you no other Aura Pressures can be sensed from the mountain below. If you really were hearing things then this entire storm's natural energy is yours for the taking at its strongest hour.

If not for Tian Fang blocking your way.

*if (stealth >= 2)
	[b][Stealth 2 Check Passed][/b]
	*line_break
	But what is "blocking", really, when she's occupying herself with cycling and you can just go around. A nudge of will pulls your chi inward and masks your aura pressure. You dip into the bushes to your left and sneak passed the woman quiet as can be. Trees are scarce and growing scarcer so close to the peak so you trudge a half mile further up to be safe, using the storm's dark clouds to hide you, and sit to cycle.

	Absorbing the storm's Heavenly Gate shocks your Cores with every spiritual inhale but you hold it steady and process as much as you can as quickly as you can.

	*rand val (7 * stealth) (9 * stealth)
	[b][Aura Pressure +${val}][/b]
	*set aurapressure + val
	*if (element1 = "Storm")
		*line_break
		*set val (4+(round(val * 0.2)))
		[b][Storm Element Bonus: +${val} Aura Pressure]
		*set aurapressure + val
	*set val 0
	
	After twenty minutes of deep meditation you sense an attack and leap to the side. Pale blue icicles pierce into the earth where you were sitting a moment before. Your eyes follow the trajectory course and see your attacker.
	
	Tian Fang's horizontally raised leg glows with a pale blue light. She's
*else
	[b][Stealth 2 Check Failed][/b]
	*line_break
	You step on a twig at your approach. She spins in place and sends a pale blue light of chi over her leg, raising it and 
pointing her bare foot at you as if it were a loaded crossbow. "Hhh...Thunderfaller...The former Laborer, correct?" Her face is flush and sweating with fever. "Why do you remain days after the rest of your Sect departed for the Trials, do you believe yourself strong enough to brave the roads alone?"

You've been training on this mountain for half the week and had absolutely no idea that everyone left already. "...Yes."

Nailed it.

She pants with strained breaths. "Apologies...you cannot be here right now. This Heavenly Gate is my payment for training the lower disciples, you need to leave. Most quickly." She leans over and grabs her chest with one hand. "As in immediately, please and kindly."

"I never agreed to anything like that." You say flatly. There's no way you're surrendering such a power-up before the Heavenly Ascension Trials. "I never received your training either, so I have as much a right to be here as anyone."

Her left foot inches back in preparation, arms raising. It's only now that her puppy-like facade drops and you recognize the wolf underneath. "Thunderfaller, I-hngg! A...Ack! A-AGH!" She grabs her head in both hands recoils. "Y-You need to leave! You need to leave NOW!" Immediately you see something is off with the Mountain Hazard disciple as her voice booms louder with each word. Her hair raises on edge. Her fingertips extend, thicken, sharpen. Her whole body trembles and tenses, flexing uncontrollably, and with each writhing twist of her torso she seems to grow another inch.

The convulsions end as quickly as they started and she looks up at you with amber eyes instead of her natural brown. You can't help but notice the pronounced canine teeth she bares in her growl.

"Fang?" You ask just before she launches an icy blast at your feet. You jump back and she drops to all fours, snarling like a Beast, with her tail horizontal and stiffly tight like a wolf about to strike.

"IT'S MINE!" She screams as if in pain, wrenching her head around with each word. "THIS STORM IS MINE!"

Instantaneously she lunges twenty feet at you while you leap back twenty feet of your own, keeping the same safe distance. The two of you circle each other in the middle of the pouring rain. By the luminous constant lightning you can see it in her eyes when the rage finalizes its control over her mind.

She's gone feral.
*choice
	*selectable_if ((((element1 = "Light") or (element1 = "Wind")) or (element1 = "Storm")) or (Agility >= 4)) #Attack her before she can react.
		*set fighting true
		*set fangambushed true
		*set fanghealth - 1
		*set ruthless + 2
		*if (Agility >= 4)
			[b][Agility 4 Check Passed][/b]
			*line_break
			This Yokai chose the wrong disciple to threaten. You're one of the fastest students in Thunderfall and if she believed you wouldn't use that to your advantage then she's a fool.
			
			The distance between the two of you disappears immediately as you rush in and deliver a gut-punch followed by a spinning kick to the chin when she hunches over. You send her airborne but she recovers and lands on her feet, spitting blood at the ground once.
			
			She growls and her shoulders shake, seeming more bestial by the minute.
			
			You hold one hand up and motion for her to come.
		*elseif (element1 = "Light")
			*set chispent + 1
			She must have not seen you coming earlier because otherwise she'd know you still have your Light speed enhancement active. You charge in to close the distance fast and hit her with a palm strike to the mid-section that forces her to throw up, launching her towards a nearby boulder.
			
			A follow-up attack is cut off though when she twists in mid-air and lands on her feet.
		*elseif (element1 = "Wind")
			*set chispent + 1
			"If it's [i]your[/i] Heavenly Gate then why can [i]I[/i] do this?" You taunt and spend a fraction of chi from your Cores to seize control over the wind around her. A spinning globe of green power forms above the girl before she catches on, then unwinds into a singular gust that pummels her into the ground like a massive fist.
			
			Generating so much potent wind is for advanced fighters, but you're in a Heavenly Gate of storm chi. The wind is already there.
			
			She gets off the ground, forehead bleeding, icy glowing mist radiating off her body. With one sleeve she dabs the blood on her brow and looks at it in shock, then back to you. Her fangs seem to grow and she lets out a howl.
		*elseif (element1 = "Storm")
			*set chispent + 1
			A quick glance at her pale blue energy almost makes you laugh. "Is that Ice chi? Did you bring Ice to a Storm fight?"
			
			With a focus of will and push of chi you call the storm's electrical power into focus around Mountain Hazard's star pupil and shock the shit out of her, generating a field of violet lightning all over her body. She screams, violently convulsing, and her tail stiffens until the power around her is spent.
			
			You're about to charge in and finish this fight when she surges a Fortitude Core to recover and swipes a claw at you, but you pull back in time.
			
			This is going to be fun.
		*else
			*bug
		
		Both your auras surge to full power and the battle begins.
	#"Then I challenge you to a duel for it."
		"We both claim the same thing," you say while circling, "so let's settle this like Martial Artists. Tian Fang, I challenge you to a duel for this Heavenly Gate."
	
		*set honor + 4
		She examines you for a moment from on all fours, nails digging into the rocky ground with every step. She flips her hair back and looks you in the eyes more clearly. Then she smiles, wide and predatory.
		
		Challenge accepted.
		
		*if (element1 = "Ice")
			Both your auras of icy mist ignite simultaneously.
		*else
			$!{auracolor} chi ignites around your body when your aura activates. Her body glows with an icy blue mist in response.
		
		She lunges at you and the battle begins.
	#Raise my hands. "Fang, it's okay. I'm here to help you."
		*set ruthless - 3
		*if (((((persuasion >= 1) and (race = "Yokai")) or ((persuasion >= 1) and (background = "Trapper"))) or (persuasion >= 2)) or (subrace = "Wolf"))
			*if (persuasion >= 2)
				[b][Persuasion 2 Check Passed][/b]
			*elseif ((background = "Trapper") and (persuasion >= 1))
				[b][Special Event: Trapper Background, Difficulty Reduced.][/b]
				*line_break
				[b][Persuasion 1 Check Passed][/b]
			*elseif ((persuasion >= 1) and (race = "Yokai"))
				[b][Racial Check Passed, Difficulty Reduced.][/b]
				*line_break
				[b][Persuasion 1 Check Passed][/b]
			*elseif (subrace = "Wolf")
				[b][Racial Check Passed: Wolf Yokai][/b]
			*else
				*bug
			*line_break
			*set apval 5
			*gosub_scene quicks apboost
			
			Her right ear twitches and she looks from side to side, expecting a trap, then growls gutturally as her body gets low to the ground.
			
			That's better than attacking, so you continue. "My Sect might have given up on this Heavenly Gate, but the Beasts and spirits haven't. You sit there and cycle, and I'll sit here and cycle. If anything comes to attack us it'll sense us both. Together. Nothing around here would even dare to attack our combined might. The Heavenly Gate only lasts so long, if we [i]both[/i] claim this territory we can cycle for the entire storm instead of wasting time fighting every interruption."
			
			Tian Fang shifts her weight to her arms while on all fours, twitching forward and visibly stopping herself from attacking on sheer willpower every passing second. Her every movement a battle of control that's only exacerbated by the thundercracks all around you.
			
			Slowly, ever so slowly, she shifts weight to her hind legs and rolls to a seating position, folding her barefoot feet to a more-human meditative stance. The aura around her lessens and you sense natural aura spiraling around her. She's cycling.
			
			You take a seat opposite of her and do the same.
			*page_break
			*if not (jadedragonfoundation)
				*achieve dogwhisperer
			*set metfang 13000000000
			*set fangrep + 12
			*set fangcombat + 1
			The two of you adopt meditative positions twenty feet apart, backs facing away from each other, her fluffy white wolf's tail knocking wind against you with each wag mid-meditation. Together, you cycle.
			
			Power flows through the air faster than anyone ever warned you. Storm Gates are nothing like the first one you cycled; it takes constant effort to hold enough chaotic energy in place to compress it into your spiritual cores. The entire process is made that much harder by the distracting thundercracks all around your mountaintop and the constant rain slapping you in the face.
			
			Luckily you have all night and nothing interrupts you.
			
			The storm rages for hours upon hours. You can't even tell when daybreak arrives due to the potent aura enriching the storm's dark clouds. But you hold strong and after fourteen hours of exhausting chi compression and painfully stressing your aura and Cores, it's done. You rise to your feet to bask in the glorious sun breaking through the clouds.
			
			The power is yours.
			
			[b][Aura Pressure +50][/b]
			*set aurapressure + 50
			*if (element1 = "Storm")
				*line_break
				[b][Storm Element Bonus: Aura Pressure +10][/b]
				*set aurapressure + 10
				
			*if (hungryspiritritual != 1)
				[b][Hungry Spirit Ritual][/b]
				*line_break
				Using your knowledge of handseals you're able to form a quick sigil-circle on the stone ground around you that aids in storing some of the storm's chi around your aura. It will enter your Cores as soon as you've processed the surging power that's already filled them.

				*if (handseals >= 2)
					*set val (5+(3*handseals))
				*else
					*set val 5
				[b][Aura Pressure +${val}][/b]
				*set aurapressure + val
			*else
				[b][Handseal Check Failed][/b]
				*line_break
				It occurs to you that there might be some kind of Seal to aid in aura absorption but you've never heard of it.
			*if (((element1 = "None") and (element2 != "Storm")) or ((element1 != "Storm") and (element2 = "")))
				
				*gosub stormelement
			
			After the storm subsides Tian Fang rises from behind you and wipes the mud off her soaked knees. You can see the animalistic traits clearly receding from her body, returning her to her normal self. "That was...Unusual." She says in her normal voice, then bows at the waist and lets her wet hair flop over her face. "Thank you very much for calming me down, clearly you have the wisdom of wrinkly old men."
			
			*choice
				#"Don't mention it."
					*set fangrep + 2
					"Don't mention it." You say.
					
					"I did not plan to!" Fang says with one finger elevated for excited emphasis. "I do apologize for my behavior, it's why I had requested a Heavenly Gate alone as payment, and I ask that you keep this a secret. You see, I have an...allergy."
					
					"An allergy?"
					
					"To Heavenly Gates. They cause me to enter bestial regression, a rare Yokai disease. It's lead to many, many complications."
				#"Yeah that, what was that about?"
					"Yeah that," You say, waving a weakened hand theatrically despite the muscle strain all over your body, "what was that about? You looked ready to kill me. Not that you could."
					
					She kicks one leg back playfully. "Hah! Ever the confident one! But truly I do apologize for that behavior, I have an unfortunate allergy to Heavenly Gates. It is why I requested one alone as my payment from your Sect. I most humbly ask that you please keep this a secret."
					
					"You have an allergy...to power?"
					
					"Not truly, but to a surplus of natural power yes. It causes bestial regression, a rare Yokai disease."
					
			"Does it hurt? Is it useful in a fight?"
				
			"Very much yes, and very much no! My training abandons me on such occasions. It is [i]quite[/i] vexing actually." She stretches and lets out a peep mid-stretch. "Oh that smarts most painfully. I fear my body is filled to bursting with power and my muscles are not happy over it, yet still I must be departing most hastily if I am to reach the Trials."
				
			"Likewise." You say, remembering that you're two days behind the rest of the Thunderfall Sect.
				
			Tian Fang leans over to wring her hair out. Though she's soaked to the bone from the storm she looks cheery once again. "Then we leave as friends to meet again as rivals in Nanhou. I thank you again so much, Thunderfaller, you have surprised me in that you have an exceptional eye for tactics and diplomacy."
				
			*if (heshe = "he")
				*if (ruthless >= 55)
					Good to see someone understands the value of your brilliant mind.
				
					"I know," You say while wringing out the rain from your shirt, "and my name isn't Thunderfaller."
				*else
					Wow, an almost-compliment.
					
					"Thanks," You say while wringing out the rain from your shirt, "but I have a name you know."
				
				Tian Fang meets your gaze playfully, staring just a moment too long, and smiles. "I know."
				*set fangromance + 1
				
				Ice manifests under her bare feet and she starts to slide downhill backwards,
			*else
				"Thanks," you say on autopilot after fourteen hours of mental and spiritual exertion, "you're not so bad yourself."
				
				"Let us hope not, the Trials will be unkind to those who are so bad themselves." Ice manifests under Tian Fang's bare feet and she starts to slide downhill,
			accelerating from a soft glide into a full skate as she gets further down the steep mountainside opposite of the village. To the west. To Nanhou. "See you at the Trials, $!{name}! Don't be late!"
			*if (roc > 0)
				*page_break
				${rocname} lands beside you as you watch the wolfgirl skate down the mountainside. You turn to your bird, who is noticeably bigger than this morning. After so long raising her as a baby giant eagle you'd almost forgotten she has Thunderbird in her direct lineage.
				
				"Storm chi suits you well." You say, sensing the flow of potent Storm energy surging through your pet bird that must have triggered its first Advancement to make her grow so much.
				
				"Cawwww!" ${rocname} replies in agreement, then takes off to find a deer to eat. She makes for poor company, but her constant hunting saves you a few Shards.
				*set roccombat + 1
			*goto departure
		*else
			[b][Persuasion Check Failed][/b]
			
			Tian Fang lunges at you with a claw extended, swiping four gashes into the legs of your pants.
			
			[i]So much for diplomacy.[/i] You think while rolling out of the way of a second swipe from her foot.
			
			*if (element1 = "Ice")
				Both your auras of icy mist ignite simultaneously.
			*else
				$!{auracolor} chi ignites around your body when your aura activates. Her body glows with an icy blue mist in response.
				
			The battle begins.
	#"Fool, the only surge you'll be getting is my fist surging into your face!"
		*set maorep + 5
		*set ruthless + 3
		Your body blazes with ${auracolor} power as you charge at the girl, her shocked expression betraying that she really thought you'd leave. Maybe
		*if (jadedragonfoundation = false)
			her Aura Pressure is higher than yours, or maybe
		she's got some specialty she's known for, or maybe she's studied you in practice from a distance.
		
		Whatever it was, whatever reason she had for being confident, it flies out the window when she gets punched in the mouth. You landed a glancing blow, only managing to bloody her lip, but it shakes her bravado.
		
		She jumps twenty feet back and spits a single mouthful of blood to the side.
		
		Both your auras surge to full power as the battle begins.
	#I take the loss and leave.
		*comment like a bitch
		*set metfang 14000000000
		*set ruthless - 5
		*set honor - 1
		"Look, if it's that big of a deal then you can keep it." You say with disappointment.
		
		*set fangrep + 3
		She responds only with a howl and turns back to the dark storm clouds touching the peak like a fog. She puts one foot in front of the other and disappears behind the swirling clouds.
		
		Damn it. So close, but you shake your head reluctantly. You can't fight an ally village's star pupil,
		*if (honor >= 52)
			it would be dishonorable if she really was promised this Heavenly Gate as a payment.
		*elseif (ruthless <= 48)
			you might hurt her.
		*else
			it's too big a risk of injuy, especially with the Trials coming.
			
		You turn around and sprint off to another peak hoping to get a shred of chi before the Heavenly Gate ends. The next peak is normally five hours away but you make it in three, exhausted beyond physical limits.
		
		*set apval 4
		*gosub_scene quicks apboost
		*if (weight >= chapter)
			*line_break
			[b][Weighted Clothing Bonus: Aura Pressure +3][/b]
			*set aurapressure + 3
		
		After too long spent gasping for air and soaked to the bone you drop into a meditative stance to cycle the natural chi flowing all around you before it runs out.
		
		*if (roc > 0)
			${rocname} lands behind you and shakes happily, soaking in the Storm chi.
			
			"Yeah must be nice to have been able to fly this whole time." You say to her.
			
			"Caw!" She replies.
			
			"Probably been absorbing it in the sky the while I ran on the ground like a fool."
			
			"Caww!"
			
			"Nah two against one would've been rude."
			
			"Caw."
			
			You two keep chatting for a bit through the night as you cycle what you can until the morning light breaks through the thinning storm clouds.
			*set roccombat + 1
		*else
			It's more difficult to cycle storm chi than you expected, but you pull in what you can little by little. Each breath feels like a spark and your nerves shout warnings constantly despite the safety granted from your Cores.
			
			Hours of intense focus and meditation pass until the morning light breaks through the thinning storm clouds.
		
		[b][Aura Pressure +25][/b]
		*set aurapressure + 25
		
		You fall asleep on the mountain peak and rise hours later to head home, ragged but better off than you were yesterday.
		*goto departure
*goto Next_dogfight

*label Next_dogfight
*page_break Prepare yourself!
*set fighting true
*if (sonarmode)
	[b][Thunderfaller vs Tian Fang][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png

Big Chu's lessons embed into your reflexes and you take on a proper battle stance, ready to seize this irreplaceable source of chi for yourself. It's the last opportunity you have before the Heavenly Ascension Trials and you're not going to give it up.

But neither is Tian Fang.

Her hands glow brighter and brighter until pale icicles form over her fingers to make a pair of clawed gauntlets.

*if (fangambushyou) or (agility < 4)
	[b][Agility 4/Ambush Check Failed][/b]
	*set agiexp + 1
	*line_break
	She lunges at you and rakes her energy-fueled claws against your torso.
	
	*set combatstat "fortitude"
	*set combatdiff 4
	*gosub_scene quicks combatcheck
	*if (passcheck)
		She finds no success. Your skin hardens to the strength of steel. The spiritual force of her attack pushes through your defenses and cuts deep into your spirit, but her claws shatter after.
		
		You use that hardness as an asset and slam your forearm against the side of her face, feeling a crunch as her skin struggles to exist between your rock-hard arm and her skull. She jumps back, bleeding from her cheek and fuming with bloodlust.
		*set fanghealth - 1
	*else
		You try to defend yourself but her claws dig into the flesh of your arms with sharp physical force and freezing spiritual power that weakens your skin's natural defenses. She cuts through the upper skin and muscle of your forearms.
		
		[b][1 Wounds Suffered][/b]
		*set wounds + 1
		*if (((health + (fortitude / 2)) - wounds) < 1)
			*goto dogfightlost
*else
	[b][Agility 4 Check Passed][/b]
	*set agiexp + 1
	*line_break
	But you're too fast.
	
	You're able to strike first, smacking her face from side to side with a barrage of quick strikes that force her potent claws into a defensive position, which allows you to trip her to the ground. Her own Agility Core surges and she dashes twenty feet away from you in the blink of an eye.
	
	Or in her case, the blink of a black eye.
	*set fanghealth - 1
*page_break
*if (sonarmode)
	[b][Thunderfaller vs Tian Fang][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png

The two of you clash again, unrelenting.

Your aura against hers, her leg to your forearm, your fist to her shinguard.

Neither of you gets an advantage but both of you get a breather, testing the other's capabilities. Finally your chi and stamina recover, it's time to act.
*gosub_scene quicks statcheck
*goto fangfightoptions

*label fangfightoptions
*choice
	*disable_reuse #Shoot her with scalding blasts of chi.
		*if (sonarmode)
			[b][Thunderfaller vs Tian Fang][/b]
		*else
			*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png
		
		Normally you only have enough Aura Pressure to generate a few chi blasts a day, powerful enough to deflect some rocks or destroy a
		*if (soul >= 3)
			table,
		*else
			vase,
		but you're inside a Heavenly Gate. The free energy surrounding you fuels all of your attacks.
		
		Power surges from your Cores, through your shoulders, and down into your outstretched arms erupting outwards in explosive ${auracolor} chi orbs you fire at Tian Fang. Your power rains down across the rocky battlefield.
		*if (soul >= 3) or (handseals >= 3)
			
			[b][Handseals/Soul 3 Check Passed][/b]
			*set solexp + 1
			*line_break
			*if (soul >= 4) or (handseals >= 4)
				Your mastery over chi even gives you the secrets needed to pull off your assault without surging a Soul Core.
			*else
				The constant assault is taxing but manageable, it just takes a bigger push from your Soul Core.
				*set solspent + 1
		*else
			Energy attacks aren't your strong suit however, and it costs a heavy investment of chi and the surging of a Soul Core to keep the attack going.
			*set solspent + 1
			*set chispent + 1
			
			[b][1 Chi Point spent][/b]
			
		*if (power >= 3) or (soul >= 4)
			*set fanghealth - 1
		*set fanghealth - 1
		
		There's no room for mercy so you don't let up, continuously firing so many chi blasts that the ground around the battlefield turns to dust, blocking your vision of the girl.
		
		A mistake.
		
		Out of the dust cloud to your left flies a speeding ice-spike the size of both your arms put together. You form a blast of chi in both hands and try your best to blow the ice shard out of the sky before it rips through you.
		
		*if ((((element1 = "Fire") or (element2 = "Fire")) or (element1 = "Storm")) or (power >= 3))
			*if ((((element1 != "Fire") and (element1 != "Storm")) and (element1 != "Ice")) and (element1 != "Earth"))
				*if (power < 4)
					*set powspent + 1
					[b][1 Power Chi Spent][/b]
					*line_break
			[b][Element/Power 4 Check Passed][/b]
			
			And you succeed, melting the spike with your own potent
			*if ((element1 = "Fire") or (element2 = "Fire"))
				scorching hot Fire
			*elseif (element1 = "Storm")
				crackling Storm
			chi.
		*elseif (element1 = "Ice")
			[b][Element: Ice Check Passed][/b]
			
			And you succeed, dispersing the physical ice into chi. It crashes into your soul attuned to the same element and harmlessly dissipates.
		*elseif (element1 = "Earth")
			[b][Element: Earth Check Passed][/b]
			
			And you succeed, hardening your skin like a boulder by channeling the massive mountain beneath your feet.
		*else
			[b][Element/Power 4 Check Failed][/b]
			But you fail. It takes a half second too long to spin your Cores into action and generate the spiritual energy needed to blast the icicle away, and a half second is long enough for it to lodge into your side.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
	*disable_reuse #Rush in to deliver a dozen-strike combo.
		*if (sonarmode)
			[b][Thunderfaller vs Tian Fang][/b]
		*else
			*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png
		
		The savage Mountain Hazard fighter tries to create distance but you dash in close to stop her.
		
		*set combatstat "agility"
		*set combatdiff 4
		*gosub_scene quicks combatcheck
		*if (passcheck)
			With a quick swipe you flip her leg into the air as you catch up, knocking her off balance and letting you land four jabs at her center before the force of the blows knocks her back. She spins in mid-air and throws a kick where your head should be, but you duck on your pursuit and strike her hamstring, her kidney, and her neck.
			
			Each strike is weak, but combined they're effective enough to send her tumbling back.
			*if (power >= 4)
				*set fanghealth - 1
			*set fanghealth - 1
		*else
			Just as she hoped you would. Right when you close the gap she drops to the ground and spins, swiping your legs out from under you. She leaps on top of you as you trip, raining blows down on your head.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
			
			Her tenacity distracts her enough that she doesn't notice all the power rushing to your legs. It takes agonizingly long to you, as you're taking slashes to the face while refusing to give up your concentration, but finally you build enough power store to kick off the ground with such tremendous force that Tian Fang launches across the battlefield. You're on your feet by the time she returns.
		*page_break
		Both of you catch your breath from the assault and circle each other, preparing your next move.
		
		That's when she throws her hands up and glows brighter, seizing control of a pool of natural energy in the air. A globe of power eight feet wide begins to form, icy blue mist coalescing into something worse.

		Crap. She's using a Technique.
		
		*if (element1 = "Storm")
			[b][Element Check Passed: Storm Element][/b]
		
			Not on your watch. The energy doesn't need to be converted to answer your call, it's already Storm Chi.
			
			You extend your spiritual powers and seize control of the pool of chi she'd been collecting over her head, then crash it down onto her in a bright blinding flash of violet power.
			*goto dogfightwon
		*elseif (soul >= 3) or (element1 = "Ice")
			*if (soul = 3)
				[b][1 Soul Chi Spent][/b]
				*set solspent + 1
				*line_break
			*if (soul >= 3)
				[b][Soul 4 Check Passed][/b]
			*else
				[b][Ice Check Passed][/b]
			*set solexp + 1
		
			An urgent call to the natural energies around you and a flex of your willpower forces the pool of chi to answer your command.
			
			Rather than convert to ice like her Technique would have done, the chi remains as Storm chi and crashes down onto her, shocking her body stiff long enough to let you kick her in the jaw.
			*if (power >= 4)
				*set fanghealth - 1
			*set fanghealth - 1
		*elseif ((element1 = "Fire") or (element2 = "Fire"))
			[b][Element Check Passed: Fire Element][/b]
			
			There's plenty of writings on the metaphysical duality between fire and ice. If you had read any of it, you'd know what to do.
			
			But you haven't.
			
			So instead you launch a fireball at her face while her hands are up. She looks down just in time to close her eyes and take your explosive attack to the face, knocking her hair every which way and dispersing her attack.
			*set fanghealth - 1
		*else
			[b][Element/Soul 4 Check Failed][/b]
		
			You try to wrest control of the aura but your mastery of chi isn't good enough. The air around you turns to tiny icy needles and shoots into your body from a hundred angles, stabbing into you and freezing up your blood.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
	*disable_reuse #Leap into the air to deliver an axe kick.
		*if (sonarmode)
			[b][Thunderfaller vs Tian Fang][/b]
		*else
			*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png
		
		One mighty leap takes you high into the air above your opponent.
		
		You raise your leg towards the sky and gather the storm's energy into your muscles before dropping to the ground in a massive axe kick.
		
		*set combatstat "power"
		*set combatdiff 4
		*gosub_scene quicks combatcheck
		*if (passcheck)
			Dust and rocks explode out of the impact zone when you crash into Tian Fang, her guard holds strong from surging a Fortitude Core but you can tell she's taken damage. Her aura pressure is already weaker as fragments of her pale blue power scatter outward with the debris.
			
			*if (power >= 4)
				*set fanghealth - 2
				You didn't even have to surge a Power Core to do it.
			*else
				It was well worth surging a Power Core to see the look on her face when you land hard enough to score an advantage.
				*set fanghealth - 1
			
			Unfortunately she's no amateur, and recovers in time to grab
		*else
			But it's not strong enough to break through her guard. While you were busy leaping into the air and crashing down upon her, the Yokai girl was surging her Fortitude Core and pushing all her hardening energy into her arms.
			
			She screams in rage as you crash into her arms, cracking the bones of your foot with an audible crunch as if falling on a steel wall from such a high drop.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
			
			Before you can create distance she's already grabbed
		your ankle.
		*page_break
		Tian Fang pulls you to the ground by the ankle where both of her legs wrap around your knee for a leglock.
		*if (honor >= 48) and (heshe = "he")
			
			"Whoa, whoa!" You shout in surprise, "At least buy me dinner first!"
			*set fangrep + 1
			
			She snarls and twists harder.
			
		*set combatstat "fortitude"
		*set combatdiff 4
		*gosub_scene quicks combatcheck
		*if (passcheck)
			You don't have time to stop the leglock but you don't have to, knowing your body can harden like the best of the disciples
			*if (fortitude >= 4)
				without even surging a Fortitude Core.
			*elseif (fortitude >= 3)
				by surging a Fortitude Core.
			*else
				*bug
			
			When she completes her hold on your leg and twists like an animal possessed you respond by hardening your entire body like steel. Then you [i]stand up[/i], completely ignoring the strain she presses on the sides of your knees with her leg muscles.
			
			The joint holds strong and so do you as you lift her off the ground and slam her back down, her ribs caught between the stone mountaintop and your steel skin.
			*set fanghealth - 1
		*else
			Her hold on your leg lasts only as long as your joint does, her body twisting and writhing like an animal possessed as she tries to jerk your knee into an injury. A quick bite to her fingers gets her to end her grapple but by the time she's jumped away you're having difficulty standing.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
	*if (element1 != "None")
		*disable_reuse *selectable_if (((chipool + (soul/2)) - chispent) >= 1) #Unleash ${an} beam ${element1} energy. [Costs 1 Chi]
			*label neveratime
			*set chispent + 1
			*if (sonarmode)
				[b][Thunderfaller vs Tian Fang][/b]
			*else
				*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png
			
			There's never a time to pull your punches in real fights, so you draw on your internal reserves of
			*if (usefire)
				spiritual fire, igniting a burning red flame around your fist.
			*else
				${element1}-aligned chi and wrap it around your fist.
			Tian Fang leaps back to dodge but it's too late, you weren't really using a punch.
			
			With a wide, stabilizing stance you thrust your fist forward and shoot a beam of
			*if (usefire)
				flames into her center that scorch against her Ice aura, burning at her spirit's energies and blasting
				*goto knockback
			*elseif (element1 != "")
				${element1}
			*elseif (element1 = "None")
				${element2}
			energy at her face. It connects and
			*if ((element1 = "Light") or (element1 = "Darkness"))
				blinds her long enough for you to close the gap with a
				*if (soul >= 4) or (power >= 4)
					real fist full of chi, the attack she originally expected, and slam it into her gut sending
					*set fanghealth - 2
				*else
					leaping kick to her torso that sends
					*set fanghealth - 1
				her flying backwards. Your spiritual senses tell you her Fortitude Core took damage from the assault.
			*else
				knocks
				*label knockback
				her twenty yards back in an explosion of ${auracolor} energy.
				*if (((soul >= 4) or (power >= 4)) or (usefire))
					*set fanghealth - 2
				*else
					*set fanghealth - 1
				*set usefire false
			*goto fangcont
	*if (element2 = "Fire")
		*disable_reuse *selectable_if (((chipool + (soul/2)) - chispent) >= 1) #Unleash a beam of Fire chi. [Costs 1 Chi]
			*set usefire true
			*goto neveratime
*label fangcont
*if (((health + (fortitude / 2)) - wounds) < 1)
	*goto dogfightlost
*set fangfightcounter + 1
*if (fangfightcounter < 2)
	*goto fangfightoptions
	
*page_break
*if (sonarmode)
	[b][Thunderfaller vs Tian Fang][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png
*gosub_scene quicks statcheck

The two of you clash continuously in a flurry of blows with no clear winner. Her cuts and scrapes don't seem to slow her down at all. You separate to catch your breath, but the fight's been dragging on too long. Even Tian Fang's bestial attitude has begun to slip. She's standing on two legs now, still visibly feral but more alert. Analyzing. Aware.

Tian Fang
*if (fanghealth <= 2)
	wipes blood from her mouth and
looks around the storm's dark clouds surrounding the two of you. Her chest heaves with one heavy breath, then another. "Why won't you FALL?!" She screams, eyes nearly glowing red with whatever has overtaken her senses, but she doesn't drop to all fours this time. At first you're glad that she seems to be slowly snapping out of it, from feral to just pissed, but then her hand twitches and you feel the workings of a Technique in the air. She opens her mouth and you see one last chance for diplomacy.

"RRRAAAAAUUUGGHHHH!!"

Nevermind.

Before your very eyes the swirling pale blue aura around her coalesces in her hand and extends into a massive seven-foot claymore of pure ice. With a two-handed grip on the frozen claymore she pushes more chi into its construction and wreathes it in enough ice power to resemble blue flames.

[i]Well shit,[/i] You think to yourself. [i]I wish I knew a Technique.[/i]

She charges you and swings with the full power of her Iceblade, enforced with the crackling energy of the storm's Heavenly Gate.
*set val 5
*choice
	#Leap overhead to dodge.
		*set combatstat "power"
		*set combatskill "athletics"
		*if (((element1 = "Ice") or (element1 = "Wind")) or (element1 = "Storm"))
			[b][${element1} Element Check Passed, Difficulty Reduced][/b]
			*line_break
			*set val - 1
		*elseif (style = "Midorikatai")
			[b][Midorikatai Style Check Passed, Difficulty Reduced][/b]
			*line_break
			*set val - 1
		*set combatdiff val
		*gosub_scene quicks combatcheck
		*if (passcheck)
			With one mighty leap you launch yourself out of the way of her attack by leaping straight up, ascending forty feet into the air thanks to the ambient power of the Heavenly Gate leaking into your every movement. Tian Fang disappears beneath you due to the thick dark storm clouds around the two of you and you know that she can't see you either, nor can she sense you thanks to the storm chi radiating through the air.

			Radiating...[i]too much[/i] through the air.
			
			A jerk, twist, and expulsion of chi takes you out of the path of a violet lightning bolt midair just before it crashes into the ground below. A scream from Tian Fang lets you know that the bolt chose her as the next best conductor when you moved out of the way, though the force of it still blasts you thirty feet away where you barely land on your feet on the ground below.
			*set fanghealth - 1
		*else
			With one mighty leap you get halfway off the ground until her attack slams into your midsection. By sheer luck she hits you just below your center of gravity so your body spins when her blade's ice aura erupts in a massive explosion of freezing chi. Rather than being bisected, you're sent flying thirty feet away. The only saving grace is that Tian Fang was standing in her own explosion.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
			*set fanghealth - 1
	#Drop to the ground in a feint.
		*set combatstat "agility"
		*set combatskill "thievery"
		*if (((element1 = "Earth") or (element1 = "Light")) or (element1 = "Darkness"))
			[b][${element1} Element Check Passed, Difficulty Reduced][/b]
			*line_break
			*set val - 1
		*elseif (style = "Kurokonton")
			[b][Kurokonton Style Check Passed, Difficulty Reduced][/b]
			*line_break
			*set val - 1
		*set combatdiff val
		*gosub_scene quicks combatcheck
		As Tian Fang's blade comes close to your face you drop to the ground and feint a kick at her leg with enough force to spin your body, causing the woman to swing downward and trace your attack to land a devastating slash to your thigh.
		
		*if (passcheck)
			With a quick jerk you pull your leg back in and let the momentum of your kick pull you around in a 360 degree spin just as her massive glowing sword slams into the ground where your leg would have been if you kept it fully extended and attempted the trip attack that you projected. Her blade crashes into the stone ground instead and explodes in a violent eruption launches you both a dozen feet back until you come skidding to a halt.
			*set fanghealth - 1
		*else
			Her attack accelerates mid-swing, crashing into your leg before you have time to pull it in for your feint. All your internal chi rushes to your leg to prevent it from being cut off when her iceblade cleaves into you in an explosion of ice shards that launches you thirty feet back, bouncing against the hard stone of the mountain peak while your body writhes in pain. The only saving grace is that Tian Fang was standing in her own explosion.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
			*set fanghealth - 1
	#Catch it.
		Tian Fang's seven-foot glowing claymore of frostfire chi comes down on you with the fury of an enraged Beast and you try to catch it in your hands.
		*if ((style = "Akakiru") and (((element1 = "Ice") or (element1 = "Fire")) or (element2 = "Fire")))
			*comment chiev Swordsinger
			
			[b][Special Event: Akakiru Style + 
			*if (element1 = "None")
				[b]${element2}[/b]
			*else
				[b]${element1}[/b]
			[b]Element][/b]
			
			*gosub swordsong
			*if ((element1 = "Fire") or (element2 = "Fire"))
				burning the ice power off her forged Technique in an instant by releasing chi-fueled roaring flames between your palms.
			*else
				mustering your control over Ice to absorb the surging elemental power running through her blade.
			
			Tian Fang grits her teeth and tenses her shoulders to wrest control of her massive sword from your grip. She screams and snarls, head whipping in every direction to pull her weapon back for another attack. All the while your muscles scream to let go but your mind screams that to let go would be to court death.
			
			With one final push of your own power, you
			*if (element1 = "Ice")
				jettison all the stolen ice chi back through the blade
			*elseif ((element1 = "Fire") or (element2 = "Fire"))
				push even more flame energy through the blade
			*else
				*bug
			with so much force that her sword of ice explodes outward through the handle, engulfing Tian Fang in the
			*if ((element1 = "Fire") or (element2 = "Fire"))
				fiery
			eruption and launching her thirty feet back with several bounces against the hard stone.
			*goto dogfightwon
		*else
			It's immediately obvious that was the wrong move.
		
		*if (element1 = "Ice")
			[b][Ice Element Check Passed: Reduced Damage][/b]
			
			The forces of Ice call out to your inner chi and you pull them in, hoping to seize her blade by sensing its elemental aura. The desperate desire to survive aids your calling and the ice chi of her blade pulls into you, snuffing out the blue flames of her blade.
			
			[b][Restored 1 Chi Point][/b]
			*set chispent - 1
			*if (chispent < 0)
				*set chispent 0
			
			*gosub unfortunatesword
		*elseif ((element1 = "Fire") or (element2 = "Fire"))
			[b][Fire Element Check Passed: Reduced Damage][/b]
			
			The forces of Fire burn through your body as you rev up your response, a full-power burst of flames enhanced by the Heavenly Gate into a fireball twice the size of your body. The eruption explodes over Tian Fang's blade and burns through its energies, enveloping and erasing the blue iceflames of her Technique.
			
			*gosub unfortunatesword
		*elseif (style = "Akakiru")
			*gosub swordsong
			though the energy around her blade loses no momentum and leaves her ice claymore in a whirl of power, crashing into your chest with enough force to cause an explosion of frozen power that sends you thirty feet back, skidding across the hard stones of the mountain peak. The only saving grace is that Tian Fang was standing in her own explosion.
			
			[b][1 Wounds Suffered][/b]
			*set wounds + 1
			*set fanghealth - 1
		*else
			Tian Fang's blade slips through your hands and cuts deep into your torso then explodes in a massive eruption of freezing energy. You're sent flying thirty feet away with a trail of blood left behind. The only saving grace is that Tian Fang was standing in her own explosion.
		
			[b][2 Wounds Suffered][/b]
			*set wounds + 2
			*set fanghealth - 1
*if (((health + (fortitude / 2)) - wounds) < 1)
	*goto dogfightlost

*if (wounds >= 2)
	Despite the pain relief
*else
	Relief
flows through you when you recover from being launched so far away and see Tian Fang's heaving breaths across the battlefield. Her knees tremble and exhaustion is clearly painted on her face. That attack took much out of her and her aura is weakening. This battle can be over in one final attack but only if you have what it takes to execute it.

Tian Fang rears her blade back over her shoulder and lets out a roar.

Without hesitation you respond with a roar of your own and the two of you meet in one final clash.
*choice
	#Take the hit and headbutt Tian Fang with my chi-reinforced skull.
		*set combatstat "power"
		*set combatstat2 "fortitude"
		*set combatdiff 8
		*if (yokaitrait1 = "horns")
			*if (heshe = "he")
				[b][Bull[/b]
			*else
				[b][Cow[/b]
			[b]Yokai Event: Reduced Difficulty][/b]
			*set combatdiff - 1
		*gosub_scene quicks combatcheck
		*if (passcheck)
			If she wants to end this then you're more than happy
			*if ((power + fortitude) >= 8)
				to, and you won't even need to surge a Combat Core. Your Power and Fortitude Cores are advanced enough to win this without strain.
			*else
				to. You burn through your chi reserves and rush in to meet her head-on.
		*else
			*if ((((health + (fortitude/2)) - wounds) >= fanghealth) and (((chipool + (soul/2)) - chispent) >= 1))
				*gosub nocondition
				*set powspent + 1
				*set forspent + 1
				
			*else
				Taking a hit wasn't the best plan, you realize, as her blade shifts to pure energy and pierces through your chest.
				
				With a spiritual [i]heft[/i] she lifts you off the ground and activates something within her blade. Your aura freezes in place, shattering your remaining chi and stamina from the inside of your soul.
				*set wounds + 1
				*goto dogfightlost
		With the durability of steel and the power of a cannon you charge at her gigantic sword and take the stab directly to the chest, grabbing the blade and breaking it in your hand.
		
		It stings like a bitch.
		
		And you make sure she knows it. An enraged howl escapes your throat and you grab her head on both sides, framing her shocked expression with your hands and holding her in place for your attack. She tries to say something but you can't hear it over the heavy storm winds whipping through your ears when you slam your
		*if (yokaitrait1 = "horns")
			horns against her forehead.
		*else
			forehead down into the bridge of her nose.
	#Wrap chi around my fist and dash in for a haymaker.
		*set combatstat "agility"
		*set combatstat2 "soul"
		*set combatdiff 8
		*gosub_scene quicks combatcheck
		*if (passcheck)
			If she wants to end this then you're more than happy
			*if ((agility + soul) >= 8)
				to, and you won't even need to surge a Combat Core. Your Agility and Soul Cores are advanced enough to win this without strain.
			*else
				to. You burn through your chi reserves and vibrate intensely with all the speed-aligned chi coursing through your spirit.
		*else
			*if ((((health + (fortitude/2)) - wounds) >= fanghealth) and (((chipool + (soul/2)) - chispent) >= 1))
				*gosub nocondition
				*set agispent + 1
				*set solspent + 1
				
			*else
				Speed and energy seemed like such a good idea at the time, but you learn quickly that they're her specialties too.
				
				As your Agility Core starts to surge you see blood spray from your chest and freeze in the air, clinging to your body and draining your aura.
				
				Tian Fang's attack is already finished.
				
				She's ten feet behind you now, dust swirling around her as she skids to a halt from her burst of speed that you couldn't even see.
				*set wounds + 1
				*goto dogfightlost
		You don't have anything flashy like her ice sword, but you've got energy and you've got speed.
		
		Vibrant ${auracolor} power wraps around your fist like a glowing ${auracolor} cocoon, weaving layer after layer until the power in your grasp hums louder than the storm.
		
		"Let's go!" You shout in defiance while Tian Fang charges recklessly.
		
		The Yokai girl surges an Agility Core to become a blur of pale blue light speeding towards you and in response you shoot your compacted chi at the ground to lift you airborne. The force of all that energy around your fist launches you over her reach as she swipes where you were standing a moment ago. She doesn't have the chance to see what happens next. You arc your glowing arm over your head and use its propulsion to shoot yourself at her in a crescent formation after your ascent. When you speed back behind her she turns just in time to take a nose-crunching direct hit to the face.
	#Wrestle her to the ground.
		*set combatstat "fortitude"
		*set combatstat2 "agility"
		*set combatdiff 8
		*gosub_scene quicks combatcheck
		*if (passcheck)
			If she wants to end this then you're more than happy
			*if ((fortitude + agility) >= 8)
				to, and you won't even need to surge a Combat Core. Your Power and Agility Cores are advanced enough to win this without strain.
			*else
				to. You burn through your chi reserves with Fortitude and Agility-aligned chi to prepare yourself for swift and uninterruptable movements.
		*else
			*if ((((health + (fortitude/2)) - wounds) >= fanghealth) and (((chipool + (soul/2)) - chispent) >= 1))
				*gosub nocondition
				*set forspent + 1
				*set agispent + 1
				
			*else
				You dash in to wrestle her to the ground where her sword will be too unwieldy, but can't close the gap in time. She swings at you and lands a heavy cut to your thigh and elbow. You push through the tearing pain and grab her neck in the crook of your other arm's elbow and bicep.

				The momentum of your charge pulls her backwards to the ground with you,	hoping to slam her head into the hard stone ground, but all you get is a second stab wound through the side from behind.
				*set wounds + 1
				*goto dogfightlost
		First thing's first, now that she's slowed down you're not giving her a chance to use that sword. A swift charge baits her into swinging at your torso but you duck under the attack and slide behind her.
		
		With no time to lose you wrap your hands around Fang's waist from behind and lift her off her feet, over your head in a circular arc, and down into the hard ground with a bone-crunching suplex that connects the top of her skull to the rock of the mountaintop with such force that the rock explodes and makes way for her body, planting her like a radish and sending up a dust cloud engulfing the two of you.
	#Gather enough energy from the Heavenly Gate to launch a beam of power.
		*set combatstat "soul"
		*set combatstat2 "power"
		*set combatdiff 8
		*gosub_scene quicks combatcheck
		*if (passcheck)
			If she wants to end this then you're more than happy
			*if ((soul + power) >= 8)
				to, and you won't even need to surge a Combat Core. Your Soul and Power Cores are advanced enough to win this without strain by using the energy of the Heavenly Gate.
			*else
				to. You burn through your chi reserves to surge as much power between your hands as your spirit can handle, then pull in even more from the Heavenly Gate around you.
			
		*else
			*if ((((health + (fortitude/2)) - wounds) >= fanghealth) and (((chipool + (soul/2)) - chispent) >= 1))
				*gosub nocondition
				*set solspent + 1
				*set powspent + 1
				
			*else
				Glowing ${auracolor} power starts to form around your hands but try as you might you just can't create enough distance or focus on the power around you. Every time you try to build up enough energy for an attack you're forced to waste it knocking Fang or yourself back to avoid a dangerous strike from her glowing blade.
				
				And then you slip up.
				
				You push another layer of the storm Heavenly Gate's power in between your hands and try to harness a stronger energy blast, but when she swings this time she surges an Agility Core and you don't.
				
				Her blade catches you in between the arm and ribs, cutting both.
				
				Blood freezes your sliced bicep to your shattered rib, avoiding blood loss but immobilizing your movements.
				*goto dogfightlost
		Glowing ${auracolor} power forms around your hands and illuminates your form: a wide stance, one foot forward, one foot back, cupping both hands together to weave the power all around you into a condensed and potent blast. Tian Fang paces back and forth, still keeping her distance and catching her breath yet grinning like a predator bearing down on its prey; she can see your attack is no better than a normal energy blast. But you don't release it. You build upon that power with another layer pulled from the storm chi swirling around you. Then another. Then another.
		
		Normally this is impossible, the layers of chi would dissipate into your surroundings, but your surroundings are already saturated with chi within the Heavenly Gate. The layers remain.
		
		"If you want a clash of Techniques, I'll give you one!" You add another layer. Suddenly Fang doesn't seem willing to play with her prey anymore, uncertainty growing in her eyes. Waiting for your display could cost her this prize.
		
		She attacks.
		
		You leap back and add another layer. She slashes at you. The blade misses but the ice chi around it stings your skin. You add another layer.
		
		She swings downward where you're going to be. You kick the flat of her blade to deflect and add another layer of energy from the Heavenly Gate around you.
		
		Her iceblade swings against the ground and emits a wave of freezing icicles thrusting at your throat. A twist of the torso has the attack crash against your shoulder. You add another layer.
		
		She leaps above you and raises her blade overhead, but you jump in a different direction and add another layer.
		
		Finally with a mighty roar her frustrations mount into action. She throws her blade at you like a javelin while you're stuck in midair.
		
		No time for more layers.
		*page_break 
		You unleash your "Technique", an unsteady beam of ${auracolor} energy built from not only your own internal chi but also the environment's strongest natural energies you've ever felt in your life.
		
		The river of power you release is as wide as your house.
		
		Blinding light prevents you from seeing the impact but the explosion cracks louder than the Heavenly Gate's enhanced thunder. It takes ten long seconds for the debris to clear but you can already feel that your opponent's aura is completely diminished.
		*goto dogfightwon
	*if (element1 = "Ice")
		*selectable_if (((chipool + (soul/2)) - chispent) >= 2) #Conjure my own ice claymore. [Costs 2 Chi] [Requires Ice Element]
			*set chispent + 2
			[b][2 Chi Points Spent][/b]
			
			You don't have a "Best Technique", but she sure does. And she activated it in a Heavenly Gate where its echo imprinted upon the natural aura all around you. Your willpower reaches out to that imprint of her Technique and you offer your internal Ice chi as fuel to pull that echo into your hand.

			A duplicate glowing ice claymore forges itself in your grip.
			
			Its summoning is slow, and she could interrupt it, but she's frozen with astonishment at the sight of you stealing her ultimate Technique.
			*set fangrep + 5
			*set solexp + 4
			
			Good.
			
			You channel the ice power of your summoned blade and charge it into hers. She defends at the last moment but the trajectory is on your side. Both Techniques shatter against each other in a house-sized explosion of ice-mist that launches over her thanks to your momentum advantage. It cascades into the Yokai girl like an explosive avalanche and knocks her body skyward like a spinning ragdoll.
	*elseif (element1 = "Storm")
		*selectable_if (((chipool + (soul/2)) - chispent) >= 1) #Unleash the storm. [Costs 1 Chi] [Requires Storm Element]
			*set chispent + 1
			[b][2 Chi Points spent][/b]
			
			Did she just ask for your best Technique? You're inside a Heavenly Gate. A [i]Storm Aura[/i] Heavenly Gate. You don't need to know a Technique when your elemental chi is soaking into the air all around you.
			
			Your senses reach out and spiritually seize the potent aura in the dark clouds around you. With a force of will you squeeze out every ounce of Storm Chi stored within them and pour it over your hands, generating violet arcs of lightning that a spin like wheels around your fists.
			
			"Good!" She shouts, seeming more excited than angered for once, "Iconic! Legendary! A sword against shields!"
			
			"Shields?" You ask. You're not sure what she's talking about, because these spinning disks of Storm Chi aren't shields. Both your hands clasp together and the arcing electricity from each hand combines into a massive ball of power.
			
			Power that you aim.
			
			The resulting eruption of lightning releases as a singular, body-width bolt of violet energy that blows her ice-sword, aura, and Fortitude Cores away. Even her body is blown back sixty feet up the trail and embedded into the stone hard enough to be an ornamental lawn piece.
	*elseif (element1 != "None")
		*selectable_if (((chipool + (soul/2)) - chispent) >= 2) #Forge a whip of ${element1} power. [Costs 2 Chi]
			*label elementalwhip
			*set chispent + 2
			[b][2 Chi Points spent][/b]
			
			You don't have enough mastery over
			*if (val = 444)
				${element2}
			*else
				${element1}
			chi to pull off a massive blade of power like hers, but you can try.
			
			With a focus of will and a massive infusion of your internal chi you generate a ten foot bar of 
			*if (element1 = "Water")
				nearly solid electrified water chi.
			*elseif (element1 = "Earth")
				stone glowing with amber power.
			*elseif (val = 444)
				nearly solidified burning flames.
			*else
				nearly solidified ${element1} chi.
			When she charges at you with her glowing blue blade you pull on the storm's power to enhance your attack and swing at her blade with a glowing ${auracolor} whip.
			
			If you were fighting with swords it would be a clash of wills, a contest of Technique mastery, and a test of the strongest Aura Pressure, but you aren't fighting with swords. Only she is.
		
			Her claymore slams into your glowing whip and bends it, causing your attack to lash in an arc around her sword, loop around it twice, and comically slap her in the face.
			
			Then its tip explodes on impact into a blinding ${auracolor} eruption.
	*elseif (element2 = "Fire")
		*selectable_if (((chipool + (soul/2)) - chispent) >= 2) #Forge a whip of ${element2} power. [Costs 2 Chi]
			*set val 444
			*goto elementalwhip
*goto dogfightwon

*label dogfightwon
*page_break It's over.
*if not (jadedragonfoundation)
	*achieve dogfight
*set infused 3
*if (sonarmode)
	[b][Thunderfaller vs Tian Fang][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-thunderfaller-vs-tian-fang.png

*if (sonarmode)
	[b][Victory!][/b]
*else
	*image https://www.auraclash.com/assets/img/ap-victory.png

*gosub_scene quicks statcheck
*line_break
*line_break
*set prestige + 1
*gosub_scene quicks fightexp
*set metfang 11000000000
*set fighting false

Tian Fang lies on the ground, bruised and defeated but still breathing. Her hair strewn about the cold stone floor and her fur robes soaked from the rain. You're glad you didn't hold back if she's this sturdy.

Realization dawns on you while catching your breath: you did it. You won a real fight.

Nobody's opinion can matter as much as this victory. You require no approval or permission to call this a victory, you've proven your worth with your own merit. With your own fists. In a roaring howl you laugh to the Heavens, you've won! Not against some clone and not in some race, this time you've faced another Sect's star pupil, and you won!

Wiping the blood from your bruised lip never felt so good as you march up the mountaintop through the heavy winds of the storm, grinning ear to ear, then sit down to harvest the storm's Heavenly Gate.

A well-earned reward that you cycle throughout the night.

[b][Aura Pressure +50][/b]
*set aurapressure + 50

*if (insight >= 2)
	[b][Insight 2 Check Passed][/b]
	*line_break
	Using meditation forms you're able to better organize your cycling methods and fill your Cores with even more power.

	*set val (5+(3*insight))
	[b][Aura Pressure +${val}][/b]
	*set aurapressure + val
*else
	[b][Insight 2 Check Failed][/b]
	*line_break
	The constant booming thunder in the air disrupts your meditation, preventing you from taking in as much as possible.

*if ((((athletics >= 2) or (bodytype = "Muscular")) or (bodytype = "Dommymommy")) or (style = "Midorikatai"))
	*if (athletics >= 2)
		[b][Athletics 2 Check Passed][/b]
	*elseif (style = "Midorikatai")
		[b][Style Check Passed: Midorikatai][/b]
	*else
		[b][Bodytype Check Passed: Muscular Specialty][/b]
	*line_break
	Using your physical fitness your larger muscles are able to passively absorb the potent chi.

	*set val (5+(3*athletics))
	[b][Aura Pressure +${val}][/b]
	*set aurapressure + val
	*if ((equippedaccessory1 = "Weighted Clothing") or (equippedaccessory2 = "Weighted Clothing"))
		*line_break
		*set val (3*athletics)
		*if (val < 3)
			*set val 3
		[b][Weighted Clothing Bonus: Aura Pressure +${val}]
		*set aurapressure + val
*else
	[b][Bodytype/Athletics 2 Check Failed][/b]
	*line_break
	Your muscles have only been increased with chi, rather than physical growth, and so you aren't able to store any additional storm aura into your physical body than normal.

*if (hungryspiritritual != 1)
	[b][Hungry Spirit Ritual][/b]
	*line_break
	Using your knowledge of handseals you're able to form a quick sigil-circle on the stone ground around you that aids in storing some of the storm's chi around your aura. It will enter your Cores as soon as you've processed the surging power that's already filled them.

	*if (handseals >= 2)
		*set val (5+(3*handseals))
	*else
		*set val 5
	[b][Aura Pressure +${val}][/b]
	*set aurapressure + val
*else
	[b][Handseal Check Failed][/b]
	*line_break
	It occurs to you that there might be some kind of handseal ritual to aid in aura absorption, but you've never heard of it.
*if (((element1 = "None") and (element2 != "Storm")) or ((element1 != "Storm") and (element2 = "")))
	
	*gosub stormelement

*if (roc > 0)
	*page_break What's that sensation in the air?
	"Shit!" You curse to yourself once you sense a disturbance among the Storm aura above. A different type of chi is approaching you quickly, inhuman and potent. [i]Beast chi[/i]. Numbness courses through your body when you flare your aura to life after stretching it so rapidly in the Heavenly Gate, but you have to ignore it. Beasts fight to the death. Sparks of unprocessed Storm chi shoot around you while powering up for a fight to the...
	
	A laugh escapes your lips when the presence gets closer and you let out a cheery whistle.
	
	The Beast descends from the dark clouds and lands next to you with a heavy thud. It's just ${rocname}, nuzzling your shoulder with her beak.
	
	"Good girl." You pat your now-much-larger bird and feel the weight of the world fall off your shoulders. No Beast fight today after all. You've spent so much time raising her as a baby giant eagle that you'd almost forgotten she has Thunderbird in her ancestry; the Storm chi is soaked into her like a sponge and must have triggered her first Advancement. She hasn't transformed into a Thunderbird proper but she has grown significantly, already up to your chest. "Storm chi suits you well."
	
	"Cawwww!" replies ${rocname} in agreement, then she takes off to find a deer to eat. Your Beast pet makes for poor company. At least her hunting saves you a few Shards.
	*set roccombat + 1
*page_break
Hours of cycling pass and so does the storm. Every minute without an intruder is another blessing from the heavens, but now that so much time has gone a disturbing thought echoes through your mind.

[i]Where is everyone?[/i]

Even if the Thunderfall Sect has left there's still plenty of other cultivators in the village that aren't real Martial Artists. You can't be the only one who didn't know about the village's promise to Tian Fang, so why has no one shown up to cycle this Heavenly Gate?

You get up and walk home to investigate and pass by Tian Fang's resting body, looking [i]much[/i] better than how you left it. An unpowered inhabitant of the Heavenly Gate's storm would have been ripped apart by stray energies but it seems a Martial Artist's body uses the potent chi to restore themselves.

That explains why you feel better.

[b][Wounds Healed][/b]
*set wounds 0
*line_break
[b][Chi Restored][/b]
*set chispent 0
*line_break
[b][Cores Replenished][/b]
*set powspent 0
*set forspent 0
*set agispent 0
*set solspent 0

The close presence of your aura wakes Tian Fang. Her eyes flutter open just as the Heavenly Gate ends and sits up, groaning. "Rrrrhhhhnnngggg...This one's head hurts." She opens her robes by a few inches and looks down at the bruises covering her torso. "In fact, it appears to be the body that hurts even more. Thunderfaller, please tell, what happened here?"

*choice
	#"You went feral and I put you down." I say flatly, walking passed her and returning home.
		"You went feral and I put you down." You say flatly, walking passed her.
		
		"Th-Thunderfaller wait, that was not me! It's a primal allergy to Heavenly Gates, I didn't mean to-"
		
		*set honor + 2
		*set ruthless + 1
		You keep walking and leave her whining on the mountaintop as you go. She can forage for scraps of energy now that you've feasted upon the storm. Nothing stands in your way as you march home victoriously, filled with new power.
		*goto departure
	#"We fought. I won. Are you concussed? Do you need an escort home?"
		"We fought. I won.
		*set honor + 2
		*set ruthless - 1
		*if (heshe = "he")
			*set fangromance + 1
		Are you concussed? Do you need an escort home?"
		
		"No, no, this one is okay. Will be okay." 
		
		*goto NicetoFang
	#"You went feral and attacked me, what was that about?"
		"You went feral and attacked me" You say, "What was that about? And are you okay now?"
		
		"That was...An illness. A curse."
		*set ruthless - 1
		*goto NicetoFang
	#"We determined who was top dog around here." I spit on the ${mutt}. "Make sure to remember it."
		*set ruthless + 3
		*set fangrep - 5
		*set metfang + 100000000
		*if (heshe = "he")
			*set fangromance + 1
		"You went feral and we determined who was top dog around here." You hock up snot and spit it at her. "Make sure to remember it."
		
		Your spittle slaps her right between the eyes. Her mouth opens and closes in shock, and from the tears forming she must know there's nothing she can do. You can see the hopelessness on her face. You spit on her one more time to drive the point home.
		
		She actually starts to cry.
		
		Hah! You turn your back to her and laugh all the way down the mountain. What is she going to do, attack you? You've both already seen how that ends.
		
		Nothing stands in your way as you march home victoriously filled with new power.
		
		Damn, it's good to be the best.
		*goto departure

*label NicetoFang
*set fangrep + 5
She reaches into her bra and pulls out some sort of green pill that she swallows.

Fang stands, her robes muddied and soaked in the storm, and you can feel chi flowing through her veins from the fast-acting refinement pill. "That was not the real me, it was an embarrassing condition I inherited from my mother." She turns to you and bows at the waist, wet hair flopping over her head so her wolf ears stand out. "This one humbly apologizes for her actions."

*choice
	#"Apology accepted."
		*set fangrep + 2
		"Apology accepted." You say.
		
		"Phew, thank you much."
		
		"Don't mention it."
		
		"I did not plan to!" Fang says with one finger elevated for excited emphasis. "Though I must confess this entire situation is why I had requested a Heavenly Gate alone as payment, and I ask that you keep this a secret. You see, I have an...allergy."
		
		"An allergy?"
		
		"To Heavenly Gates. They cause me to enter bestial regression, a rare Yokai disease. It's lead to many, many complications."
	#"Apologize? You attacked me like a rabid animal!"
		*set forexp + 2
		"Apologize?" You say, waving a weakened hand theatrically despite the muscle strain all over your body, "you attacked me like a rabid animal!"
		
		She kicks one leg back playfully. "Hah! $!{manwoman} versus Beast, a tale as old as time. When next we meet I swear to be more cordial! I have an unfortunate allergy, you see, an allergy to Heavenly Gates. It's why I requested one alone as my payment from your Sect. I most humbly ask that you please keep this a secret."
		
		"You have an allergy...to power?"
		
		"Oh Ancestors no, that would make life much more difficult. I can handle Advancement elixirs, Beast meat, Soul Treasures, rituals, even the presence of nature spirits. But I [i]do[/i] have an allergy to unrefined natural power entering my body. Spirit fruit and Heavenly Gates. It causes bestial regression, a rare Yokai disease."

"Does it hurt? Is it useful in a fight?"
	
"Very much yes, and very much no! My training abandons me on such occasions as if my instincts were all I've ever had. It is [i]quite[/i] vexing actually." She stretches and lets out a peep mid-stretch. "Oh that smarts most painfully. I fear my body is filled to bursting with power and my muscles are not happy over it, yet still I must be departing most hastily if I am to reach the Trials." She twists and turns, stretching her back after the beating you gave her. "I underestimated you, Thunderfaller." She looks around and sighs, "And missed an opportunity for it, by the looks of the sun ignorantly smiling upon us. Well fought."

It's a surprise to see her to revert to niceties after the clobbering you both delivered to each other's face while she screamed like an animal, but it seems that's the path she's chosen.

*if (ruthless >= 54)
	You nod in return. "I did fight well, didn't I?"
*else
	You push the awkwardness down and bow back. "Well fought."

Fang rises from her bow and looks down at Thunderfall Village in the valley below, taking in a deep breath through her nose. "You know Thunderfaller, your village is much like mine. It possesses two or three promising disciples leading handfuls of lost souls. Far too many in the Outer Provinces only play at the Martial Arts..."

She turns and meets your eyes, her amber irises returned to their natural brown. "Protect them if you can. The danger of the Trials are said to be a league above what our senseis planned for us. The weak will depend upon our strength."

*if (jadedragonfoundation)
	You don't quite know what to say. The idea of you protecting Thunderfall Disciples sounds backwards, you're the one who's been trying to catch up for so long.
*else
	You're not sure how to answer such a plea. On the one hand, with your Jade Dragon Foundation, you're so far above the other Thunderfall disciples that you don't think of them much anymore.
	
	On the other hand, perhaps due to your draconic spirit, the idea of someone taking something away from you fills you with a cold rage. Thunderfall is your home. Whatever lies within it is not for anyone else to destroy, even if it's the Lower Disciples you've never cared for.
	
	*if (ruthless >= 52)
		Ancestors, you hope this dragon-greed doesn't make you waste time protecting those idiots.
	*else
		Ancestors, how much of your personality is based on being a reborn dragon from thousands of years ago?
		
		You live a strange life.

"Or do not."
*if (jadedragonfoundation)
	Fang
*else
	She
says with a twitch of both ears. "I have observed they do not like you much anyway. A jealousy of your quick natural rise perhaps? If so I can understand. You [i]are[/i] my rival now, after all."

"I don't know if I have room for more rivals."

Tian Fang smiles at that. "I'm sure you can make room." Ice manifests under her bare feet and she starts to slide downhill, accelerating from a soft glide into a full skate as she gets further down the steep mountainside opposite the village. To the west. To Nanhou. "See you at the Trials,
*if (fangrep > 50)
	$!{name}!
*else
	Thunderfaller!
Don't be late!"
*goto departure

*label dogfightlost
*page_break It's over...
Tian Fang howls to the storm as the world around you grows darker. It takes too long for you to realize it's not a Technique she's using to bring about shadows, it's your consciousness fading from injuries.

You fought valiantly inside the greatest source of natural energy of your life.

[b][Aura Pressure +25][/b]
*set aurapressure + 25

But you lost.
*set metfang 12000000000
*set fangcombat + 1
 
*if ((equippedaccessory1 = "Weighted Clothing") or (equippedaccessory2 = "Weighted Clothing"))
	Perhaps a handicap like weighted clothing wasn't a good idea for a serious fight. Still, it did push you past your limits.
	
	*set apval 15
	*gosub_scene quicks apboost
	
*page_break Damn it...
*set fighting false
*set forspent 0
*set powspent 0
*set agispent 0
*set solspent 0
*set chispent 0
*set wounds 0
[b][Wounds Healed][/b]
*line_break
[b][Chi Restored][/b]
*line_break
[b][Cores Replenished][/b]
*line_break

Morning light wakes you hours later and your stiff back is propped up against the town wall. The western entrance lies ten feet to your left where two guards stand watch over the busy roads that have more foot traffic than ever now that the storm has come and gone. Dozens of travelers wander in and out carrying satchels or riding wagons on their way to Nanhou.

The guards see you stir and they wave.
*if (roc > 0)
	$!{rocname} sits beside you, noticeably bigger than when you last saw her. She's all the way up to your chest now and must have used all that storm aura to trigger her first Advancement. Though weaker than you, she's a real Beast now.
	
	And it seems the guards know it, as they're avoiding eye contact with your bird.

"Good morning, Honored Disciple. That Yokai girl dropped you off by the gate last night. We didn't want to wake you,
*if (roc > 0)
	especially after your erm...pet arrived. That and
you looked pretty beat 
*if (heshe = "he")
	up. Between the wolfgirl and the scratches we weren't sure if your night had gone poorly or [i]very[/i] well."
	
	The other guard snickers under his helmet.
*else
	up and I've learned it's best to stay out of a quarrel between powerful women."
	
	The second guard snorts dismissively. "He's talking about his wives."

"Be..." You try to respond but your mouth is dry, you're not sure how much blood you lost but it was enough to need a drink and more rest. Closing your mouth to slowly salivate alleviates the pain of your dry throat ever so slightly. "Beast...The girl, Tian Fang. She was acting like a Beast."

"Doesn't sound like the girl I saw." Says the first guard. "She seemed quite pleasant when leaving you here to rest, apologized and everything. Told us to ask you not to mention her allergy to anyone, whatever that means."

The second guard speaks up. "Will you be attending the Trials, Honored Disciple? If so you'd best be off soon, it's a months-long journey and the rest of the Sect left two days ago."

Shit, that's right.

You pick your sorry butt off the ground and drag your feet back home,
*if (ruthless >= 55)
	dismissing the guards without a word.
*elseif (ruthless < 50)
	thanking the guards for watching over you.
*else
	nodding to the guards in exhausted appreciation.
*if (roc > 0)
	${rocname} glares at them as you walk past them through the town gate, then jumps over the gate with a flurry of her wings and hops along the road beside you.
	
"Storm chi looks good on you." You say to the bird.

"Caw!" ${rocname} responds.
*goto departure

*label departure
*page_break
Getting home isn't the serene reprieve that you'd been dreaming of this last week out in the wilderness. Night after night spent wrapped in a blanket on the hard stone ground of various caves left you dreaming of your tatami mat by the fireplace.
*if (roc >= 1)
	${rocname} didn't make it any easier. You suspect she's part rooster with how loud the damned roc is in the early morning.

Unfortunately, after all that you finally return home only to find a crime scene. An upper disciple of the Thunderfall Sect, an elderly woman in leather armor over a blue gi, is speaking to your parents while guards plunder through your house.

"And you're certain ${heshe} hasn't returned home?"

"Obviously-oh, obviously not." Says Father, changing from annoyed to relieved when his eyes meet yours further up the road.

The upper disciple turns to see you. "Well well, ${fullname} shows ${hisher} face at last."

One glance is all it takes to tell you the situation, from the upper disciple questioning your parents to the guards searching through your house. They don't mean well for your family.
*choice
	#"Is there a problem, Upper Disciple?"
		*set ruthless - 1
		*set honor + 2
		*set solexp + 1
		"Is there a problem, Upper Disciple?" You ask politely with a short bow. They may mean trouble but manners come for free.
		
		The white-haired woman, deceptively strong if your spiritual senses are to be believed, shallowly bows back to you. "Yes, Lower Disciple, we've had an issue of a great theft."
		*label askabouthouse
		
		"A theft?" This sounds
		*if ((honor >= 51) or (wounds > 0))
			like trouble.
		*else
			juicy.
		
		"Yes, and one of great concern: an armory theft. Crusher Mao and half our Upper Disciples began escorting the Lower Disciples to the Heavenly Ascension Trials two days ago, a secret that should not have left this village. Someone who knew about our schedule and plans abused the situation to break into the Lower Armory where they stole everything not used up in the Trial preparations. Ritual components, alchemical reagents, Soul Treasure weapons, sealed forbidden objects, even all our spare gi and belts."

		*if (honor >= 51)
			"That's unfortunate, but
		*else
			"That's not my problem,
		I was out of town. Who do you suspect, Rin and Jin?"
		
		"My children are no thieves!"
		*if (thievery >= 1)
			Lies father.
		*else
			Says father.
		
		"Naturally we don't suspect
		*if (japannaming)
			${clan} Rin or ${clan} Jin,"
		*else
			Rin ${clan} or Jin ${clan},"
		the old woman retorts as if stating the obvious, "they had already left with Crusher Jack before the thefts."
		
		You blankly stare from the Upper Disciple to Father and back. "...What?"
		*page_break
		When did Jack even get back from Mountain Hazard? And Jin and Rin can't be entering the lethal Heavenly Ascension Trials, they're just kids!
		
		"That Jack boy," Father mumbles to the ground, "He came looking for you. Demanded a rematch, said it would be 'fun'. Jin and Rin told him off but he had his Father's men take them away. We...We couldn't stop them."
		
		"There was [i]no need[/i] to stop them." Replies the old woman through a distant ringing in your ears. You can't believe what you're hearing. "Your siblings are Warrior Caste with auras, are they not? The Heavenly Ascension Trials call for all Martial Artists under 25."
		
		*if ((jinaura = false) and (rinaura))
			"Jin doesn't have an aura." He's supposed to be running Father's business, how could he have found the time to cultivate power at the same age you did without using a Heavenly Gate?
			
			"I don't know what to tell you, young ${manwoman}, he does now.
		*elseif ((jinaura) and (rinaura = false))
			"Rin doesn't have an aura." She's turned into a girly girl over the years, pining after boys and trying to make her own tablecloths or homemade makeup to sell. How could she have unlocked an aura at the same age you did without a Heavenly Gate?
			
			"I don't know what to tell you, young ${manwoman}, she does now.
		*else
			"This is insane," You protest, "they've barely developed their auras at all." Jin's been busy with Father's business and Rin's grown into a girly girl, pining after boys and knitting tablecloths to sell. "They can't be in the Trials, that's sending them to their deaths!"
			
			The old woman's face scrunches up in conflicting emotions. She knows it's an unnecessary risk as much as you do. "I'm sorry young ${manwoman}, it's out of my hands.
		Crusher Jack was adamant they be added to the Sect before he'd let the caravan leave. He wouldn't take no for an answer. Unfortunately I am not here to talk about them, I am here to talk about the Lower Armory's grand theft. We have a handful of suspects but the primary targets are you and that beggar
		*if (bffheshe = "he")
			boy
		*else
			girl
		you're always hanging around, Kosuke I
		*if (kosukeaura)
			believe. Always suspicious when the poor cultivate auras. The threats in the wilds make them desperate and I do not trust the desperate."
		*else
			believe."
		
		"Kosuke isn't an idiot, ${bffheshe} wouldn't risk death stealing from the Sect." Damn it all, Kosuke is exactly the kind of idiot to risk stealing from the Sect. 
		
		"That's what your Mother said, but what about you? Why have you not gone with the rest of the Sect in their pilgrimage to the Trials? Do you intend to disobey Imperial Decree?"
		
		"I didn't know everyone had left yet. I've been training in the mountains for the last week."
		
		"Hm...Just long enough to remain for the Heavenly Gate's energies that I sense coursing through you. Most suspicious that you knew it was coming, and most forbidden if you contested our Honored Guest, Tian Fang, for her reward." The guards behind the spry old woman draw their tonfas. She holds a hand up to stop them. "However, it also alleviates you of guilt. The theft was just before dawn and if you had such unprocessed Storm energies in your core at the time then you would have been detected. Come men, we're on to the next suspect."
		
		"Yes, Upper Disciple!" The group of splint mail armored guards shout in salute before following the spry old woman away.
		
		When they disappear down the road Father finally grumbles. "Bastards come in here, make a mess, [b]abduct my children[/b], and won't even clean up after themselves."
		
		Mother comes out of the house holding several pots and pans she was hiding from the guards to avoid them seeing her dirty dishes. "Oh they'll be alright darling. Rin will fail out on purpose or find a boy to protect her, and Jin can look after himself. But do you really think the thief was-"
		
		"Kosuke? Let us hope not." Father says, staring down the road where the guards had already disappeared. "A crime like this is punishable only by death."
	#"What's the meaning of this?"
		"What's the meaning of this?" You ask to the upper disciple questioning your parents.
		
		The white-haired woman, deceptively strong if your spiritual senses are to be believed, waves a hand in the direction of your house. "We're running a search through the property of all suspects in a theft investigation."
		*goto askabouthouse
	#"Get those buffoons out of my house before I start removing limbs."
		*set honor - 1
		*set ruthless + 2
		"Get those buffoons out of my house before I start removing limbs."
		
		The butt of the elder's spear rushes at your face with such speed that her entire body seems to blur.
		*page_break
		*set combatstat "power"
		*set combatskill "perception"
		*set combatdiff 6
		*if (((element1 = "Earth") or (style = "Midorikatai")) or (element1 = "Water"))
			*set combatdiff - 1
			*if (element1 = "Earth")
				[b][Element Event: Earth (Difficulty Lowered)][/b]
			*elseif (style = "Midorikatai")
				[b][Style Event: Midorikatai (Difficulty Lowered)][/b]
			*elseif (element1 = "Water")
				[b][Element Event: Water (Difficulty Lowered)][/b]
			*line_break
		*gosub_scene quicks combatcheck
		*if (passcheck)
			*if (element1 = "Earth")
				The skin of your arms hardens reactively.

			*elseif (style = "Midorikatai")
				Your muscles harden with Wild Chi reactively.
				
			*elseif (element1 = "Water")
				Your body moves on its own as if following the flow of an unseen tide.
				
			Faster than a normal eye can see, you catch the butt of the spear in one hand and use the other to strike the weapon at its center where it snaps in half. The upper disciple's eyes widen in response and she leaps twenty feet down the road with a sudden sense of danger.
			
			You toss the bottom half of her spear aside and cycle chi to generate your ${auracolor} aura, blazing from the power of the Heavenly Gate. "I said get out of my house. Now."
			
			Credit to the upper disciple, she adjusts quickly. "You heard ${himher}, men. The search is over."
			
			"But Honored Disciple, we-"
			
			"I said it's over." She turns to you and gives a slight bow. "I underestimated your ability. Please allow me to explain myself, we are not here to hassle your good family. We are investigating a theft against the Thunderfall Sect."
			*goto askabouthouse
		*else
			Her weapon connects to your nose with a spray of blood shooting from your face in all directions, your nose sufficiently shattered.
			
			*set wounds + 1
			[b][1 Wounds Suffered][/b]
			*if (((health + (fortitude / 2)) - wounds) < 1)
				*goto dogfightlost
			
			Your vision spins from the sudden shock of the old woman's attack and you curl over in pain, gripping the pulp of your nose.
			
			"Show some respect, lower disciple, you are in the presence of a superior. You [b]will[/b] cooperate with us while we investigate this theft."
			*goto askabouthouse
*page_break
The next hour is spent running around general shops in a hurry collecting everything you'll need for your journey. Bandages, clothes, soap, dried foods, a bedroll, flint, rope, knives, belt pouches, fishing nets, empty sacks, candles, a reinforced travel lantern, more bandages, unguents, waterskins, and some treated herbs Mother uses for her burnt leaf soup that you throw out when she's not looking.

*if (handseals >= 1)
	[b][Handseals 1 Check Passed][/b]
	*line_break
	[b][Travel Inventory Sealed in Fuuinjutsu Tags][/b]
	*line_break
	*set apval 3
	*gosub_scene quicks apboost

*if (underlings >= 1)
	Mother and Father rent out your
	*if (underlings >= 2)
		slaves
	*else
		slave
	to a merchant caravan heading to Nanhou. Bringing
	*if (underlings >= 2)
		them
	*else
		him
	with you personally would slow you down, and it never hurts to rake in some extra Shards.
	
	*rand val (underlings * 18) (underlings * 25)
	*set val + (commerce * 3)
	[b][Item Gained: ${val} Shards][/b]
	*set shards + val
	*set val 0

There's no sign of Kosuke on your way out of town.

When you get to the gates you find not just Mother and Father but most of your childhood friends too. The struggles of spiritual cultivation have kept you so busy, so focused on the next Advancement, that you nearly forgot you had so many friends. Most have grown up into their own craft by now and [i]so many[/i] have beards. They surround the gate out of town and cheer for you alongside their parents or, in some cases, spouses.

Oh Ancestors, some of them are carrying babies.

"Go show them how we do things in Thunderfall." Says the baker's son, now just 'the baker', while giving you a strong handshake for a man without chi. He showed you and Jin how to hook worms when you were six.

The weaver's son claps you on the back as you walk by. "If anyone gives you trouble let me know, I'll have some of my guys visit some of their guys." Him and his seven brothers were the last crew to keep up with your family and Kosuke in the old sparring games.

"I heard the Sect took Jin with them." Says the barber/dentist's daughter. She used to beat you at tag so badly that you and Kosuke practiced uphill sprints for months just to stop losing. "Bring him home in one piece or I'll have your head."

"Yeah, and we're counting on you to bring Rin back too!" Begs the carpenter who immediately gets slapped by the young woman you assume is his wife.

After saying your goodbyes to everyone you hug Mother and Father then walk through the gates of Thunderfall Village for the longest journey of your life, alone but not abandoned. It takes a village to raise a child and a village is what you had. Everyone here helped shape you into the ${manwoman} you are today: a Martial Artist contending in the Heavenly Ascension Trials.

Now to prove you were worth it.
*finish

*label nocondition
You're in no condition for your battleplan, but you do it anyway. The power swirling through the air inside this Heavenly Gate calls out to you, acting as an extension of your own energy. With a battlecry you push your body to meet that temporarily increased limit by blowing through your chi reserves, your Cores, and your own lifeforce. Everything burns up as fuel for this one final attack.

*if (((health + (fortitude / 2)) - wounds) >= 2)
	*set wounds + 1
	[b][1 Wound Suffered][/b]
	*line_break
*set chispent (chipool + (soul/2))
*if ((chispent modulo 1) = 0.5)
	*set chispent + 0.5
[b][Heavenly Gate Special Action: Chi Pool Spent][/b]
*return

*label swordsong
A song drifts on the wind as if her blade calls out to you, begging for a true master. Your body moves on its own to the melody sinking through your mind and spirit. You clap both hands together at the exact moment that the urge passes through your mind and against all odds you actually catch her blade,
*return

*label unfortunatesword
Unfortunately it is still a seven foot long claymore, and it slashes you across the chest so hard that you're pushed ten feet back, kept alive only by the Heavenly Gate reinforcing your flesh. Blood stains your gi as it spills freely from your chest wound.

[b][1 Wounds Suffered][/b]
*set wounds + 1
*return

*label stormelement
In the thunderous power cycling through your body and soul there lies a budding consciousness calling out to your own. An aspect of the Storm itself yearning to merge with your power.

Do you answer its call?

[b][Elements can be used to solve several problems by spending Chi. Most Martial Artists can only learn 2 Elements in one mortal lifetime.][/b]
*choice
	#Embrace the power of the Storm. [Learn the Storm Element]
		*set auracolor "violet"
		*if (element1 = "None")
			*set element1 "Storm"
			*set element1rank 1
		*elseif (element2 = "")
			*set element2 "Storm"
			*set element2rank 1
		Instead of contesting the Storm chi you embrace it, letting its crackling lightning burst in flashes throughout your spirit, carving new lines of power. The pain subsides quickly to make way for invigorating energy, sparks exploding all around your body. Just as you grow accustomed to the feeling a set of massive lightning bolts crash down upon you from the storm clouds, all at once.

		Seizing up in that flash you look into the eye of the storm and it looks back upon you. You've never felt more alive. Gazing into the soul of primordial forces of nature you feel as if you are immortal. That you have inside you the blood of Kings. That you have no rival, for no one can be your equal.

		This is true power, the power that will take you to the future as an immortal.
		
		*if ((element1 != "None") and (element2 != ""))
			[b][You can now set your aura color in the Cultivation Page][/b]
		*page_break
	#Deny the call of lightning, your Elemental power lies elsewhere.
		*set val 0
*return